à l'aide de l'asp classique de l'expression régulière

Nous avons quelques Classiques asp sites, et je suis en train de travailler sur un lil' bit, et je me demandais comment puis-je écrire une expression régulière vérifier, et extrait de la correspondance de l'expression:

l'expression que j'ai est dans le nom du script
donc, disons que ce

Response.Write Request.ServerVariables("SCRIPT_NAME")

Imprime:

review_blabla.asp
review_foo.asp
review_bar.asp

Comment puis-je obtenir le blabla, foo et bar à partir de là?

Grâce.

Quelle langue utilisez-vous, VBscript ou JScript?
ressemble VBScript. Dieu ait pitié avec son âme.
c'est un très vieux site et malheureusement, nous n'avons pas le temps de réécrire le tout

OriginalL'auteur Itai Sagi | 2011-07-13

  1. 18

    Tandis que Yots' réponse est certainement correctes, vous pouvez atteindre le résultat que vous recherchez avec beaucoup moins de code et un peu plus clairement:

    'A handy function i keep lying around for RegEx matches'
Function RegExResults(strTarget, strPattern)

    Set regEx = New RegExp
    regEx.Pattern = strPattern
    regEx.Global = true
    Set RegExResults = regEx.Execute(strTarget)
    Set regEx = Nothing

End Function

'Pass the original string and pattern into the function and get a collection object back'
Set arrResults = RegExResults(Request.ServerVariables("SCRIPT_NAME"), "review_(.*?)\.asp")

'In your pattern the answer is the first group, so all you need is'
For each result in arrResults
    Response.Write(result.Submatches(0))
Next

Set arrResults = Nothing

    En outre, je n'ai pas encore trouvé mieux RegEx aire de jeux de Regexr, c'est génial pour essayer votre regex modèles avant de plonger dans le code.

    regexpal.com c'est mieux je trouve.

    OriginalL'auteur Richard Benson

  2. 4

    Vous devez utiliser le Submatches Collection de la Correspondance Objet pour récupérer vos données à partir de la review_(.*?)\.asp Modèle

    Function getScriptNamePart(scriptname)
    dim RegEx : Set RegEx = New RegExp
    dim result : result = ""
    With RegEx
        .Pattern = "review_(.*?)\.asp"
        .IgnoreCase = True
        .Global = True
    End With

    Dim Match, Submatch
    dim Matches : Set Matches = RegEx.Execute(scriptname)    
    dim SubMatches
    For Each Match in Matches
        For Each Submatch in Match.SubMatches
                result = Submatch
        Exit For
        Next
    Exit For
    Next

    Set Matches = Nothing
    Set SubMatches = Nothing
    Set Match = Nothing
    Set RegEx = Nothing

    getScriptNamePart = result
End Function

    OriginalL'auteur Yots

  3. 0

    Vous pouvez faire

    review_(.*?)\.asp

    Voir ici sur Regexr

    Ensuite, vous trouverez votre résultat dans la capture de groupe 1.

    OriginalL'auteur stema

  4. 0

    Vous pouvez utiliser l'objet RegExp pour le faire.
    Votre code va être comme ceci:

    Set RegularExpressionObject = New RegExp
RegularExpressionObject.Pattern = "review_(.*)\.asp"
matches = RegularExpressionObject.Execute("review_blabla.asp")

    Désolé, je ne peux pas tester le code ci-dessous à droite maintenant.
    Découvrez l'utilisation de la MSDN à l'adresse http://msdn.microsoft.com/en-us/library/ms974570.aspx

    OriginalL'auteur Ostin