à l'aide de multiples boucle do while en VBA

Je voudrais vous demander comment faire pour utiliser plusieurs do while ou si il y a une autre façon de comment automatiser ce type de calcul.
J'ai de la feuille de calcul avec le prix de fermeture des stocks nommé Fermé. Sur une autre feuille appelée Retourne, je voudrais calculer le rendement. Je ne sais pas combien de lignes et de colonnes seront Fermés.
J'ai donc écrit macro pour la première colonne.

 Sub CalcReturns()
' CalcReturns
Dim row As Integer

Worksheets("Returns").Activate
row = 3
Do While Cells(row, 1) <> ""
Cells(row, 2).Value = Worksheets("Close").Cells(row, 2).Value / _
Worksheets("Close").Cells(row - 1, 2).Value - 1

row = row + 1
Loop
End Sub

Ma question est comment faire pour ajouter la deuxième boucle pour faire le calcul ci-dessus, pour autant que les données sont dans les colonnes de la première ligne.
J'ai essayé d'étudier l'utilisation de boucles, mais j'ai été capable de faire juste un, non pas de multiples Merci d'avance!

InformationsquelleAutor user3703785 | 2014-07-03

Vous pouvez imbriquer des boucles:

Do while firstCondition
    Do while secondCondition

    Loop
Loop

Je ne suis pas sûr si c'est ce que vous voulez faire, mais vous pouvez ajouter une boucle imbriquée pour votre code comme ci-dessous:

Sub CalcReturns()
' CalcReturns
Dim row As Integer

Worksheets("Returns").Activate
row = 3
'first loop
Do While Cells(row, 1) <> ""
    col = 2
    'second loop
    Do While Cells(row,col)<>""
        Cells(row, col).Value = Worksheets("Close").Cells(row, col).Value / _
        Worksheets("Close").Cells(row - 1, col).Value - 1
        col = col+1
    Loop
row = row + 1
Loop
End Sub

InformationsquelleAutor MatthewHagemann

Sub CalcReturns()
  ' CalcReturns
  Dim row As Integer

  Worksheets("Returns").Activate
  row = 3
  do until isempty(cells(row,1))
    col = 2
    do until isempty(cells(row,col))
      Cells(row, col).Value = Worksheets("Close").Cells(row, col).Value / _
      Worksheets("Close").Cells(row - 1, col).Value - 1
      col = col+1
    Loop
    row = row + 1
  Loop
End Sub

Évitez les sélections et les activations

InformationsquelleAutor r_hudson

Je n'ai pas bien comprendre pourquoi vous avez besoin de la boucle imbriquée, mais voici un exemple de imbriquée boucle do while plus une solution de rechange.

Le code fonctionne sur l'hypothèse que vous avez votre nom de feuille de calcul "Proximité" avec les cours de clôture quotidiens (pour les actions A et les actions B) et la date de la première colonne.

Stock A Stock B
01.12.2018  1000    345
02.12.2018  1002    350
03.12.2018  1001    351
04.12.2018  1003    352
05.12.2018  1005    348
06.12.2018  1006    349
07.12.2018  1005    352

En Plus d'une deuxième feuille de calcul nommée "Retour" dans lequel vous avez la même structure pour le stockage, le quotidien de données de retour.

Stock A Stock B
01.12.2018      
02.12.2018  0.20%   1.45%
03.12.2018  -0.10%  0.29%
04.12.2018  0.20%   0.28%
05.12.2018  0.20%   -1.14%
06.12.2018  0.10%   0.29%
07.12.2018  -0.10%  0.86%

Le code calcule le rendement quotidien pour toutes les dates pour les actions A et continue ensuite avec le bouillon de B (et des stocks supplémentaires que vous pourriez ajouter à la feuille).

Voici la solution à l'aide de imbriquée faire des boucles while:

Sub CalculateReturns_UsingDoWhile()

    Dim wsC As Worksheet, wsR As Worksheet
    Dim lngRow As Long, lngCol As Long

    Set wsC = Worksheets("Close")
    Set wsR = Worksheets("Return")

    lngCol = 2
    Do While wsC.Cells(2, lngCol) <> vbNullString
        lngRow = 3
        Do While wsC.Cells(lngRow, lngCol).Value <> vbNullString
            wsR.Cells(lngRow, lngCol).Value = wsC.Cells(lngRow, lngCol).Value / wsC.Cells(lngRow - 1, lngCol).Value - 1
            lngRow = lngRow + 1
        Loop

        lngCol = lngCol + 1
    Loop

End Sub

Personnellement, j'aime l'approche alternative de l'aide Pour les boucles, car il y a beaucoup moins de risque de créer des boucles infinies et je le trouve plus facile à lire. Les deux extraits de code en faire de même, et vous pouvez les choisir selon votre goût. 🙂

Sub CalculateReturns_UsingFor()

    Dim wsC As Worksheet, wsR As Worksheet
    Dim lngRow As Long, lngCol As Long

    Set wsC = Worksheets("Close")
    Set wsR = Worksheets("Return")

    For lngCol = 2 To wsC.Range("B1").End(xlToRight).Column
        For lngRow = 3 To wsC.Range("A2").End(xlDown).Row
            If wsC.Cells(lngRow, lngCol).Value <> vbNullString Then
                wsR.Cells(lngRow, lngCol).Value = wsC.Cells(lngRow, lngCol).Value / wsC.Cells(lngRow - 1, lngCol).Value - 1
            End If
        Next
    Next

End Sub

InformationsquelleAutor tk78

Vous devez vous connecter pour publier un commentaire.