à l'aide de VBscript pour extraire des données XML à partir des nœuds et des enfants

Le low-tech "modèle de conception" pour la première moitié de votre problème
la création et l'écriture d'un .CSV/.TXT fichier - est:

Get an FSO
Open traget file for writing
WriteLine Header (optional)
Loop over your data to export
    Create empty Array (elements ~ columns)
    Fill elements (if possible)
    WriteLine Join(Array, Delimiter) to traget file
Close file

Dans le code:

  Option Explicit
  Dim oFS     : Set oFS = CreateObject("Scripting.FileSystemObject")
  Dim sFSpec  : sFSpec  = "..\data\step00.csv"
  Dim sDelim  : sDelim  = ";"
  Dim aFields : aFields = Split("Yr ANum Amnt Delq FWNum")
  Dim oTS     : Set oTS = oFS.CreateTextFile(sFSpec)
  Dim nRecs   : nRecs   = 10
  Dim nRec
  oTS.WriteLine Join(aFields, sDelim)
  For nRec = 1 To nRecs
      ReDim aData(UBound(aFields))
      aData(0) = nRec
      If nRec Mod 2 Then aData(1) = "odd"

      oTS.WriteLine Join(aData, sDelim)
  Next
  oTS.Close

  WScript.Echo oFS.OpenTextFile(sFSpec).ReadAll()

De sortie:

Yr;ANum;Amnt;Delq;FWNum
1;odd;;;
2;;;;
3;odd;;;
4;;;;
5;odd;;;
6;;;;
7;odd;;;
8;;;;
9;odd;;;
10;;;;

S'il vous plaît marquer la différence entre

oTS.WriteLine Join(aData, sDelim)

et

objFileToWrite.WriteLine(strYear & "," & strAccount & "," & strCurrAmt & "," & strHasDelq & "," & strWarNum)
(spurious param list (), btw)

Un squelette pour la deuxième partie de boucle de plus structurés XML doit
ressembler à ceci

Get an msxml2.domdocument
Configure
Load .XML file
If error
   deal with it
Else
   use top level XPath to get your top level nodelist
   Loop nodelist
      handle sub-parts
End If

dans le code:

  Option Explicit
  Dim oFS     : Set oFS = CreateObject("Scripting.FileSystemObject")
  Dim sFSpec  : sFSpec  = oFS.GetAbsolutePathName("..\data\step01.xml")
  WScript.Echo oFS.OpenTextFile(sFSpec).ReadAll()

  Dim oXD : Set oXD = CreateObject("msxml2.domdocument")
  oXD.setProperty "SelectionLanguage", "XPath"
  oXD.async = False
  oXD.load sFSpec
  If oXD.parseError.errorCode Then
     WScript.Echo "fail", sFSpec
     WScript.Echo oXD.parseError.reason
  Else
     WScript.Echo "ok", sFSpec
     Dim ndlBills : Set ndlBills = oXD.selectNodes("/Bills/BillData/BillHeader")
     If ndlBills.length Then
        WScript.Echo ndlBills.length, "bill nodes"
        Dim ndBill
        For Each ndBill In ndlBills
            Dim ndSub
            Set ndSub = ndBill.selectSingleNode("Year")
            If ndSub Is Nothing Then
               WScript.Echo "no Year"
            Else
               WScript.Echo "Year", ndSub.text
            End If
            Set ndSub = ndBill.selectSingleNode("PayAmounts/CurrentAmountDue")
            If ndSub Is Nothing Then
               WScript.Echo "no Amount"
            Else
               WScript.Echo "Amount", ndSub.text
            End If
        Next
     End If
  End If

de sortie:

<?xml version="1.0" encoding="utf-8" ?>
<Bills>
 <BillData>
  <BillHeader>
   <Year>2012</Year>
  </BillHeader>
 </BillData>
 <BillData>
  <BillHeader>
   <PayAmounts>
    <CurrentAmountDue>123.45</CurrentAmountDue>
   </PayAmounts>
  </BillHeader>
 </BillData>
</Bills>

ok E:\trials\SoTrials\answers571565\data\Step01.xml
2 bill nodes
Year 2012
no Amount
no Year
Amount 123.45

Que vous voulez placer les données de chaque BillHeader dans une ligne de la .CSV et
éléments est manquant, ne prenez pas le risque de mal mappages par l'utilisation de //ou dans d'autres types de
lâche requêtes. Juste obtenir une liste de tous "/Factures/BillData/BillHeader" et de l'exploration.

La fusion des deux scripts:

  Option Explicit
Dim oFS     : Set oFS = CreateObject("Scripting.FileSystemObject")
Dim sXFSpec : sXFSpec = oFS.GetAbsolutePathName("..\data\step02.xml")
WScript.Echo oFS.OpenTextFile(sXFSpec).ReadAll()
Dim sCFSpec : sCFSpec = "..\data\step02.csv"
Dim sDelim  : sDelim  = ","
Dim aFields : aFields = Split("Yr ANum Amnt Delq FWNum")
Dim oTS     : Set oTS = oFS.CreateTextFile(sCFSpec)
oTS.WriteLine Join(aFields, sDelim)
Dim oXD : Set oXD = CreateObject("msxml2.domdocument")
oXD.setProperty "SelectionLanguage", "XPath"
oXD.async = False
oXD.load sXFSpec
If oXD.parseError.errorCode Then
WScript.Echo "fail", sXFSpec
WScript.Echo oXD.parseError.reason
Else
WScript.Echo "ok", sXFSpec
Dim ndlBills : Set ndlBills = oXD.selectNodes("/Bills/BillData/BillHeader")
If ndlBills.length Then
WScript.Echo ndlBills.length, "bill nodes"
Dim ndBill
For Each ndBill In ndlBills
ReDim aData(UBound(aFields))
Dim ndSub
Set ndSub = ndBill.selectSingleNode("Year")
If Not ndSub Is Nothing Then
aData(0) = ndSub.text
End If
Set ndSub = ndBill.selectSingleNode("PayAmounts/CurrentAmountDue")
If Not ndSub Is Nothing Then
aData(2) = ndSub.text
End If
oTS.WriteLine Join(aData, sDelim)
Next
End If
End If
oTS.Close
WScript.Echo oFS.OpenTextFile(sCFSpec).ReadAll()

de sortie:

<?xml version="1.0" encoding="utf-8" ?>
<Bills>
<BillData>
<BillHeader>
<Year>2012</Year>
</BillHeader>
</BillData>
<BillHeader>
<Year>0000</Year>
<PayAmounts>
<CurrentAmountDue>0.0</CurrentAmountDue>
</PayAmounts>
<junk/>
</BillHeader>
<BillData>
<BillHeader>
<PayAmounts>
<CurrentAmountDue>123.45</CurrentAmountDue>
</PayAmounts>
</BillHeader>
</BillData>
<BillData>
<BillHeader>
<Year>2013</Year>
<PayAmounts>
<CurrentAmountDue>47.11</CurrentAmountDue>
</PayAmounts>
</BillHeader>
</BillData>
</Bills>
ok E:\trials\SoTrials\answers\19571565\data\Step02.xml
3 bill nodes
Yr,ANum,Amnt,Delq,FWNum
2012,,,,
,,123.45,,
2013,,47.11,,

À résoudre votre problème, vous pouvez tisser en plus SI les clauses
comme

Set ndSub = ndBill.selectSingleNode("XPath")
If Not ndSub Is Nothing Then
aData(N) = ndSub.text
End If

ou - probablement mieux dans le long terme

Définir un tableau de requêtes (dans l'ordre des champs)

Dim aQueries : aQueries = Array( _
"L'année" _
"PayAmounts/CurrentAmountDue" _
)

Réduire les recoins les plus profonds de la boucle de

Dim ndBill
For Each ndBill In ndlBills
oTS.WriteLine Join(getData(ndBill, aQueries), sDelim)
Next

Définir getData()

Function getData(ndBill, aQueries)
Dim nUb : nUb = UBound(aQueries)
ReDim aData(nUb)
Dim q
For q = 0 To nUb
Dim ndSub
Set ndSub = ndBill.selectSingleNode(aQueries(q))
If Not ndSub Is Nothing Then
aData(q) = ndSub.text
End If
Next
getData = aData
End Function