Access VBA supprimer CR & LF seulement à partir du début d'une chaîne de texte en recherchant pour eux

J'ai besoin de supprimer les sauts de ligne à partir du début d'une note de service type de dossiers. Je ne veux pas utiliser la fonction remplacer car elle permettrait de supprimer tous les sauts de ligne à partir de l'enregistrement qui n'est pas souhaité. Son seul les sauts de ligne au début du champ que je suis intéressé par la suppression de.

Par ailleurs, le mes dossiers ne sont pas toujours commencer avec un saut de ligne donc je ne peux pas vraiment utiliser le texte de positionnement, la solution serait de chercher pour le saut de ligne au début au lieu de toujours attendre au début.

OriginalL'auteur uZI | 2010-03-28

ms-access vba

4
```
If Len(string) > 0 Then
   Do While Left(string,1)= chr(13) Or Left(string,1)= chr(10) or Left(string,1) = " "
     string = Right(string, len(string)-1)
   Loop
End If
```
Ce sera assurez-vous que la chaîne n'est pas vide, puis exécute une boucle simple pour supprimer le caractère la plus à gauche tant qu'il est une CR (chr(13)), LF (chr(10)), ou un espace (" ").

Une fois que la boucle frappe le premier caractère qui ne correspond pas aux critères, il s'arrête et vous avez le résultat souhaité de découper l'ensemble des CR, LF, et de l'espace uniquement des caractères à partir du début de la chaîne.

Depuis qu'il est relativement court, je viens de le mettre dans la procédure d'événement en cas de besoin, vous pouvez également le modifier pour être une fonction publique dans un module, si vous voyez l'ajustement.

OriginalL'auteur SBinVA

Remplacer ne pas remplacer toutes les occurences lorsque vous utilisez le comte argument: http://office.microsoft.com/en-us/access/HA012288981033.aspx

Vous pouvez tester donc:

s1 = vbCrLf & "abc"
s2 = "ab" & vbCrLf & "c"

MsgBox "---" & IIf(Left(s1, 2) = vbCrLf, Replace(s1, vbCrLf, "", , 1), s1)
MsgBox "---" & IIf(Left(s2, 2) = vbCrLf, Replace(s2, vbCrLf, "", , 1), s2)

OriginalL'auteur Fionnuala

1

Amélioration sur ce SBinVA a écrit

Le code suivant n'a pas besoin de l'instruction if et il est facile de les étendre à plus de caractère (espace, tabulation, etc.).

(Il suppose également des sauts de ligne peut provenir d'un fichier provenant d'autres systèmes, de sorte que vbCr et vbLf sont utilisés séparément, qui prend soin de tous les scénarios).
```
Public Function trimCrOrLf(ByVal s As String) As String
  Dim firstChar As String

  firstChar = Left(s, 1)
  Do While InStr(vbCr & vbLf, firstChar) > 0
    s = Mid(s, 2)
    firstChar = Left(s, 1)
  Loop
  trimCrOrLf = s
End Function
```
Grand, prenez votre temps

OriginalL'auteur Magnus

Envisager une instruction SQL UPDATE de jeter seulement ceux CRLF au début de chaque champ mémo.

UPDATE MyTable SET MyTable.memo_field = Mid([memo_field],3)
WHERE (((MyTable.memo_field) Like Chr(13) & Chr(10) & "*"));

OriginalL'auteur HansUp

0
```
Private Sub TestLineFeed()
Dim strString$, strTestChar, booStartsWith_CR As Boolean

strString = Chr$(13) & "some text"

strTestChar = "2"
'strTestChar = Chr$(13)   ''This is a CR.  

booStartsWith_CR = (Left(strString, 1) = strTestChar)

Debug.Print "-----"
Debug.Print "Raw: " & strString
Debug.Print booStartsWith_CR

If booStartsWith_CR Then
    strString = Mid(strString, 2, 100)
End If

Debug.Print "-----"
Debug.Print "New: " & strString
End Sub
```
Note alternatives pour strTestChar de sorte que vous pouvez voir l'action. Vous devriez noter "-----" dans votre Fenêtre d'exécution est suivie par un CR, donc une ligne vide; et ce peut être retiré. Mi(strString, 2, 100) aura besoin de quelques ajustements, mais l'idée est de copier sur votre chaîne de note sans le premier caractère.

Votre idée serait beaucoup plus utile si elle était construite autour de la réalité, c'est à dire, sur Windows, c'est CrLf, pas seulement Cr, qui est utilisé pour les fins de ligne. Dans le code, vous n'avez pas besoin d'utiliser Chr(13) & Chr(10) pour cela, mais vous pouvez utiliser la prédéfinis VBA constante vbCrLf.

OriginalL'auteur Smandoli

Je voudrais utiliser une fonction comme celle-ci. C'est assez simple et facilement adaptable à d'autres circonstances. Par exemple, pour supprimer les espaces en trop, ajouter un test à la if (c = vbCr) ligne.

Function LTrimCRLF(s As String) As String
  Dim index As Integer, start As Integer, strLen As Integer
  Dim c As String

  strLen = Len(s)
  index = 1
  start = -1

  Do While (index <= strLen) And (start = -1)
    c = Mid(s, index, 1)

    If (c = vbCr) Or (c = vbLf) Then
      index = index + 1
    Else
      start = index
    End If
  Loop

  If start = -1 Then
    LTrimCRLF = ""
  Else
    LTrimCRLF = Mid(s, start)
  End If
End Function

Voici un test de routine:

Sub TestLTrimCRLF()
  Dim withWS As String, noWS As String, blank As String, onlyWS As String

  withWS = vbCrLf & "  this string has leading white space"
  noWS = "this string has no leading white space"
  onlyWS = vbCrLf & " " & vbCrLf & " "
  blank = ""

  Say "with WS: {" & LTrimCRLF(withWS) & "}"
  Say "no WS:   {" & LTrimCRLF(noWS) & "}"
  Say "only WS: {" & LTrimCRLF(onlyWS) & "}"
  Say "blank:   {" & LTrimCRLF(blank) & "}"
End Sub

BTW, j'ai essayé de regarder votre échantillon de données, mais il est dit que le document n'est pas disponible. Peut-être vous avez besoin de la rendre publique ou de quelque chose?

OriginalL'auteur Todd

Ma contribution à VBA trimwhitespace() de la fonction, boucle retrouve pour le premier non-blanc index, divise une chaîne de caractères, puis même chose pour la fuite d'espaces. Gauche+Droite fonctions sont exécutées qu'une seule fois. Si vous avez besoin d'leftTrim ou rightTrim il est facile d'introduire de nouveaux arguments ou des fonctions distinctes.

Function trimWhitespace(str As String) As String
    Dim idx As Long
    Dim ch As String
    ' LeftTrim
    If Len(str) > 0 Then
        idx = 1
        ch = Mid(str, idx, 1)
        Do While ch = Chr(13) Or ch = Chr(10) Or ch = " "
            idx = idx + 1
            ch = Mid(str, idx, 1)
        Loop
        If (idx > 1) Then str = Right(str, Len(str) - idx)
    End If
    ' RightTrim
    idx = Len(str)
    If idx > 0 Then
        ch = Mid(str, idx, 1)
        Do While ch = Chr(13) Or ch = Chr(10) Or ch = " "
            idx = idx - 1
            ch = Mid(str, idx, 1)
        Loop
        If (idx < Len(str)) Then str = Left(str, idx)
    End If

    trimWhitespace = str
End Function

OriginalL'auteur Whome

Ce sera couper tous les principaux et espaces, retours à la ligne, tabulations, et d'autres caractères non-imprimables.

Public Function TrimSpecial(InputString As Variant) As String
' This will trim leading/trailing spaces and non-printable characters from the passed string.

    Dim i As Integer
    Dim str As String

    On Error GoTo ErrorHandler

    str = InputString

    For i = 1 To Len(str)
        If Asc(Mid(str, i, 1)) > 32 And Asc(Mid(str, i, 1)) < 127 Then
            ' Valid character found.  Truncate leading characters before this.
            str = Mid(str, i)
            Exit For
        End If
    Next i

    For i = Len(str) To 1 Step -1
        If Asc(Mid(str, i, 1)) > 32 And Asc(Mid(str, i, 1)) < 127 Then
            ' Valid character found.  Truncate trailing characters after this.
            str = Mid(str, 1, i)
            Exit For
        End If
    Next i

    TrimSpecial = str

Exit_Function:
    Exit Function

ErrorHandler:
    MsgBox "Error #" & Err.Number & " - " & Err.Description & vbCrLf & "in procedure TrimSpecial"
    GoTo Exit_Function
    Resume Next
    Resume

End Function

Vous pouvez utiliser cette routine pour tester:

Public Sub Test_TrimSpecial()
    ' Run this to test the TrimSpecial function.
    Dim x As String

    x = vbCrLf & " " & vbTab & " ab cd" & vbCrLf & vbTab & " xyz " & vbCr & vbCrLf
    Debug.Print "-----"
    Debug.Print ">" & x & "<"
    Debug.Print "-----"
    Debug.Print ">" & TrimSpecial(x) & "<"
    Debug.Print "-----"
End Sub

OriginalL'auteur Ben

Vous devez vous connecter pour publier un commentaire.