afficher les données du jeu d'enregistrements dans la fenêtre exécution

J'ai un jeu d'enregistrements rst avec 2 colonnes/champs ID et Value. Le jeu d'enregistrements a plusieurs lignes. Pendant le débogage, je suis en mesure d'afficher des enregistrements dans la première ligne du jeu dans la fenêtre d'exécution en utilisant les instructions suivantes.

?rst.fields(0)
?rst.fields(1)

Mais je ne suis pas en mesure d'afficher les données en 2ème ou 100e de ligne?

Pas directement la réponse à votre question, mais j'ai trouvé DoCmd.OpenQuery "someQueryDef" être très utile Immédiate de la fenêtre quand je veux naviguer sur un ensemble de résultats de la requête.

OriginalL'auteur Heman | 2011-12-14

  1. 7

    Relatives au déplacement par le biais d'un jeu d'enregistrements DAO et le commentaire de @nyarlathotep:

    Dim rs As DAO.Recordset
Set rs = CurrentDb.OpenRecordset("SELECT * FROM tbljournaltitles")

Debug.Print rs(0).Name
Debug.Print rs(0)
Debug.Print rs("MyText")

rs.Move 10
Debug.Print rs(0)

rs.Move -4
Debug.Print rs(0)

''Find does not work with all recordset types
rs.FindFirst "MyText Like 'Text*'"
Debug.Print rs(0)
    Merci, c'est très utile.

    OriginalL'auteur Fionnuala

  2. 1

    Vous auriez à effectuer une itération sur les lignes pour obtenir leurs données. Vous pourriez par exemple faire la suite de boucle simple:

    Do While Not rst.EOF
    'Do something with the data
    rst.MoveNext
Loop
    merci cela fonctionne. mais existe-il des commandes pour afficher des données à un particulier de ligne et de colonne autre que le déplacement de cette ligne. étant donné que je vais avoir à utiliser movenext 100 fois avant que je puisse afficher les données en 100e de ligne.
    Pas toutes les données est nécessairement dans la mémoire en même temps lors de l'utilisation d'un jeu d'enregistrements, donc je pense qu'il n'y a pas d'autre moyen que d'itérer. Mais vous pouvez stocker les lignes dans une sorte de structure de données de votre choix, et de vérifier que la structure de données par la suite
    Il est en effet possible de se déplacer par l'intermédiaire d'un jeu d'enregistrements sans itération. J'ai posté un supplément à cette réponse.

    OriginalL'auteur codeling

  3. 0

    Exploitant les réponses de @Fionnualla et @codeling (et l'ajout de fermeture & nettoyage pour le jeu d'enregistrements), en ajoutant également de l'aide de VBA: Debug.Imprimer sans retour à la ligne? pour rendre cela plus comme une table (encore besoin de travailler sur la fabrication de colonnes, la largeur réelle de la taille max du col).

    Cette procédure permet d'imprimer toute requête que vous tomber sur elle.

    Public Sub debugPrintQuery(ByVal myQuery As String)
Dim rs As DAO.Recordset
Set rs = CurrentDb.OpenRecordset(myQuery)

' print column names
Dim i As Integer
For i = 0 To rs.Fields.Count - 2
    Debug.Print rs(i).Name & vbTab; 'print col names separated with a tab one from each other
Next i
Debug.Print rs(rs.Fields.Count - 1).Name 'last one without ; so it adds the newline

Do While Not rs.EOF
    For i = 0 To rs.Fields.Count - 2
        Debug.Print rs(i) & vbTab; 'print values separated with a tab one from each other
    Next i
    Debug.Print rs(rs.Fields.Count - 1) 'last one without ; so it adds the newline
    rs.MoveNext
Loop

rs.Close 'Close the recordset
Set rs = Nothing 'Clean up

End Sub

    OriginalL'auteur Daniel Neumann