Ajouter d'un seul point à un graphe existant

J'utilise le script suivant pour s'adapter à une fonction sur un terrain. Dans la sortie de l'intrigue, j'aimerais ajouter une valeur unique avec l'étiquette sur le côté de la courbe permet de dire que le point f(3.25). J'ai lu que pour gnuplot est très difficile d'ajouter un point unique sur un terrain particulièrement lorsque cette parcelle est d'un côté d'une fonction de traçage.

A quelqu'un a une idée de la façon d'ajouter ce point unique sur le terrain?

set xlabel "1000/T (K^-^1)" font "Helvetica,20"    
#set ylabel "-log(tau_c)"       font "Helvetica,20"    
set ylabel "-log{/Symbol t}_c (ns)"     font "Helvetica,20"    
set title  "$system $type $method"        font "Helvetica,24"    
set xtics      font "Helvetica Bold, 18"                                  
set ytics      font "Helvetica Bold, 18"                                  
#set xrange[0:4]
set border linewidth 3
set xtic auto                          # set xtics automatically
set ytic auto                          # set ytics automatically
#set key on bottom  box lw 3 width 8 height .5 spacing 4 font "Helvetica, 24"
set key  box lw 3 width 4 height .5 spacing 4 font "Helvetica, 24"

set yrange[-5:]
set xrange[1.5:8]
f(x)=A+B*x/(1000-C*x)

A=1 ;B=-227 ; C=245

fit  f(x) "$plot1" u (1000/\$1):(-log10(\$2)) via A,B,C

plot [1.5:8] f(x)  ti "VFT" lw 4,  "$plot1" u (1000/\$1):(-log10(\$2)) ti "$system $type" lw 10



#set key on bottom  box lw 3 width 8 height .5 spacing 4 font "Helvetica, 24"

set terminal postscript eps color dl 2 lw 1 enhanced # font "Helvetica,20"

set output "KWW.eps"                                              



replot

Voulez-vous ajouter un point, c'est à dire un cercle plein, ou faut-il utiliser l'un des styles?
Si ce n'est pas un problème, pouvez-vous montrer deux façons de faire?

OriginalL'auteur Samanosuke Akechi | 2013-10-18

gnuplot

17

Il y a plusieurs possibilités pour définir un point/point:

1. l'objet du jeu

Si vous avez des points simples, comme un cercle, un cercle de coin ou d'un carré, vous pouvez utiliser set object, qui doit être de définir avant l' plot commande:
```
set object circle at first -5,5 radius char 0.5 \
    fillstyle empty border lc rgb '#aa1100' lw 2
set object circle at graph 0.5,0.9 radius char 1 arc [0:-90] \
    fillcolor rgb 'red' fillstyle solid noborder
set object rectangle at screen 0.6, 0.2 size char 1, char 0.6 \
    fillcolor rgb 'blue' fillstyle solid border lt 2 lw 2

plot x
```
Pour ajouter une étiquette, vous devez utiliser set label.

Cela peut être lourd, mais a l'avantage que vous pouvez utiliser différentes lignes et les couleurs de remplissage, et vous pouvez utiliser différents systèmes de coordonnées (first, graph, screen etc).

Le résultat avec 4.6.4 est:

2. Vide étiquette avec option de point

La set label commande a un point option, qui peut être utilisé pour définir un point de partir de l'existant types de points à un certain coordonnées:
```
set label at xPos, yPos, zPos "" point pointtype 7 pointsize 2
```
3. parcelle avec un '+'

La dernière possibilité est d'utiliser le nom de fichier +, ce qui génère un ensemble de coordonnées, qui sont ensuite filtrées, et tracée à l'aide de la labels tracé de style (ou points si aucune étiquette n'est demandé:
```
f(x) = x**2
x1 = 2

set xrange[-5:5]
set style line 1 pointtype 7 linecolor rgb '#22aa22' pointsize 2
plot f(x), \
     '+' using ($0 == 0 ? x1 : NaN):(f(x1)):(sprintf('f(%.1f)', x1)) \
     with labels offset char 1,-0.2 left textcolor rgb 'blue' \
     point linestyle 1 notitle
```
$0, ou, de manière équivalente column(0), les coordonnées de l'index. Dans le using déclaration seul le premier est pris comme valide, toutes les autres sont ignorés (à l'aide de NaN).

Noter que l'utilisation de + nécessite la définition d'un fixe xrange.

Ce qui a des avantages (ou les inconvénients?):
1. Vous pouvez utiliser l'habituel pointtype.
2. Vous ne pouvez utiliser que les valeurs de l'axe que les coordonnées (comme first ou second pour les objets ci-dessus).
3. Il peut devenir plus difficile à placer les différents types de points.
4. Il est plus impliqué à l'aide de différents frontière et les couleurs de remplissage.
Le résultat est:

OriginalL'auteur Christoph
5

L'ajout de Christoph excellentes réponses :

4. utilisation stdin à la pipe dans le seul point
```
replot "-" using 1:(f($1))
2.0
e
```
et d'utiliser la méthode dans la 3ème réponse à l'étiquette.

5. cuire un nommé datablock
(version > 5.0) qui contient un seul point, alors vous pouvez replot sans le ravitaillement de tous les temps:
```
$point << EOD
2.0
EOD
replot $point using 1:(f($1)):(sprintf("%.2f",f($1))) with labels
```
OriginalL'auteur Karl

Vous devez vous connecter pour publier un commentaire.

1. l'objet du jeu

2. Vide étiquette avec option de point

3. parcelle avec un '+'