Ajouter un enfant à l'entrée de nœud spécifique dans le fichier xml dans vbscipt

XmlDocument.CreateElement accepte trois paramètres: un type de nœud, un nœud de nom, et d'un espace de noms.
Dans votre exemple, car votre enfant de l'élément nommé "ajouter", c'est un élément (type==1), et il est le cadre global de la espace de noms xml, vous appelez xmlDoc.CreateElement(1, "add", "") .

Qui vous donne un élément vide. Pour insérer les données que vous voulez (l' Context="General" attribut, et tous les éléments d'enfant), vous pourriez alors avoir besoin de faire des appels successifs à la manipulation du DOM méthodes, ajouter à chaque élément enfant, chaque attribut, et ainsi de suite. Assez laborieux.

Mais vous avez déjà le fragment xml comme une chaîne de caractères. Ainsi, au lieu de la création de l'élément en utilisant les méthodes du DOM, ce que vous pouvez faire est de créer un 2ème XmlDocument et dites-lui pour obtenir son contenu à partir de la chaîne. Puis, prenez le documentElement de cette 2ème doc. Appelez ensuite appendChild sur le nœud approprié dans le premier doc, en passant le documentElement à partir de la 2ème doc.

quelque chose comme ceci:

Function GetElementFromXmlString(xmlString)
    Dim doc
    set doc = CreateObject("Msxml2.DOMDocument.6.0")
    doc.async = False
    doc.preserveWhiteSpace= False
    doc.loadXML(xmlString)
    Set GetElementFromXmlString = doc.documentElement
End Function

Sub Main()
    Set doc1 = CreateObject("Msxml2.DOMDocument.6.0")
    doc1.async = False
    doc1.preserveWhiteSpace= False ' True
    doc1.load("DataConfiguration.xml")

    ' generate an Element from an XML string
    Dim xmlString
    xmlString = "<add context=""General"">" & _
                  " <parameter name=""timeout"" type=""int"" defaultvalue=""60""/>" & _
                  " <parameter name=""address"" type=""string"" defaultvalue=""192.168.9.478"" />" & _
                  " <parameter name=""port"" type=""int"" defaultvalue=""5674""/>"& _
              "</add>"
    Dim newElt
    Set newElt = GetElementFromXmlString(xmlString)

    ' get the first child node of type=Element under the document root element in
    ' doc1.  This is not the same as  doc1.documentElement.firstChild.  There can
    ' be text nodes, etc.
    Dim node1
    Set node1 = doc1.documentElement.selectSingleNode("./*[position()=1]")

    ' append the element to the node
    node1.appendChild(newElt)

    WScript.echo (PrettyPrintXml (doc1))
End Sub

Main()

...où le PrettyPrintXml fonction est définie comme ceci:

Function PrettyPrintXml(xmldoc)
    Dim reader
    set reader = CreateObject("Msxml2.SAXXMLReader.6.0")
    Dim writer
    set writer = CreateObject("Msxml2.MXXMLWriter.6.0")
    writer.indent = True
    writer.omitXMLDeclaration = True
    reader.contentHandler = writer
    reader.putProperty "http://xml.org/sax/properties/lexical-handler", writer
    reader.parse(xmldoc)
    PrettyPrintXml = writer.output
End Function

La sortie de cette, pour moi, est:

<DataSource>
  <localdata>
    <add context="Localization">
      <parameter name="timeout" type="int" defaultvalue="60"/>
      <parameter name="address" type="string" defaultvalue="192.168.9.45"/>
      <parameter name="port" type="int" defaultvalue="6789"/>
    </add>
    <add context="General">
      <parameter name="timeout" type="int" defaultvalue="60"/>
      <parameter name="address" type="string" defaultvalue="192.168.9.478"/>
      <parameter name="port" type="int" defaultvalue="5674"/>
    </add>
  </localdata>
</DataSource>