Analyse de flux JSON automatiquement dans MS Access

À l'aide de la VBA JSON de la bibliothèque, vous pouvez importer des fichiers au format JSON dans MS Access. L'idée est de considérer les données JSON comme une collection de dictionnaires et de Visual Basic fournit le collection et dictionnaire que les structures de données.

Ci-dessous sont les étapes suivantes:

1. Construire une table pour correspondre à la structure attendue de données JSON
2. Sur le VBA IDE côté de MS Access, l'importation de l' JsonConverter.bas (à partir du lien ci-dessus) dans un nouveau module
3. Encore dans l'IDE, dans le menu Outils /Références, cochez la Référence VBA: Microsoft Scripting Runtime
4. Inclure le code suivant lit le JSON fichier texte, il analyse comme une collection de dictionnaires (avec les clés et les valeus), et ajoute les valeurs de manière itérative dans la table Access. Placez le code derrière un formulaire d'Accès ou d'un module (exemple utilise un niveau imbriqué fichier JSON)

JSON

[
  {
    "col1": somenumber,
    "col2": "somestring",
    "col3": "somestring",
    "col4": "somestring",
    "col5": "somestring"
  }
]

Code VBA

Private Function JSONImport()
    Dim db As Database, qdef As Querydef
    Dim FileNum As Integer
    Dim DataLine As String, jsonStr As String, strSQL As String
    Dim p As Object, element As Variant        

    Set db = CurrentDb

    ' READ FROM EXTERNAL FILE
    FileNum = FreeFile()
    Open "C:\Path\To\JsonFile.json" For Input As #FileNum

    ' PARSE FILE STRING
    jsonStr = ""
    While Not EOF(FileNum)
        Line Input #FileNum, DataLine

        jsonStr = jsonStr & DataLine & vbNewLine
    Wend
    Close #FileNum
    Set p = ParseJson(jsonStr)

    ' ITERATE THROUGH DATA ROWS, APPENDING TO TABLE
    For Each element In p
        strSQL = "PARAMETERS [col1] Long, [col2] Text(255), [col3] Text(255), " _
                          & "[col4] Text(255), [col5] Text(255); " _
                  & "INSERT INTO TableName (col1, col2, col3, col4, col5) " _
                          & "VALUES([col1], [col2], [col3], [col4], [col5]);"

        Set qdef = db.CreateQueryDef("", strSQL)

        qdef!col1 = element("col1")
        qdef!col2 = element("col2")
        qdef!col3 = element("col3")
        qdef!col4 = element("col4")
        qdef!col5 = element("col5")

        qdef.Execute
    Next element

    Set element = Nothing
    Set p = Nothing
End Function

OriginalL'auteur Parfait