Analyser le texte du fichier avec XSLT

J'ai un fichier texte structuré comme ceci:

!ITEM_NAME
Item value
!ANOTHER_ITEM
Its value
...

Est-il possible d'obtenir avec XSLT un fichier similaires à:

<?xml version="1.0" encoding="UTF-8" ?>
<document>
  <ITEM_NAME>Item value</ITEM_NAME>
  <ANOTHER_ITEM>Its value</ANOTHER_ITEM>
  ...
</document>

MODIFIER

Je suis désolé, je n'ai pas clairement dit avant. Je suis en train d'accomplir cette transformation avec Visual Studio 2005 moteur XSLT. J'ai essayé les deux solutions apportées, et je suis sûr que sont corrects. Mais Visual Studio 2005 ne connaît pas le unparsed-fonction texte.

Ce n'est pas possible, la seule entrée valide pour XSLT est un format Xml bien formé.
conformément à cette question, il est possible de lien
Intéressant. Aujourd'hui, son entrée dans le "Une ampoule pouvez aussi être utilisée pour faire frire un steak." liste ... merci pour le lien 🙂
Ou "à l'aide de canon pour tirer à une mouche". Toute autre suggestion de faire de la saisie de texte fichier de plus "gérable"? Peut-être avec .NET framework? 😉
Cher @O. R. Mappeur, pour info, XSLT 2.0 a été correctement utilisées de façon efficiente et dans la mise en œuvre d'un générique LR-1 analyseur et sur cette base, pour les analyseurs de ces langues JSON et XPath 2.0. L'utilisation moderne de l'analyse des méthodes, ou des expressions régulières où ils sont les plus appropriés est exactement le contraire de "Une ampoule peut également être utilisé pour faire frire un steak".

OriginalL'auteur sblandin | 2013-04-12

  1. 8

    Si vous pouvez utiliser XSLT 2.0, vous pouvez utiliser unparsed-text()...

    Fichier texte (Ne pas utiliser le fichier texte comme une entrée directe à la transformation XSLT.)

    !ITEM_NAME
Item value
!ANOTHER_ITEM
Its value
!TEST_BANG
Here's a value with !bangs!!!

    XSLT 2.0 (Appliquer cette transformation XSLT pour lui-même (utiliser la feuille de style comme le XML d'entrée). Vous allez également avoir à changer le chemin de votre fichier texte. Vous pourriez avoir à changer l'encodage).

    <xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:param name="text-encoding" as="xs:string" select="'iso-8859-1'"/>
    <xsl:param name="text-uri" as="xs:string" select="'file:///C:/Users/dhaley/Desktop/test.txt'"/>

    <xsl:template name="text2xml">
        <xsl:variable name="text" select="unparsed-text($text-uri, $text-encoding)"/>
        <xsl:analyze-string select="$text" regex="!(.*)\n(.*)">
            <xsl:matching-substring>
                <xsl:element name="{normalize-space(regex-group(1))}">
                    <xsl:value-of select="normalize-space(regex-group(2))"/>
                </xsl:element>
            </xsl:matching-substring>
        </xsl:analyze-string>
    </xsl:template>

    <xsl:template match="/">
        <document>
            <xsl:choose>
                <xsl:when test="unparsed-text-available($text-uri, $text-encoding)">
                    <xsl:call-template name="text2xml"/>                                
                </xsl:when>
                <xsl:otherwise>
                    <xsl:variable name="error">
                        <xsl:text>Error reading "</xsl:text>
                        <xsl:value-of select="$text-uri"/>
                        <xsl:text>" (encoding "</xsl:text>
                        <xsl:value-of select="$text-encoding"/>
                        <xsl:text>").</xsl:text>
                    </xsl:variable>
                    <xsl:message><xsl:value-of select="$error"/></xsl:message>
                    <xsl:value-of select="$error"/>
                </xsl:otherwise>
            </xsl:choose>
        </document>
    </xsl:template>
</xsl:stylesheet>

    XML de Sortie

    <document>
   <ITEM_NAME>Item value</ITEM_NAME>
   <ANOTHER_ITEM>Its value</ANOTHER_ITEM>
   <TEST_BANG>Here's a value with !bangs!!!</TEST_BANG>
</document>
    Est imbriquée analyser les cordes nécessaires? Ne pouvez-vous pas simplement utiliser regex="!(.*)\n(.*) à l'extérieur analyser-chaîne, puis extraire le nom et la valeur?
    Oui, et eu quelque chose comme ça à l'origine. Je ne sais pas pourquoi j'ai ajouté dans la. Je mettrai à jour. Merci!!
    Également mis à jour le texte d'entrée/de sortie xml pour afficher les valeurs avec !.

    OriginalL'auteur Daniel Haley

  2. 5

    Cette transformation XSLT 2.0:

    <xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:variable name="vText" select=
 "replace(unparsed-text('file:///c:/temp/delete/text.txt'),'\r','')"/>

 <xsl:template match="/">
  <document>
      <xsl:analyze-string select="$vText" regex="(!(.+?)\n([^\n]+))+">
       <xsl:matching-substring>
         <xsl:element name="{regex-group(2)}">
                <xsl:sequence select="regex-group(3)"/>
         </xsl:element>
       </xsl:matching-substring>
       <xsl:non-matching-substring><xsl:sequence select="."/></xsl:non-matching-substring>
      </xsl:analyze-string>
  </document>
 </xsl:template>
</xsl:stylesheet>

    quand appliedon tout document XML (non utilisé) et d'avoir le texte fourni résidant dans le fichier local C:\temp\delete\Text.txt:

    !ITEM_NAME
Item value
!ANOTHER_ITEM
Its value
...

    produit le voulait, résultat correct:

    <document>
   <ITEM_NAME>Item value</ITEM_NAME>
   <ANOTHER_ITEM>Its value</ANOTHER_ITEM>
...
</document>

    Pour tester plus complètement, nous avons mis ce texte dans le fichier:

    As is text
!ITEM_NAME
Item value
!ANOTHER_ITEM
Its value
As is text2
!TEST_BANG
Here's a value with !bangs!!!
!TEST2_BANG
 !!!Here's a value with !more~ !bangs!!!
As is text3

    La transformation de nouveau produit le voulait, résultat correct:

    <document>As is text
<ITEM_NAME>Item value</ITEM_NAME>
<ANOTHER_ITEM>Its value</ANOTHER_ITEM>
As is text2
<TEST_BANG>Here's a value with !bangs!!!</TEST_BANG>
<TEST2_BANG> !!!Here's a value with !more~ !bangs!!!</TEST2_BANG>
As is text3
</document>
    Merci beaucoup pour toutes ces réponses... je viens de découvrir que Visual Studio 2005 (IDE je suis obligé d'utiliser) analyseur XSLT ne connaît pas le unparsed-fonction texte. Désolé de ne pas fournir assez de contexte.

    OriginalL'auteur Dimitre Novatchev