Android SDK / Android.bat ne trouve pas le fichier SWT.jar

C'est un suivi de la question SDK manager ne trouve pas java mais la question à portée de main maintenant est la SDK/android.bat ne permet pas de localiser le fichier SWT.

---

Je suis sous Windows 7 x64, mon fichier les lieux sont comme suit:

Android SDK (zip version) - C:\android-sdk-windows

SWT.jar (from the Zip)    - C:\android-sdk-windows\tools\lib\x86
                            C:\android-sdk-windows\tools\lib\x86_64

JDK 6 u24 x64             - C:\Program Files\Java\jdk1.6.0_24

---

Mes variables d'environnement sont comme suit:

ANDROID_SWT = C:\android-sdk-windows\tools\lib\x86_64

Path        = ;C:\Program Files\Java\jdk1.6.0_24\bin

---

Je suis en train d'essayer de résoudre le problème suivant.

Lors de l'exécution de l'Android SDK manager, un noir de commande de l'écran clignote rapidement et disparaît, il ne démarre pas le SDK donc je ne peut pas télécharger toutes les plates-formes ni les add-ons.

Remarque que j'ai ces fichiers déjà à partir de la zip (plates-formes et ad-ons)

J'ai tracé le coupable à la android.bat fichier mais n'arrive pas à le comprendre. J'ai défini la variable d'environnement pour le SWT.jar fichier.
Je n'ai pas modifier le .bat fichier dans n'importe quel chemin jusqu'à présent.

---

Voici mon fichier bat et l'erreur est situé près du bas.

@echo off
rem Copyright (C) 2007 The Android Open Source Project
rem
rem Licensed under the Apache License, Version 2.0 (the "License");
rem you may not use this file except in compliance with the License.
rem You may obtain a copy of the License at
rem
rem      http://www.apache.org/licenses/LICENSE-2.0
rem
rem Unless required by applicable law or agreed to in writing, software
rem distributed under the License is distributed on an "AS IS" BASIS,
rem WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
rem See the License for the specific language governing permissions and
rem limitations under the License.
rem Useful links:
rem Command-line reference:
rem   http://technet.microsoft.com/en-us/library/bb490890.aspx
rem don't modify the caller's environment
setlocal
rem Set up prog to be the path of this script, including following symlinks,
rem and set up progdir to be the fully-qualified pathname of its directory.
set prog=%~f0
rem Grab current directory before we change it
set work_dir="%cd%"
rem Change current directory and drive to where the script is, to avoid
rem issues with directories containing whitespaces.
cd /d %~dp0
rem Check we have a valid Java.exe in the path.
set java_exe=
call lib\find_java.bat
if not defined java_exe goto :EOF
set jar_path=lib\sdkmanager.jar
rem Set SWT.Jar path based on current architecture (x86 or x86_64)
for /f %%a in ('%java_exe% -jar lib\archquery.jar') do set swt_path=lib\%%a
if "%1 %2"=="update sdk" goto StartUi
if not "%1"=="" goto EndTempCopy
:StartUi
echo [INFO] Starting Android SDK and AVD Manager
rem We're now going to create a temp dir to hold all the Jar files needed
rem to run the android tool, copy them in the temp dir and finally execute
rem from that path. We do this only when the launcher is run without
rem arguments, to display the SDK Updater UI. This allows the updater to
rem update the tools directory where the updater itself is located.
set tmp_dir=%TEMP%\temp-android-tool
xcopy %swt_path% %tmp_dir%\%swt_path% /I /E /C /G /R /Y /Q > nul
copy /B /D /Y lib\androidprefs.jar   %tmp_dir%\lib\        > nul
copy /B /D /Y lib\org.eclipse.*      %tmp_dir%\lib\        > nul
copy /B /D /Y lib\sdk*               %tmp_dir%\lib\        > nul
copy /B /D /Y lib\common.jar         %tmp_dir%\lib\        > nul
copy /B /D /Y lib\commons-compress*  %tmp_dir%\lib\        > nul
rem jar_path and swt_path are relative to PWD so we don't need to adjust them, just change dirs.
set tools_dir=%cd%
cd /d %tmp_dir%
:EndTempCopy
rem The global ANDROID_SWT always override the SWT.Jar path
if defined ANDROID_SWT set swt_path=%ANDROID_SWT%
if exist %swt_path% goto SetPath
echo ERROR: SWT folder '%swt_path%' does not exist.
echo Please set ANDROID_SWT to point to the folder containing swt.jar for your platform.
goto :EOF
:SetPath
rem Finally exec the java program and end here.
call %java_exe% -Dcom.android.sdkmanager.toolsdir="%tools_dir%" -Dcom.android.sdkmanager.workdir=%work_dir% -classpath "%jar_path%;%swt_path%\swt.jar" com.android.sdkmanager.Main %*
rem EOF

---

C'est ce que je reçois lors de l'exécution de la chauve-souris de fichier via l'invite de commande

C:\Users\MuniFC Portable11>C:\android-sdk-windows\tools\android.bat
[INFO] Starting Android SDK and AVD Manager
'xcopy' is not recognized as an internal or external command, operable program or batch file.
No command line parameters provided, launching UI.
See 'android --help' for operations from the command line.
java.lang.NullPointerException
at com.android.sdklib.internal.avd.AvdManager.parseAvdInfo(AvdManager.java:1205)
at com.android.sdklib.internal.avd.AvdManager.buildAvdList(AvdManager.java:1184)
at com.android.sdklib.internal.avd.AvdManager.<init>(AvdManager.java:385)
at com.android.sdkuilib.internal.repository.UpdaterData.initSdk(UpdaterData.java:238)
at com.android.sdkuilib.internal.repository.UpdaterData.<init>(UpdaterData.java:114)
at com.android.sdkuilib.internal.repository.UpdaterWindowImpl.<init>(UpdaterWindowImpl.java:86)
at com.android.sdkuilib.repository.UpdaterWindow.<init>(UpdaterWindow.java:42)
at com.android.sdkmanager.Main.showMainWindow(Main.java:302)
at com.android.sdkmanager.Main.doAction(Main.java:281)
at com.android.sdkmanager.Main.run(Main.java:99)
at com.android.sdkmanager.Main.main(Main.java:88)`

---

Si vous avez une idée sur comment résoudre ce problème ce serait génial!

---

Mise à JOUR

fixe le xcopy problème en ajoutant la C:\windows\system32 de mes variables de Chemin d'accès, maintenant, la question qui reste en suspens est la SWT

Invite de commande, exécutez Android.bat =

C:\Users\MuniFC Portable11>C:\android-sdk-windows\tools\android.bat
[INFO] Starting Android SDK and AVD Manager
No command line parameters provided, launching UI.
See 'android --help' for operations from the command line.
java.lang.NullPointerException
at com.android.sdklib.internal.avd.AvdManager.parseAvdInfo(AvdManager.java:1205)
at com.android.sdklib.internal.avd.AvdManager.buildAvdList(AvdManager.java:1184)
at com.android.sdklib.internal.avd.AvdManager.<init>(AvdManager.java:385)
at com.android.sdkuilib.internal.repository.UpdaterData.initSdk(UpdaterData.java:238)
at com.android.sdkuilib.internal.repository.UpdaterData.<init>(UpdaterData.java:114)
at com.android.sdkuilib.internal.repository.UpdaterWindowImpl.<init>(UpdaterWindowImpl.java:86)
at com.android.sdkuilib.repository.UpdaterWindow.<init>(UpdaterWindow.java:42)
at com.android.sdkmanager.Main.showMainWindow(Main.java:302)
at com.android.sdkmanager.Main.doAction(Main.java:281)
at com.android.sdkmanager.Main.run(Main.java:99)
at com.android.sdkmanager.Main.main(Main.java:88)
C:\Users\MuniFC Portable11>

source d'informationauteur Chaoticandroid