Apprendre à créer des MouseEvent.CLIQUEZ sur l'événement en AS3 (passer des paramètres à la fonction)?

Vous avez vraiment besoin d'étendre la classe d'événement pour créer votre propre événement avec des paramètres supplémentaires. Placer les fonctions à l'intérieur de la méthode addEventListener (fonctions anonymes) est une recette pour les fuites de mémoire, qui n'est pas bon.
Jetez un oeil à la suivante.

import flash.events.Event;

//custom event class to enable the passing of strings along with the actual event
public class TestEvent extends Event
{
    public static const TYPE1 :String = "type1";
    public static const TYPE2 :String = "type2";
    public static const TYPE3 :String = "type3";

    public var parameterText:String;

    public function TestEvent (type:String, searchText:String)
    {
        this.parameterText = searchText;
        super(type);
    }

}

lorsque vous créez un nouvel événement comme

dispatchEvent(new TestEvent(TestEvent.TYPE1, 'thisIsTheParameterText'))" ;

vous pouvez ensuite écouter pour que l'événement de ce

someComponent.addEventListener(TestEvent.TYPE1, listenerFunction, true , 0, true);

et à l'intérieur de la fonction " listenerFunction de l'événement.parameterText contiendra votre paramètre.

donc à l'intérieur de votre myClips composant d'incendie à l'événement personnalisé et écouter pour que l'événement, et non l'événement Click.

OriginalL'auteur kenneth

Vous pouvez accomplir ceci en obtenant votre gestionnaire d'une fonction qui donne la variable de fermeture, comme ceci:

for (var i=0; i<5; i++) {
    myClips[i].addEventListener( MouseEvent.CLICK, getHandler(i) );
}

function getHandler(i) {
    return function( e:MouseEvent ) {
        test(i);
    }
}

function test( j ) {
    trace("foo "+j);
}

Également, pour laquelle il crée une nouvelle fermeture, vous pourriez vouloir vérifier l'explication dans la accepté de répondre à cette question similaire.

OriginalL'auteur fenomas

Je vois votre objectif principal n'est pas de créer un personnalisé MouseEvent.CLIQUEZ sur, mais pour passer un paramètre à la fonction. Vous n'avez pas besoin d'située dans un endroit compliqué de créer ou d'étendre quoi que ce soit. Il y a un simple et la fermeture de la difficulté pour le faire.

Suffit de faire votre fonction comme ceci:

function doSomething(index:Number):Function {
  return function(e:MouseEvent):void {
    //Use "e" and "index" here. They'll be unique for each addEventListener()
    trace(index);
  }
}

Cette technique peut se rapporter à tout AS3 type d'événement vous pouvez utiliser la méthode addEventListener.

Et maintenant vous pouvez l'ajouter comme ceci:

var functionsDoSomething:Object;

for (var i:Number = 0; i < 10; i++) {
  var someVar:Number = i;
  functionsDoSomething[i] = doSomething(someVar);
  myClips[i].addEventListener(MouseEvent.CLICK, functionsDoSomething[i]);
}

La doSomething(someVar) peut être utilisé directement sur addEventListener(), mais il est préférable de les conserver dans une variable parce que vous serez en mesure de le retirer plus tard la même manière que vous l'avez ajouté:

for (i = 0; i < 10; i++) {
  myClips[i].removeEventListener(MouseEvent.CLICK, functionsDoSomething[i]);
}

Couramment utilisés e.currentTarget.someCustomProperty fonctionne pour les objets dynamiques (c'est à dire MovieClip), mais je vous laisserai en bas à autre chose (c'est à dire Sprite), vous forçant à construire un ensemble personnalisé étendue de l'objet/événement pour chaque type.

Cette solution traite de tous les "écoutable" de l'objet et de l'événement. Et cette réponse a plus de détails et d'exemples.

OriginalL'auteur