AS3 Création d'un tableau d'objets

Je voudrais ajouter un tas de voitures sur la scène, et de les stocker dans un tableau comme des objets. Le problème est que je déteste l'aide externe, les fichiers et aimeraient le garder aussi simple que possible.

J'ai essayé de faire :

var car:Object = {carcolor:String,carscale:Number,carpower:Number};
var test:Array = new Array()
for (var i:Number=0; i<10; i++) {
    test.push(car)
}

Le problème est que si j'essaie de définir une valeur d'un objet dans l'
test[1].carscale = 5

Chaque objet du tableau devient leur attribut carscale 5.

Est-il possible que je peux le faire sans l'aide de fichiers de classe externes?

Je vous suggère de commencer à l'aide extérieure sous forme de fichiers, et surtout de créer une Voiture.en tant que classe pour stocker vos informations. De cette façon, vous pouvez ajouter de la flexibilité à votre application et la rendre plus facile à déboguer/maintenir dans le temps.

OriginalL'auteur victorkhugo | 2012-04-07

  1. 11

    Alors que vous devriez utiliser externes COMME les fichiers (c'est une bonne pratique), voici la raison pour laquelle vous avez de la question, et je vais vous expliquer ligne par ligne

    var car:Object = {carcolor:String,carscale:Number,carpower:Number};
//This creates an object called car. Suppose it saves it in memory at "location" 0x12345

var test:Array = new Array();
//This creates an empty array

for (var i:Number=0; i<10; i++) {
    test.push(car);
    //This adds the object "car" to the array
    //Since Object is a reference type, its memory location is actually added to the array
    //This means you added 0x12345 to the array (10 times over the loop)
}

//The array now contains 
[0x12345, 0x12345, 0x12345, .......];

//So now
test[1]; //returns the object at 0x12345

test[1].carscale=5;  //sets the carscale property of the object at 0x12345

    Depuis tous les objets dans le tableau pointer vers le même emplacement, d'avoir un quelconque d'entre eux seront effectivement en retour le même objet. Cela signifie que tous d'entre eux montrent carscale 5

    Une solution à ce problème serait:

    var test:Array = new Array();
for (var i:Number=0; i<10; i++) {
    var car:Object = {carcolor:String,carscale:Number,carpower:Number};
    test.push(car);
}

    Mieux, RÉEL orienté-Objet, la solution serait de créer une classe appelée la Voiture et puis au lieu de faire 

    var car:Object = {carcolor:String,carscale:Number,carpower:Number};

    vous utilisez 

    var car:Car = new Car();

    La Car.as classe serait comme ceci:

    public class Car {
    public function Car() {
        //this is the constructor, initialize the object here
        //Suppose the default values of the car are as follows:
        carcolor="red";
        carscale=5;
        carpower=1000;
    }

    public var carcolor:String;
    public var carscale:Number, carpower:Number;
}

    En fait, vous pourriez même utiliser un autre constructeur qui définit automatiquement les propriétés fondé sur des arguments:

        public function Car(_color:String, _scale:Number, _power:Number) {
        carcolor=_color;
        carscale=_scale;
        carpower=_power;
    }

    et l'appeler comme 

    var car:Car=new Car("red", 5, 1000);

    En fait, la car avant carcolor, carscale et carpower n'est même pas nécessaire, car il est évident que lorsqu'on les met dans une classe appelée Car.

    Tout à fait universelle explication, qui travaille pour Java.

    OriginalL'auteur Pranav Hosangadi

  2. 2

    Comme TheDarkIn1978 dit que vous êtes en poussant une référence de votre car exemple dans votre tableau. Lorsque vous modifiez la valeur d'une propriété de l'instance, le même phénomène se produit pour chaque référence.

    La réponse la plus simple est de créer un nouvel objet à chaque interaction de votre boucle comme suit:

    var test:Array = [];

for (var i:Number = 0; i < 10; i++) 
{
    var car:Object = {carcolor:String, carscale:Number, carpower:Number};    
    test.push(car);

}//end for

    [Mise à JOUR]

    Je sais que vous avez dit que vous ne souhaitez pas utiliser "des classes externes", mais il y a des avantages à utiliser une classe personnalisée objet pour stocker des valeurs, par opposition à un Object objet. Voici un exemple: 

    package 
{
import flash.display.Sprite;
import flash.events.Event;
public class Main extends Sprite 
{
public function Main():void 
{
if (stage) init();
else addEventListener(Event.ADDED_TO_STAGE, init);
}//end function
private function init(e:Event = null):void 
{
removeEventListener(Event.ADDED_TO_STAGE, init);
var cars:Vector.<Car> = new Vector.<Car>();
cars.push(new Car("red", 1, 1));
cars.push(new Car("blue", 2, 2));
cars.push(new Car("green", 3, 3));
trace(cars[2].color); //output: green
}//end function
}//class
}//end package
internal class Car
{
private var _color:String;
private var _scale:Number;
private var _power:Number;
public function get color():String { return color; }
public function get scale():String { return scale; }
public function get power():String { return power; }
public function Car(color:String, scale:Number, power:Number)
{
_color = color;
_scale = scale;
_power = power;
}//end function
}//end class

    C'est un bon exemple de création d'un objet dans le seul but de stocker des valeurs qui ne changent jamais, en autorisant uniquement les propriétés de l'objet au moment de l'initiation et en utilisant des méthodes de lecture pour rendre les valeurs en lecture seule.

    saisi de la question pour répondre exactement à cet)

    OriginalL'auteur Taurayi

  3. 1

    Je me sens stupide, j'ai trouvé la réponse ici :
    http://board.flashkit.com/board/showthread.php?t=792345

    Vous êtes poussant la référence de l'Objet dans le tableau, pas un Objet unique à chaque fois. Que vous avez à faire quelque chose comme:

    for(var temp=0;temp<100;temp++){
var roomData:Object=new Object;
roomData.first_time=true;
rooms.push(roomData);
}
    C'est exactement ce que tous les autres réponses ici vous l'a dit. Pourquoi chercher ailleurs?

    OriginalL'auteur victorkhugo

  4. 0

    vous êtes en train d'ajouter de l'objet même de la matrice à plusieurs reprises. vous avez besoin de créer de nouvelles instances de votre voiture à l'objet.

    EDIT:

    bien que ce serait une des meilleures pratiques pour créer votre propre "Voiture" classe et de créer de nouvelles instances, même si c'est seulement un objet de petite taille avec 3 propriétés, voici un petit exemple qui devrait vous obtenir a commencé.

    package 
{
//Imports
import flash.display.Sprite;
//Class
public class Main extends Sprite 
{
//Constants
private static const DEFAULT_CAR_COLOR:Number = 0x000000;
private static const DEFAULT_CAR_SCALE:Number = 1.0;
private static const DEFAULT_CAR_POWER:int = 50;
//Properties
private var carsArray:Array;
//Constructor
public function Main():void 
{
init();
outputCarColors();
}
//Initialize
private function init():void
{
carsArray = new Array();
for (var i:int = 0; i < 10; i++)
{
carsArray.push(CreateCar(Math.random() * 0xFFFFFF));
}
}
//Output Car Colors
private function outputCarColors():void
{
for (var i:int = 0; i < carsArray.length; i++)
{
trace("Color of car " + i + " : " + carsArray[i].carColor);
}
}
//Create Car Object
private function CreateCar(carColor:Number = DEFAULT_CAR_COLOR, carScale:Number = DEFAULT_CAR_SCALE, carPower:int = DEFAULT_CAR_POWER):Object
{
var result:Object = new Object();
result.carColor = carColor;
result.carScale = carScale;
result.carPower = carPower;
return result;
}
}
}
    J'étais juste en train d'écrire un exemple, alors vous avez répondu avant moi. De toute façon, vous voudrez peut-être ajouter qu'il peut simplement résoudre le problème avec la déclaration suivante test.push({carcolor:String,carscale:Number,carpower:Number});

    OriginalL'auteur TheDarkIn1978