AS3: TextField Focus

Je suis en train de gérer un événements de focus sur un Champ de texte afin que je puisse sélectionner tout le texte lors de la mise au point (onglet ou cliquez sur). Me semble que je suis en train de faire quelque chose de mal ici ?

txtTextField.addEventListener(FocusEvent.FOCUS_IN, handleFocusIn);
function handleFocusIn() {
 //select all text here
}

OriginalL'auteur Yens | 2009-07-10

5

J'avais besoin de la même chose, pour sélectionner le contenu d'un champ de texte lorsqu'il reçoit le focus.

J'ai essayé:

A), il suffit de sélectionner après un FocusEvent. Cela ne semble pas fonctionner (ma conjecture est que FocusEvents sont licenciés avant le clic de la souris est en cours de traitement, qui à son tour permet d'annuler la sélection).

B) la Sélection à chaque clic de souris. Cela fonctionne, mais c'est très ennuyeux pour un utilisateur qui veut sélectionner seulement une partie du texte plus tard, depuis cette tentative sera toujours -tout - le contenu sélectionné.

La solution de contournement suivante semble fonctionner bien:
```
    myTextField.addEventListener(MouseEvent.CLICK, selectAllOnce);

    function selectAllOnce(e:MouseEvent) {
        e.target.removeEventListener(MouseEvent.CLICK, selectAllOnce);
        e.target.addEventListener(FocusEvent.FOCUS_OUT, addSelectListener);
        selectAll(e);
    }

    function addSelectListener(e:FocusEvent) {
        e.target.addEventListener(MouseEvent.CLICK, selectAllOnce);
        e.target.removeEventListener(FocusEvent.FOCUS_OUT, addSelectListener);
    }

    function selectAll(e:Event) {
        e.target.setSelection(0, e.target.getLineLength(0));
    }
```
Espère que ça aide. Personnellement, je pense qu'il serait plus logique si adobe simplement ajouté une option pour ce pour l'objet TextField.

OriginalL'auteur Mattijs
4

Votre handleFocusIn doit avoir la signature
```
function handleFocusIn(event:FocusEvent) //or just Event
```
OriginalL'auteur Vinay Sajip
2

J'ai eu un problème similaire à le prototype de la phase de développement (en Flash).
Un champ de texte n'était pas de tir FocusEvent.FOCUS_OUT des manifestations à tous.
Le problème est que j'avais un Bouton composant sur la scène.
Dès que j'ai remplacé par flash Bouton instance de composant avec un bouton personnalisé créé à partir de zéro, je l'ai eu à travailler.
Je n'ai pas été en mesure de trouver ce bug et la solution sur internet.

Avec un composant de Bouton sur la scène-je obtenir FOCUS_IN cas, uniquement la première fois que je clique sur elle.
Après cela, je n'ai pas ni FOCUS_OUT ni FOCUS_IN les événements déclenchés.

J'espère que cela aidera quelqu'un en quelque sorte.

OriginalL'auteur vitaLee

Je fais mon gestionnaire de ce genre. Fonctionne comme un charme:

private function onFocusIn(e:FocusEvent):void 
{
    setTimeout(title.setSelection, 100, 0, e.target.text.length);           
}

OriginalL'auteur Fehaar

vous pouvez trouver de l'utilisateur n'est pas de sélectionner seulement une partie de ce texte:

private function clickHandler(e:MouseEvent){
    if(tfield.selectionBeginIndex == tfield.selectionEndIndex){
        tfield.setSelection(0, tfield.length);
    }
}

OriginalL'auteur Dast

La solution est simple:

import flash.events.Event;
import flash.events.MouseEvent;
import flash.events.FocusEvent;

tf.addEventListener(FocusEvent.FOCUS_IN, handleFocusIn);

function handleFocusIn(e:FocusEvent):void
{
    tf.addEventListener(MouseEvent.MOUSE_UP, preventLosingSelection);
    tf.setSelection(0, tf.length);
    stage.focus = tf;
}

function preventLosingSelection(e:MouseEvent):void
{
    tf.removeEventListener(MouseEvent.MOUSE_UP, preventLosingSelection);
    tf.setSelection(0, tf.length);
    stage.focus = tf;
}

Espérons que cette aide de quelqu'un dans le futur!

OriginalL'auteur aconma.com

0

Vous avez tout simplement oublié le var que les captures de l'événement.
Il doit être entre crochets dans la définition de la fonction.
Le chemin le plus court est juste de l'appeler "e" sans plus de définitions, comme je l'ai fait ici.
Il travaille:
```
txtTextField.addEventListener(FocusEvent.FOCUS_IN, handleFocusIn);
function handleFocusIn(e) {
 //select all text here
}
```
OriginalL'auteur Avi

Vous devez vous connecter pour publier un commentaire.