Attribuer sur-cliquez sur une fonction VBA pour dynamiquement un bouton créé sur Excel Userform

Je suis la création de boutons de façon dynamique sur un userform Excel avec le code suivant:

With Me.CurrentFrame.Controls.Add("Forms.CommandButton.1")
    .Caption = "XYZ"
    .name = "AButton"
    .Font.Bold = True
    .ForeColor = &HFF&
    ... blah blah blah
End With

J'aimerais attribuer une fonction à exécuter lorsque ces boutons sont cliqué, mais je ne peux pas trouver un moyen simple de faire cela car il n'y a pas de propriété dans le cadre de la touche elle-même.

Est-il un moyen de le faire à l'aide de la idiome? Dois-je aller à ce sujet toute chose d'une manière différente?

OriginalL'auteur notnot | 2009-02-19

9

Vous avez besoin pour créer dynamiquement du code /des gestionnaires d'événement pour chaque bouton.

Il prendre un peu de faire - voir ici: http://navpadexcel.blogspot.com/2006/11/httpwwwcpearsoncomexcelvbehtm.html

Une meilleure façon pourrait être de créer un tas de boutons sur la forme (autant que vous pensez que vous aurez besoin) à l'avance. Créer le code de gestionnaire d'événements. Faire d'eux tous, masqué au départ.

Puis quand votre formulaire s'ouvre, vous pouvez modifier dynamiquement le bouton de légendes, de les rendre visibles et de les déplacer. Le code d'événement que vous avez créé va d'abord être liée à l'activation des boutons comme prévu.

Idée astucieuse! Semble que tout en VBA, il faut être intelligent.

OriginalL'auteur DJ.
14

Pour ajouter un événement de contrôle de manière dynamique sous Excel; vous devez d'abord ajouter l'événement(s) dans un module de classe. Pour mon exemple, je vais ajouter un module de classe nommé clsTEST avec un événement, btn_click()
```
    '#### CLASS NAMED clsTEST
    Public WithEvents btn As MSForms.CommandButton
    Public frm As UserForm

    Dim iCount As Long

    Private Sub btn_Click()

    iCount = IIf(iCount < 1, 1, iCount + 1)
    btn.Caption = "Count " & Str(iCount)

End Sub
'### END CLASS
```
Comme vous pouvez le voir, la seule chose que cela va faire est de définir la légende sur le bouton pour le nombre de fois où vous avez cliqué.
Ensuite, dans le code du formulaire, saisissez les éléments suivants:
```
    Dim mColButtons As New Collection    '## SET A NEW COLLECTION

    Private Sub UserForm_Activate()
    '
    Dim btnEvent As clsTEST
    Dim ctl As MSForms.Control
    '
    Set ctl = Me.Controls.Add("Forms.CommandButton.1")
    '
    With ctl
    .Caption = "XYZ"
    .Name = "AButton"
    END With
    '
    Set btnEvent = new clsTEST   
    Set btnEvent.btn = ctl
    set btnEvent.frm = Me
    '
    mColButtons.add btnEvent
    'End Sub
```
Lorsque vous activez la forme, il va créer un bouton. chaque fois que vous cliquez sur le bouton de la légende va changer.

Cela a fonctionné très bien pour moi. Je me demandais est-il une manière que je peux envoyer une variable de la classe. Par exemple, si je devais changer .de la légende à ce que j'envoie. Private Sub btn_Click(var1 as String), j'ai essayé cela, mais il a abouti à un "Objet ne gère pas cette propriété ou cette méthode"
C'est le droit. _Click() événements n'accepte pas les paramètres. Ce que vous pouvez essayer est de mettre une autre variable privée à l'intérieur de la classe et de vous attribuer la légende de la première, puis la configuration de votre événement pour le gestionnaire.

OriginalL'auteur 598Bubblehead

Le code ci-dessous devrait être de travailler

Dim NewButton As OLEObject
Dim CodeModule As Object

Set NewButton = ActiveSheet.OLEObjects.Add(ClassType:="Forms.CommandButton.1", _
    Link:=False, DisplayAsIcon:=False, Left:=52.5, Top:=Hght, _
    Width:=202.5, Height:=26.25)
NewButton.Object.Caption = "Click Me!"
Set CodeModule = ActiveWorkbook.VBProject.VBComponents.VBE.ActiveCodePane.CodeModule
CodeModule.InsertLines CodeModule.CreateEventProc("Click", NewButton.Name) + 1, vbTab & "MsgBox ""Hello world"""

OriginalL'auteur Alex

Sub Oval1_Click()
    file = ActiveWorkbook.Name
    Set Output = Workbooks.Add()
    ActiveWorkbook.SaveAs Filename:="Try.xls"        
    Sheets(1).Select        
    ActiveSheet.Buttons.Add(460, 10, 140, 30).Select
    ActiveSheet.Buttons.Text = "DATA"      
    ActiveSheet.Shapes("Button 1").Select
    Selection.OnAction = "Book1.xlsm!data_Click"
End Sub

Sub data_Click()      
    MsgBox "you have clicked me"       
    ActiveSheet.DrawingObjects.Delete        
End Sub

Je veux dire pour les boutons ajoutés à des userforms, pas à la feuille de calcul

OriginalL'auteur Priyanka

0

J'ai été à la recherche à ce sujet. Semble que vous pouvez exécuter une macro à l'aide de la propriété onClick:
```
Command1.OnClick = "Macro1"
```
Puis créer une macro de ce nom qui exécute la fonction désirée.
C'est mon hack autour de cette jusqu'à ce que je trouve quelque chose de mieux.

Pour un userform excel de contrôle, assingin "onClick", a permis de... "cet Objet ne gère pas cette propriété ou cette méthode"

OriginalL'auteur

Vous devez vous connecter pour publier un commentaire.