awk + une ligne awk syntaxe pour imprimer uniquement une fois que le deuxième champ si “vrai” mot appariés

Je ne sais pas comment faire avec awk
Mais mon objectif est de créer awk une syntaxe de ligne de commande pour imprimer le deuxième champ ($2) si
tous les premier champ ($1) sont remplies

par exemple

J'ai le fichier:

   true my_name_is_lenon
   true my_name_is_lenon
   true my_name_is_lenon
   false my_name_is_lenon
   true my_name_is_lenon

   false my_dog_is_fat
   true my_dog_is_fat
   true my_dog_is_fat

   true I_am_very_tall
   true I_am_very_tall
   true I_am_very_tall

   true my_ball_is_fine
   true my_ball_is_fine

la awk imprimer uniquement le texte suivant:

 I_am_very_tall
 my_ball_is_fine

Parce que I_am_very_tall , my_ball_is_fine vraie sur le premier champ, sans faux

my_dog_is_fat , my_name_is_lenon pas imprimé, parce que le faux mot sur le premier champ

La règle est d'imprimer le deuxième champ si aucun faux mot sur le premier champ! (De toutes la même phrase sur le deuxième champ)

lidia

OriginalL'auteur lidia | 2010-07-23

awk

En voici une:

awk '{if ($1 == "false") {array[$2] = $1} else if (array[$2] != "false") array[$2] = $1} END {for (i in array) if (array[i] == "true") print i}' inputfile

Edit:

Ici, il est sur plusieurs lignes:

awk '{if ($1 == "false") 
         {array[$2] = $1} 
     else if (array[$2] != "false") 
         array[$2] = $1} 
     END {for (i in array)
             if (array[i] == "true") 
                 print i}
' inputfile

salut dennis pouvez-vous modifier le awk comme radoulov awk? (pas une ligne) THX lidia
OK, mais votre question a dit "awk une syntaxe de la ligne".
Je pense que c'est mieux de ne pas une ligne (dans le script sa pas l'air bien)

OriginalL'auteur Dennis Williamson

1

En supposant que chaque bloc est de la même catégorie.
```
$ awk -vRS= '!/false/' file | uniq | awk '{print $NF}'
I_am_very_tall
my_ball_is_fine
```
désolé, mais ce awk fonctionne pas essayez la suivante fichier : vrai my_name_is_lenon vrai my_name_is_lenon vrai my_name_is_lenon faux my_name_is_lenon vrai my_name_is_lenon faux my_dog_is_fat vrai my_dog_is_fat vrai my_dog_is_fat vrai I_am_very_tall vrai I_am_very_tall vrai I_am_very_tall vrai my_ball_is_fine vrai my_ball_is_fine

OriginalL'auteur ghostdog74
0

Je ne suis pas sûr que c'est possible que awk one-liner. Au moins pas facilement. Est awk absolument nécessaire? Comme il y a un interpréteur de ligne de solutions disponibles si awk est juste une partie de la solution.

Par exemple, c'est un shell one-liner (juste une longue ligne):
```
awk '{ print $2 }' < {infile} | while read line; do grep -i "false $line" {infile} > /dev/null || echo $line; done | uniq
```
Il n'est pas efficace, mais il fait le travail.

En comparaison, la plus courte awk solution que j'ai obtenu est d'environ 25 lignes (ce que je peux déposer ici en ici si vous voulez, laissez un commentaire et je vais mettre à jour ce en conséquence). Mais cela voudrait alors dire que vous pourriez économiser ce dans un fichier et de l'exécuter awk -f alltrue.awk < {infile}. Je ne suis pas sûr que ce strictement classes perl one-liner bien 🙂

Une meilleure compréhension de ce que vous êtes finalement essayez d'atteindre ou de ce que cela pourrait être utile.

OriginalL'auteur Chris J
0

Et un autre:
```
awk 'END { 
  for (A in all)  
    if (!(A in ko)) print A
  }
NF { all[$2] } 
$1 == "false" { ko[$2] }
' infile
```
Si vous souhaitez conserver l'ordre initial, vous aurez besoin de plus de code si.

OriginalL'auteur Dimitre Radoulov

Une autre solution compacte.

awk '
  $1 == "true" && ! ($2 in false) {true[$2]}
  $1 == "false" {false[$2]; delete true[$2]}
  END {for (word in true) print word}
' true.txt

OriginalL'auteur glenn jackman

Ici est une autre façon:

gawk '{a[$2]=a[$2] || $1=="false"} END {for (i in a) if (!a[i] && i) print i}' a.txt

my_ball_is_fine
I_am_very_tall

OriginalL'auteur DanielAjoy

Ici est en une seule ligne:

awk '{$1=="false" ? false[$2]="false" : true[$2]="true"} END{for (i in true) if   (!false[i]) {print i} }'

my_ball_is_fine
I_am_very_tall

OriginalL'auteur ghub24

Vous devez vous connecter pour publier un commentaire.