Besoin de plus d'exemples sur la façon d'utiliser le Tableur::ParseExcel

J'ai été en utilisant le Feuille De Calcul::ParseExcel pour lister le contenu de la feuille de calcul. J'ai vu plusieurs exemples sur la façon de vider la totalité de la feuille de calcul. Je voudrais vraiment voir comment utiliser ce script de manière plus sélective.

L'exemple ci-dessous d'IBM fondamentalement vide le contenu de toutes les cellules qui contiennent des données. 

#!/usr/bin/perl -w

use strict;
use Spreadsheet::ParseExcel;

my $oExcel = new Spreadsheet::ParseExcel;

die "You must provide a filename to $0 to be parsed as an Excel file" unless @ARGV;

my $oBook = $oExcel->Parse($ARGV[0]);
my($iR, $iC, $oWkS, $oWkC);
print "FILE  :", $oBook->{File} , "\n";
print "COUNT :", $oBook->{SheetCount} , "\n";

print "AUTHOR:", $oBook->{Author} , "\n"
 if defined $oBook->{Author};

for(my $iSheet=0; $iSheet < $oBook->{SheetCount} ; $iSheet++)
{
 $oWkS = $oBook->{Worksheet}[$iSheet];
 print "--------- SHEET:", $oWkS->{Name}, "\n";
 for(my $iR = $oWkS->{MinRow} ;
     defined $oWkS->{MaxRow} && $iR <= $oWkS->{MaxRow} ;
     $iR++)
 {
  for(my $iC = $oWkS->{MinCol} ;
      defined $oWkS->{MaxCol} && $iC <= $oWkS->{MaxCol} ;
      $iC++)
  {
   $oWkC = $oWkS->{Cells}[$iR][$iC];
   print "( $iR , $iC ) =>", $oWkC->Value, "\n" if($oWkC);
  }
 }
}

Quelqu'un peut-il me donner un exemple de comment je peux préciser certaines mesures à prendre pour une certaine colonne pour chaque ligne?

Par exemple, j'ai une feuille de calcul avec 7 colonnes et n lignes. Je veux reformater les données dans chacune des colonnes dans une certaine manière. Peut-être que je veux prendre de la colonne 6 pour chaque ligne et ajouter du texte à la fin de la chaîne stockée dans la cellule. Comment pourrait-il être mis en place?

OriginalL'auteur XL. | 2010-07-09

  1. 9

    De modifier un fichier Excel, le Feuille De Calcul::ParseExcel::SaveParser module est très utile. Il vous permet de lire un fichier, effectuez les modifications, puis d'écrire le contenu modifié dans un nouveau fichier. Voici un exemple simple:

    use strict;
use warnings;

use Spreadsheet::ParseExcel;
use Spreadsheet::ParseExcel::SaveParser;

my $excel_file_name = $ARGV[0];
my $parser          = Spreadsheet::ParseExcel::SaveParser->new();
my $workbook_orig   = $parser->Parse($excel_file_name);

# We will edit column 7 of the first worksheet.
my $worksheet = $workbook_orig->worksheet(0);
my $EDIT_COL = 6;

my ($row_min, $row_max) = $worksheet->row_range();
for my $r ($row_min .. $row_max){
    my $cell = $worksheet->get_cell($r, $EDIT_COL);
    unless (defined $cell){
        next; # Modify as needed to handle blank cells.
    }
    my $val = $cell->value . '_append_text';
    $worksheet->AddCell( $r, $EDIT_COL, $val, $cell->{FormatNo} );
}

# You can save the modifications to the same file, but when
# you are learning, it's safer to write to a different file.
$excel_file_name =~ s/\.xls$/_new.xls/;
$workbook_orig->SaveAs($excel_file_name);

    Pour beaucoup d'autres exemples, voir l'excellente documentation:

    Je suis le responsable de la feuille de calcul::ParseExcel et je pense que c'est un bel exemple. ++
    Wow, magnifique exemple. Merci beaucoup! Et merci à tous de vos contributions et de ces outils formidables!
    J'ai eu la suivante: vous ne Pouvez appeler la méthode de la "valeur" sur une valeur non définie ./excel-test de la nouvelle ligne 19.
    Après vous obtenez $cell de la get_cell méthode, vous avez souvent besoin de vérifier si elle est définie. Si non, cela signifie que la cellule dans la feuille de calcul était vide. J'ai édité ma réponse pour illustrer l'idée.
    Brillant. Merci beaucoup!

    OriginalL'auteur FMc

  2. 2

    Pour reformater les données dans chacune des colonnes d'une certaine manière, vous pouvez utiliser la combinaison de Spreadsheet::ParseExcel et Spreadsheet::WriteExcel modules comme

    Créer un nouveau excel par Spreadsheet::WriteExcel module et ajoutez la feuille de calcul.Ensuite d'Analyser l'existant, Excel et écrire le contenu dans de nouveaux excel avec le formatage.

    Voici un exemple d'échantillon:

    use strict;
use Spreadsheet::ParseExcel;
use Spreadsheet::WriteExcel;

die "You must provide a filename to $0 to be parsed as an Excel file" unless @ARGV;

my $oBook = $oExcel->Parse($ARGV[0]);
my($iR, $iC, $oWkS, $oWkC);
my $workbook  = Spreadsheet::WriteExcel->new('/root/Desktop/test_simple.xls');
my $worksheet = $workbook->add_worksheet();
$worksheet->set_column('A:A', 50);
my $format = $workbook->add_format();
            $format->set_size(10);
            $format->set_bold();
            $format->set_color('black');
            $format->set_font('Verdana');
            $format->set_text_wrap();
for(my $iSheet=0; $iSheet < $oBook->{SheetCount} ; $iSheet++)
        {
                    $oWkS = $oBook->{Worksheet}[$iSheet];
            for(my $iR = $oWkS->{MinRow} ;defined $oWkS->{MaxRow} && $iR <= $oWkS->{MaxRow} ;$iR++)
            {
                for(my $iC = $oWkS->{MinCol} ;defined $oWkS->{MaxCol} && $iC <= $oWkS->{MaxCol} ;$iC++)
                {
                   $oWkC = $oWkS->{Cells}[$iR][$iC];
                   $worksheet->write($iR , $iC,  $oWkC->Value, $format) if($oWkC); #writing a new excel from existing excel
                }
            }
        }

    Après l'écriture d'un nouveau excel à partir de l'existant excel, vous pouvez utiliser l'API de Spreadsheet::WriteExcel pour ajouter des données.Il permettra de résoudre les problèmes comme

    1. D'abord, il permettra de conserver votre fichier Excel.
    2. vous pouvez faire le formatage de nouveaux fichiers excel sans en modifier le Fichier Excel d'origine.
    Savez-vous comment nous pouvons nous occuper de la fusion de cellules ici ?

    OriginalL'auteur Nikhil Jain