Besoin d'un “Simple” macro excel pour trouver le fond de la cellule dans une colonne, de créer une gamme et de le copier

J'ai une feuille de calcul que j'utilise pour compiler le texte qui change tout le temps.

Dans la colonne AD, Ligne 4(AD4), j'ai mis le contenu du texte, et il peut avoir des données allant de 1000 à 4000 lignes vers le bas. Il change à chaque fois, donc il n'est pas statique nom de la gamme. J'ai besoin d'une macro qui

  • trouve le dernier élément de données dans la colonne,
  • alors automatiquement à "glisser une boîte" à partir de ce spot de deux colonnes vers la gauche (AB4)
  • et la copie... (Un 3000 ligne morceau de texte serait AB4:AD3004) (Macro s'arrête là, avec le texte à copier en surbrillance)

La version actuelle trouve la cellule du bas correctement, mais si je lance la macro, un 2ème temps, avec de nouvelles données, il continue d'essayer de copier la même gamme. (J'ai utilisé la Formule Définir.Nom de la méthode, le nom de la cellule, puis sélectionné AB4:LastRow) mais il est TOUJOURS 3160 si les données de ligne de 4000 ou pas.....

Sub Last_row()
Cells(Application.Rows.Count, 30).End(xlUp).Select
' following lines of code are useless
Range("AB4:AD3160").Select
Range("AD3160").Activate
Selection.Copy
End Sub
  • C'est dans MS Office Excel 2007. BTW.
InformationsquelleAutor CJG | 2012-03-28
  1. 3

    Pour répondre directement à votre question:

    With Sheet1
    .Range("AB4", .Cells(Rows.Count, "AD").End(xlUp)).Copy
End With

    Copie à l'emplacement spécifique SANS à l'aide du presse-papiers:

    With Sheet1
    .Range("AB4", .Cells(Rows.Count, "AD").End(xlUp)).Copy Sheet2.[A1]
End With

    Copie et de l'exclure de la mise en forme:

    With Sheet1
    With .Range("AB4", .Cells(Rows.Count, "AD").End(xlUp))
        Sheet2.Cells(1, "A").Resize(.Rows.Count, .Columns.Count).Value = .Value
    End With
End With

    Remarque: Remplacer toutes les feuille les noms de code (feuil1, Feuil2) ci-dessus avec votre feuille les noms de code.

    InformationsquelleAutor Reafidy
  2. 1

    Votre code en dur les codes de la plage d'intérêt avec
    Range("AB4:AD3160").Select

    Ce code permet de définir une plage dynamique à partir de AB4 à la dernière cellule non vide de la colonne AD

    Vous pouvez ensuite utiliser cette gamme (sans sélection) pour modifier les valeurs d'ailleurs (notez que vous ne pouvez pas besoin de copie rng1, il est possible de dumper ces valeurs à une gamme distincte directement, sans copier-coller.

    Sub Last_row()
Dim rng1 As Range
Set rng1 = Range([ab4], Cells(Rows.Count, 30).End(xlUp))
rng1.Copy
End Sub

    Mise à jour: Exemple de comment copier une dynamique de taille moyenne gamme à partir d'une feuille à l'autre sans un copier-coller:

    Sub Last_row2()
    Dim ws1 As Worksheet
    Dim ws2 As Worksheet
    Dim rng1 As Range

    Set ws1 = Sheets(1)
    Set ws2 = Sheets(2)
    Set rng1 = ws1.Range(ws1.[ab4], ws1.Cells(Rows.Count, 30).End(xlUp))
    ws2.[a1].Resize(rng1.Rows.Count, rng1.Columns.Count).Value = rng1.Value
End Sub
    InformationsquelleAutor brettdj