Boucle à travers les cellules et les ajouter à une gamme

Comment pourrais-je faire une boucle par les cellules B1 à J1 et de les ajouter à une gamme si elles répondent à certains critères. Par exemple.

Dim Range1 As Range
For i = 1 to 9
If Range("A1").Offset(1,i) meets a certain criteria Then
**Add that cell to Range1**
End If
Next i

Je ne suis pas sûr de la façon d'aborder la partie de l'ajout de certaines cellules Plage1.

Merci pour l'aide!

OriginalL'auteur user1067701 | 2011-11-30

  1. 24

    Quelque chose comme ceci en utilisant Union de la colle ensemble de votre gamme

    1. Veuillez noter que For each boucles sont plus rapides que d'un For i = 1 to x approche

    2. Vous pourriez bien être en mesure d'utiliser SpecialCells pour déterminer votre nouvelle gamme instantanément (par exemple, les lacunes, les erreurs, toutes les formules, etc)

      Sub Test()
  Dim rng1 As Range
  Dim rng2 As Range
  Dim c As Range
  Set rng1 = Range("B1:J1")

  For Each c In rng1
    ' Add cells to rng2 if they exceed 10
    If c.Value > 10 Then
        If Not rng2 Is Nothing Then
        ' Add the 2nd, 3rd, 4th etc cell to our new range, rng2
        ' this is the most common outcome so place it first in the IF test (faster coding)
            Set rng2 = Union(rng2, c)
        Else
        ' the first valid cell becomes rng2
            Set rng2 = c
        End If
    End If
  Next
End Sub
    u sont sûr "Pour chaque boucles sont plus rapides que Pour i = 1 à x approche"? je pensais sinon, stackoverflow.com/questions/365615/...
    For Each est plus rapide pour une gamme, For I plus rapide pour une boucle dans un tableau de type variant
    o ok. merci pour les précisions

    OriginalL'auteur

  2. 1

    J'utilise cette méthode en mode immédiat quand je ne veux pas ajouter du code à la feuille.

    strX="": _
For Each cllX in Range( ActiveCell, Cells( Cells.SpecialCells(xlCellTypeLastCell ).Row, ActiveCell.Column) ): _
strX=strX & iif(cllX.text="","",iif(strX="","",",")& cllX.address): _
Next: _
Range(strX).Select

    Mais tout cela est intuitive, elle ne fonctionne que pour 35 à 50 cellules. Après cela, le VBA renvoie une erreur 1004.

    Run-time error '1004':
Application-defined or object-defined error

    Il est plus robuste à utiliser le Union fonction.

    Set rngX=ActiveCell: _
For Each cllX in Range( ActiveCell, Cells( cells.SpecialCells(xlCellTypeLastCell ).Row, ActiveCell.Column) ): _
Set rngX=iif( cllX.text="", rngX, Union(rngX, cllX) ): _
Next: _
rngX.Select

    C'est si court et intuitive, je viens de jeter après chaque utilisation.

    OriginalL'auteur