Boucle à travers les valeurs définies

Est-il un moyen de faire un "pour chaque" oracle, quelque chose comme ceci:

begin
  for VAR in {1,2,5}
  loop
    dbms_output.put_line('The value: '||VAR);
  end loop;
end;

Je sais que vous pouvez faire quelque chose comme:

begin
  for VAR in 1..5
  loop
    if VAR in(1,3,5) then
      dbms_output.put_line('The value: '||VAR);
    end if;
  end loop;
end;

Mais n'est-ce pas là un moyen de le faire dans une jolie manière? La définition d'un ensemble de valeurs et d'itération à travers eux?

Grâce.

Mettre la liste de valeurs dans un tableau. Vous pouvez maintenant faire une boucle par les valeurs dans le tableau à l'aide d'un curseur.

OriginalL'auteur JGS | 2012-05-29

  1. 31

    Vous pourriez faire, mais probablement pas aussi lisse que vous le souhaitez:

    declare
  type nt_type is table of number;
  nt nt_type := nt_type (1, 3, 5);
begin
  for i in 1..nt.count loop
    dbms_output.put_line(nt(i));
  end loop;
end;

    Si vous créez un type dans la base de données:

    create type number_table is table of number;

    ensuite, vous pouvez faire ceci:

    begin
  for r in (select column_value as var from table (number_table (1, 3, 5))) loop
    dbms_output.put_line(r.var);
  end loop;
end;
    En fait, vous n'avez pas besoin de créer un type dans la base de données, vous pouvez le faire for r in (select column_value from table(sys.dbms_debug_vc2coll(1,3,5))) loop

    OriginalL'auteur Tony Andrews