Boucle vba sur une plage non contiguë

J'ai une plage non contigu sur les lignes (exemple d'adresse de myRange: $2:$2,$4:$205,$214:$214) et je voudrais accéder à un niveau particulier de ligne et de colonne de la plage. J'ai essayé ce qui suit:

'Obtenir la valeur de la 2ème ligne, 1ère colonne de la plage

myRange.rows(2).Cells(, 1).Value

Cependant, ce qui me donne la valeur de la 2e rangée dans la Feuille de calcul, et non PAS dans le sens qu'il me donne l'adresse $3$1 - et pas $4$1

Quelqu'un peut-il expliquer comment je peux accéder aux valeurs à l'intérieur de ma gamme? (Il peut avoir à faire avec des domaines différents)

Merci

source d'informationauteur Jeffrey

  1. 4

    Voici mes entrées - pas nécessairement mieux que d'Irwin

    Function GetValue(rInput As Range, Row As Long, Column As Long) As Variant

    Dim rArea As Range
    Dim lCumRows As Long
    Dim lActualRow As Long

    For Each rArea In rInput.Areas
        lCumRows = lCumRows + rArea.Rows.Count
        If Row <= lCumRows Then
            lActualRow = rArea.Rows(1).Row + (Row - (lCumRows - rArea.Rows.Count + 1))
            Exit For
        End If
    Next rArea

    If lActualRow > 0 Then
        GetValue = rInput.Parent.Cells(lActualRow, Column).Value
    End If

End Function

Function GetValue2(rInput As Range, Row As Long, Column As Long) As Variant

    Dim rRow As Range
    Dim lRowCnt As Long

    For Each rRow In rInput.Rows
        lRowCnt = lRowCnt + 1
        If lRowCnt = lrow Then
            GetValue2 = rRow.Cells(1, Column).Value
            Exit For
        End If
    Next rRow

End Function

    Et aller lire http://www.dailydoseofexcel.com/archives/2004/07/07/the-strange-object/ pour certains de comprendre pourquoi Excel est de se comporter de cette façon.

    Et le test proc si vous êtes intéressé

    Sub test()

    Dim myRange As Range

    Set myRange = Union(Rows(2), Range("4:205"), Rows(214))

    Debug.Print GetValue(myRange, 1, 2), GetValue(myRange, 1, 2)
    Debug.Print GetValue(myRange, 2, 2), GetValue(myRange, 2, 2)
    Debug.Print GetValue(myRange, 3, 2), GetValue(myRange, 3, 2)
    Debug.Print GetValue(myRange, 200, 2), GetValue(myRange, 200, 2)

End Sub
  2. 2

    Je pense que ce que vous êtes désireux de VBA est de voir votre plage non contigu comme une zone contiguë. Je ne pense pas que l'approche que vous prenez va travailler. Vous aurez à les traiter comme multipe contiguë plages. Le code suivant devrait vous obtenir a commencé. Où rowSelection est la ligne dans votre gamme qui vous intéressent. Si vous saisissez 2, il va sélectionner la ligne 4 dans le classeur car il est la deuxième ligne dans votre gamme.

    Sub Macro1()

    Dim rowCounter As Long
    Dim rowSelection As Long

    rowSelection = 2
    For Each Rng In Range("A2:A2,A4:A205,A214:A214").Areas
         If Rng.Rows.Count >= rowSelection Then
            Rng.Rows(rowSelection - rowCounter).Cells(1, 1).Select
            End
         Else
            rowCounter = rowCounter + Rng.Rows.Count
         End If
    Next Rng

End Sub
  3. 1

    Ce code parcourt une plage nommée:

    Dim c As Range

x=0

For Each c In Range("MyNamedRange")

    'if x = pick a number and do something here

    MsgBox c.Address & vbTab & c.Value

x=x+1

Next c
  4. 0

    Merci à vous tous pour les réponses, Avant que vu de ces réponses, j'ai pensé moi-même et jusqu'à présent, il est de travail. Je ne dirai pas que c'est la plus efficace méthode, mais semble fonctionner:

     Public Function NextRow(index As Integer, rows As Range) As Range
    Dim i As Integer, r As Range
    i = 1
    Set NextRow = Nothing
    For Each r In rows.rows
        If i = index Then
            Set NextRow = Range(r.Address)
            Debug.Print "NextRow: " & NextRow.Address
            Exit Function
        End If

        i = i + 1
    Next r

End Function

    Il semble similaire 2ème réponse - baically je suis l'avancement de gamme à l'index, je veux travailler avec et que je retourne à une plage définie par l'adresse (!important)

    J'ai que de l'appeler comme ceci:

    NextRow(2, myRange).Cells(,1).value