CDO.Message - “Le transport échec de la connexion au serveur.”

Je suis en train de travailler sur un Classique ASP & Vbscript site qui utilise CDO.Message pour l'envoi de mail dans une fonction. Je suis en cours d'exécution des ennuis avec cette fonction et je suis recevoir le message d'erreur,

CDO.Message.1 error '80040213'

The transport failed to connect to the server.

Je crois qu'il a à faire avec les paramètres d'authentification SMTP et le partage d'hôte, nous sommes en cours d'exécution sur. Je suis à la recherche pour aider à déboguer le problème.

Voici les principaux extraits de code à partir de la fonction,

Set objConfig = Server.CreateObject("CDO.Configuration")
Set Fields = objConfig.Fields

' Set config fields we care about
With Fields
 .Item(cdoSendUsingMethod)       = cdoSendUsingPort
 .Item(cdoSMTPServer)            = "mail.<website>.com"

 '.Item(cdoSMTPServerPort)        = 25
 '.Item(cdoSMTPConnectionTimeout) = 10
 '.Item(cdoSMTPAuthenticate)      = cdoBasic
 '.Item(cdoSendUserName)          = "support"
 '.Item(cdoSendPassword)          = "password"

 .Update
End With

Set objMessage = Server.CreateObject("CDO.Message")

Set objMessage.Configuration = objConfig

With objMessage
 .To       = lEmailTo                   '"Display Name <email_address>"
 .From     = lEmailFrom                 '"Display Name <email_address>"
 .Subject  = lSubject
 .TextBody = lMessage
 .Send
End With

Au premier abord j'ai cru qu'il pourrait avoir été avec le commentaire des lignes 9-13 dans l'extrait ci-dessus, mais il semble qu'un ancien développeur a commenté sur objectif et que la fonction e-mail travaillait encore à un certain point dans le temps. Décommenter ces lignes n'est toujours pas à résoudre l'erreur.

Peut-on rien voir j'ai peut-être manquant? Personne ne sait ce que les valeurs par défaut pour les CDO.La Configuration et quels paramètres SMTP de ce code est d'essayer d'utiliser avec notre hôte? Dois-je d'abord appeler notre hébergement & clarifier avec eux?

Par l'implication de ce code a été de travailler à "un moment donné, mais maintenant, n'est-ce pas. Ce qui a changé quand il a cessé de travailler?
Je pense que c'était à partir d'un changement dans l'hébergement mutualisé, nous sommes de l'aide. Tout de même, vous m'a fait réfléchir sur le problème de nouveau & maintenant c'est résolu!

OriginalL'auteur nrub | 2009-11-29

  1. 1

    J'ai eu un moment difficile avec des CDO jusqu'à ce que j'ai compris la bibliothèque de types en haut de la page asp. Notez que la bibliothèque de types est pas à l'intérieur de la <% %> délimiteurs. La bibliothèque de types de ligne est assez longue, de sorte que vous besoin de faire défiler vers la droite pour lire tous les

    Essayez d'ajouter juste la typelib déclaration à votre page en premier.

    Si cela ne fonctionne pas, alors essayez le reste du code ci-dessous. J'ai utilisé avec succès ce code sur mon site web hébergé par Godaddy. Bien sûr, vous devrez brancher votre serveur de messagerie d'infos et de login/mot de passe si nécessaire.

    <!--METADATA TYPE="typelib" UUID="CD000000-8B95-11D1-82DB-00C04FB1625D" NAME="CDO for Windows 2000 Type Library" -->
<%
Sub SendEmail()

    Set cdoConfig = CreateObject("CDO.Configuration")

    if lcase(Request.ServerVariables("SERVER_NAME")) = "dev" then
            With cdoConfig.Fields
                    .Item(cdoSendUsingMethod) = cdoSendUsingPort
                    .Item(cdoSMTPServer) = "xxx.<devmailservername>.xxx"
                    .Item(cdoSMTPAuthenticate) = 1
                    .Item(cdoSendUsername) = "[email protected]"
                    .Item(cdoSendPassword) = "<passwordgoeshere>"
                    .Update
            End With
    else
            With cdoConfig.Fields
                    .Item(cdoSendUsingMethod) = cdoSendUsingPort
                    .Item(cdoSMTPServer) = "xxx.<productionmailservername>.xxx"
                    .Update
            End With
    end if

    Set cdoMessage = CreateObject("CDO.Message")

    With cdoMessage
        Set .Configuration = cdoConfig
        .From = "[email protected]"
        .To = "[email protected]"
        .Subject = "Sample CDO Message"
        .htmlbody = "<html><body>Sample <b>CDO</b> message.</body></html>"
        .TextBody = "Sample CDO Message."
        .Send
    End With

    Set cdoMessage = Nothing
    Set cdoConfig = Nothing

End Sub
%>

    OriginalL'auteur Michael Riley - AKA Gunny

  2. -2

    J'ai changé le cdoSMTPServer à localhost, tout navire de forme!

    OriginalL'auteur nrub