Chaîne SQL Server ou des données binaires seront tronqués

Vous aurez besoin d'afficher les définitions de table pour les tables source et de destination pour nous de figure où la question est mais la ligne de fond est que l'un de vos colonnes de la table source est plus grand que votre destination colonnes. Il se pourrait que vous ayez à changer des formats dans une manière que vous n'étiez pas au courant de. Le modèle de base de données vous vous déplacez de est important de le comprendre ainsi.

Comme d'autres l'ont déjà dit, l'une de vos colonnes de types de données dans la table source est plus grande que votre colonnes de destination.

Une solution simple est tout simplement de désactiver l'avertissement et de permettre la troncature à prendre place. Donc, si vous recevez cette erreur, mais vous êtes sûr qu'il est acceptable pour les données de votre ancienne base de données/tableau tronqué (coupé à la taille), vous pouvez simplement faire ce qui suit;

SET ANSI_WARNINGS  OFF;
-- Your insert TSQL here.
SET ANSI_WARNINGS ON;

Comme ci-dessus, n'oubliez pas de mettre des avertissements à nouveau par la suite. J'espère que cette aide.

Pour les autres, aussi vérifier votre procédure stockée. Dans mon cas, dans ma procédure stockée CustomSearch j'ai accidentellement déclaré ne pas assez de longueur pour ma colonne, donc quand je suis entré dans un big data, j'ai reçu cette erreur, même si j'ai une grande longueur sur ma base de données. J'ai juste modifié la longueur de ma colonne dans ma recherche personnalisée que l'erreur disparaisse. C'est juste pour le rappel. Merci.

Oui,je suis aussi face à ce genre de problème.

REMARKS VARCHAR(500)
to
REMARKS VARCHAR(1000)

Ici, j'ai des REMARQUES de la modification déposée longueur de 500 à 1000

J'ai construit une procédure stockée qui analyse une source de la table ou de la requête avec plusieurs caractères par colonne parmi lesquels la longueur minimale (min_len) et de longueur maximale (max_len).

CREATE PROCEDURE [dbo].[sp_analysetable] (
@tableName varchar(8000),
@deep bit = 0
) AS
/*
sp_analysetable 'company'
sp_analysetable 'select * from company where name is not null'
*/
DECLARE @intErrorCode INT, @errorMSG VARCHAR(500), @tmpQ NVARCHAR(2000), @column_name VARCHAR(50), @isQuery bit
SET @intErrorCode=0
IF OBJECT_ID('tempdb..##tmpTableToAnalyse') IS NOT NULL BEGIN
DROP TABLE ##tmpTableToAnalyse
END
IF OBJECT_ID('tempdb..##tmpColumns') IS NOT NULL BEGIN
DROP TABLE ##tmpColumns
END
if CHARINDEX('from', @tableName)>0
set @isQuery=1
IF @intErrorCode=0 BEGIN
if @isQuery=1 begin
--set @tableName = 'USE '+@db+';'+replace(@tableName, 'from', 'into ##tmpTableToAnalyse from')
--replace only first occurance. Now multiple froms may exists, but first from will be replaced with into .. from
set @tableName=Stuff(@tableName, CharIndex('from', @tableName), Len('from'), 'into ##tmpTableToAnalyse from')
exec(@tableName)
IF OBJECT_ID('tempdb..##tmpTableToAnalyse') IS NULL BEGIN
set @intErrorCode=1
SET @errorMSG='Error generating temporary table from query.'
end
else begin
set @tableName='##tmpTableToAnalyse'
end
end
end
IF @intErrorCode=0 BEGIN
SET @tmpQ='USE '+DB_NAME()+';'+CHAR(13)+CHAR(10)+'
select
c.column_name as [column],
cast(sp.value as varchar(1000)) as description,
tc_fk.constraint_type,
kcu_pk.table_name as fk_table,
kcu_pk.column_name as fk_column,
c.ordinal_position as pos,
c.column_default as [default],
c.is_nullable as [null],
c.data_type,
c.character_maximum_length as length,
c.numeric_precision as [precision],
c.numeric_precision_radix as radix,
cast(null as bit) as [is_unique],
cast(null as int) as min_len,
cast(null as int) as max_len,
cast(null as int) as nulls,
cast(null as int) as blanks,
cast(null as int) as numerics,
cast(null as int) as distincts,
cast(null as varchar(500)) as distinct_values,
cast(null as varchar(50)) as remarks
into ##tmpColumns'
if @isQuery=1 begin
SET @tmpQ=@tmpQ+' from tempdb.information_schema.columns c, (select null as value) sp'
end
else begin
SET @tmpQ=@tmpQ+'
from information_schema.columns c
left join sysobjects so    on so.name=c.table_name  and so.xtype=''U''
left join syscolumns sc    on sc.name=c.column_name and sc.id  =so.id 
left join sys.extended_properties sp on sp.minor_id = sc.colid AND sp.major_id = sc.id and sp.name=''MS_Description''  
left join information_schema.key_column_usage kcu_fk    on kcu_fk.table_name = c.table_name     and c.column_name = kcu_fk.column_name
left join information_schema.table_constraints tc_fk    on kcu_fk.table_name = tc_fk.table_name and kcu_fk.constraint_name = tc_fk.constraint_name
left join information_schema.referential_constraints rc on rc.constraint_name = kcu_fk.constraint_name
left join information_schema.table_constraints tc_pk    on rc.unique_constraint_name = tc_pk.constraint_name
left join information_schema.key_column_usage kcu_pk    on tc_pk.constraint_name = kcu_pk.constraint_name
'
end
SET @tmpQ=@tmpQ+' where c.table_name = '''+@tableName+''''
exec(@tmpQ)
end
IF @intErrorCode=0 AND @deep = 1 BEGIN
DECLARE
@count_rows int,
@count_distinct int,
@count_nulls int,
@count_blanks int,
@count_numerics int,
@min_len int,
@max_len int,
@distinct_values varchar(500)
DECLARE curTmp CURSOR LOCAL FAST_FORWARD FOR
select [column] from ##tmpColumns;
OPEN curTmp
FETCH NEXT FROM curTmp INTO @column_name
WHILE @@FETCH_STATUS = 0 and @intErrorCode=0 BEGIN
set @tmpQ = 'USE '+DB_NAME()+'; SELECT'+
'  @count_rows=count(0), '+char(13)+char(10)+
'  @count_distinct=count(distinct ['+@column_name+']),'+char(13)+char(10)+
'  @count_nulls=sum(case when ['+@column_name+'] is null then 1 else 0 end),'+char(13)+char(10)+
'  @count_blanks=sum(case when ltrim(['+@column_name+'])='''' then 1 else 0 end),'+char(13)+char(10)+
'  @count_numerics=sum(isnumeric(['+@column_name+'])),'+char(13)+char(10)+
'  @min_len=min(len(['+@column_name+'])),'+char(13)+char(10)+
'  @max_len=max(len(['+@column_name+']))'+char(13)+char(10)+
' from ['+@tableName+']'
exec sp_executesql @tmpQ,
N'@count_rows int OUTPUT,
@count_distinct int OUTPUT,
@count_nulls int OUTPUT,
@count_blanks int OUTPUT,
@count_numerics int OUTPUT,
@min_len int OUTPUT,
@max_len int OUTPUT',
@count_rows     OUTPUT,
@count_distinct OUTPUT,
@count_nulls    OUTPUT,
@count_blanks    OUTPUT,
@count_numerics OUTPUT,
@min_len        OUTPUT,
@max_len        OUTPUT
IF (@count_distinct>10) BEGIN
SET @distinct_values='Many ('+cast(@count_distinct as varchar)+')'
END ELSE BEGIN
set @distinct_values=null
set @tmpQ = N'USE '+DB_NAME()+';'+
'  select @distinct_values=COALESCE(@distinct_values+'',''+cast(['+@column_name+'] as varchar),  cast(['+@column_name+'] as varchar))'+char(13)+char(10)+
'  from ('+char(13)+char(10)+
'    select distinct ['+@column_name+'] from ['+@tableName+'] where ['+@column_name+'] is not null) a'+char(13)+char(10)
exec sp_executesql @tmpQ,
N'@distinct_values varchar(500) OUTPUT',
@distinct_values        OUTPUT
END
UPDATE ##tmpColumns SET
is_unique      =case when @count_rows=@count_distinct then 1 else 0 end,
distincts      =@count_distinct,
nulls          =@count_nulls,
blanks         =@count_blanks,
numerics       =@count_numerics,
min_len        =@min_len,
max_len        =@max_len,
distinct_values=@distinct_values,
remarks       =
case when @count_rows=@count_nulls then 'all null,' else '' end+
case when @count_rows=@count_distinct then 'unique,' else '' end+
case when @count_distinct=0 then 'empty,' else '' end+
case when @min_len=@max_len then 'same length,' else '' end+
case when @count_rows=@count_numerics then 'all numeric,' else '' end
WHERE [column]=@column_name
FETCH NEXT FROM curTmp INTO @column_name
END
CLOSE curTmp DEALLOCATE curTmp
END
IF @intErrorCode=0 BEGIN
select * from ##tmpColumns order by pos
end
IF @intErrorCode=0 BEGIN --Clean up temporary tables
IF OBJECT_ID('tempdb..##tmpTableToAnalyse') IS NOT NULL BEGIN
DROP TABLE ##tmpTableToAnalyse
END
IF OBJECT_ID('tempdb..##tmpColumns') IS NOT NULL BEGIN
DROP TABLE ##tmpColumns
END
end
IF @intErrorCode<>0 BEGIN
RAISERROR(@errorMSG, 12, 1)
END
RETURN @intErrorCode

- Je stocker cette procédure dans la base de données de sorte que je peux l'utiliser dans toutes les bases de données comme suit:

sp_analysetable 'table_name', 1
// deep=1 for doing value analyses

Et la sortie est:


column description constraint_type fk_table fk_column pos default null data_type length precision radix is_unique min_len max_len nulls blanks numerics distincts distinct_values remarks
id_individual NULL PRIMARY KEY NULL NULL 1 NULL NO int NULL 10 10 1 1 2 0 0 70 70 Many (70) unique,all numeric,
id_brand NULL NULL NULL NULL 2 NULL NO int NULL 10 10 0 1 1 0 0 70 2 2,3 same length,all numeric,
guid NULL NULL NULL NULL 3 (newid()) NO uniqueidentifier NULL NULL NULL 1 36 36 0 0 0 70 Many (70) unique,same length,
customer_id NULL NULL NULL NULL 4 NULL YES varchar 50 NULL NULL 0 NULL NULL 70 0 0 0 NULL all null,empty,
email NULL NULL NULL NULL 5 NULL YES varchar 100 NULL NULL 0 4 36 0 0 0 31 Many (31)
mobile NULL NULL NULL NULL 6 NULL YES varchar 50 NULL NULL 0 NULL NULL 70 0 0 0 NULL all null,empty,
initials NULL NULL NULL NULL 7 NULL YES varchar 50 NULL NULL 0 NULL NULL 70 0 0 0 NULL all null,empty,
title_short NULL NULL NULL NULL 8 NULL YES varchar 50 NULL NULL 0 NULL NULL 70 0 0 0 NULL all null,empty,
title_long NULL NULL NULL NULL 9 NULL YES varchar 50 NULL NULL 0 NULL NULL 70 0 0 0 NULL all null,empty,
firstname NULL NULL NULL NULL 10 NULL YES varchar 50 NULL NULL 0 NULL NULL 70 0 0 0 NULL all null,empty,
lastname NULL NULL NULL NULL 11 NULL YES varchar 50 NULL NULL 0 NULL NULL 70 0 0 0 NULL all null,empty,
address NULL NULL NULL NULL 12 NULL YES varchar 100 NULL NULL 0 NULL NULL 70 0 0 0 NULL all null,empty,
pc NULL NULL NULL NULL 13 NULL YES varchar 10 NULL NULL 0 NULL NULL 70 0 0 0 NULL all null,empty,
kixcode NULL NULL NULL NULL 14 NULL YES varchar 20 NULL NULL 0 NULL NULL 70 0 0 0 NULL all null,empty,
date_created NULL NULL NULL NULL 15 (getdate()) NO datetime NULL NULL NULL 1 19 19 0 0 0 70 Many (70) unique,same length,
created_by NULL NULL NULL NULL 16 (user_name()) NO varchar 50 NULL NULL 0 13 13 0 0 0 1 loyalz-public same length,
id_location_created NULL FOREIGN KEY location id_location 17 NULL YES int NULL 10 10 0 1 1 0 0 70 2 1,2 same length,all numeric,
id_individual_type NULL FOREIGN KEY individual_type id_individual_type 18 NULL YES int NULL 10 10 0 NULL NULL 70 0 0 0 NULL all null,empty,
optin NULL NULL NULL NULL 19 NULL YES int NULL 10 10 0 1 1 39 0 31 2 0,1 same length,


Yep - "une pinte dans une demi-pinte pot ne sera pas aller". Je n'ai pas eu beaucoup de chance (pour quelque raison que ce soit) avec les différents SPs que les gens ont suggéré, MAIS aussi longtemps que les deux tables sont dans la même DB (ou vous pouvez les obtenir dans la même DB), vous pouvez utiliser INFORMATION_SCHEMA.Les COLONNES de localiser l'errant champ(s), ainsi:

select c1.table_name,c1.COLUMN_NAME,c1.DATA_TYPE,c1.CHARACTER_MAXIMUM_LENGTH,c2.table_name,c2.COLUMN_NAME, c2.DATA_TYPE,c2.CHARACTER_MAXIMUM_LENGTH
from [INFORMATION_SCHEMA].[COLUMNS] c1
left join [INFORMATION_SCHEMA].[COLUMNS] c2 on 
c1.COLUMN_NAME=c2.COLUMN_NAME
where c1.TABLE_NAME='MyTable1'
and c2.TABLE_NAME='MyTable2'
--and c1.DATA_TYPE<>c2.DATA_TYPE
--and c1.CHARACTER_MAXIMUM_LENGTH <> c2.CHARACTER_MAXIMUM_LENGTH
order by c1.COLUMN_NAME

Cela vous permettra de défilement vers le haut et vers le bas, en comparant les longueurs de champ, comme vous allez. Le commentaire sections vous permettent de voir (une fois retirée, évidemment) si il y a des différences de type de données, ou plus précisément pour montrer à ceux qui diffèrent par la longueur de champ - parce que je suis trop paresseux pour faire défiler - juste être conscient que la chose entière est fondée sur la source de la colonne des noms correspondant à ceux de la cible.

J'ai été en utilisant la chaîne vide "sur la création de la table et ensuite recevoir le message d'erreur" Msg 8152, Chaîne de caractères ou des données binaires seront tronquées " sur mise à jour ultérieure. Ce qui se passait en raison de la valeur de mise à jour contenant 6 caractères et être plus grande que la définition de la colonne prévue. J'ai utilisé un "ESPACE" pour contourner cela, uniquement parce que je savais que j'allais être mise à jour en vrac suite à la première création de données, c'est à dire la colonne n'allait pas rester vide longtemps.

SI GROSSE mise en garde ICI: Ce n'est pas particulièrement lisse solution, mais elle est utile dans le cas où vous êtes à rassembler un ensemble de données, par exemple sur des demandes de renseignements où vous créez un tableau pour l'exploration de données, l'application de certaines traitement en vrac/interprétation et de stocker les résultats avant et après pour comparaison ultérieure/mines. C'est un phénomène fréquent dans ma ligne de travail.

Vous pouvez remplir à l'aide de l'ESPACE de mots clés à savoir

    select 
Table1.[column1]
,Table1.[column2]
,SPACE(10) as column_name
into table_you_are_creating
from Table1
where ...

Les mises à jour ultérieures de "column_name" de 10 caractères ou moins (à remplacer le cas échéant) seront alors autorisés sans causer de tronquer erreur. Encore une fois, je tiens seulement à l'utiliser dans des scénarios similaire à celle décrite dans ma mise en garde.

Cette erreur est renvoyée lorsque la colonne d'une table permet de contrainte [ pour la plupart de la longueur ]. . E. g. si le schéma de base de données pour la colonne macolonne est de type CHAR(2), puis lors de votre appel à partir de votre application pour insérer la valeur, vous devez passer une Chaîne de caractères de longueur deux.

L'erreur de coeur, dit-il; chaîne de caractères de longueur et trois ci-dessus est incompatible pour s'adapter à la limitation de la longueur spécifiée par le schéma de base de données. C'est pourquoi SQL Server avertit et jette la perte de données/erreur de Troncation.

S'il vous plaît essayer le code suivant:

CREATE TABLE [dbo].[Department](
[Department_name] char(10) NULL
)
INSERT INTO [dbo].[Department]([Department_name]) VALUES  ('Family Medicine')
--error will occur
ALTER TABLE [Department] ALTER COLUMN [Department_name] char(50)
INSERT INTO [dbo].[Department]([Department_name]) VALUES  ('Family Medicine')
select * from [Department]