Changement de Vim swap/sauvegarder/annuler nom de fichier

Est-il possible de changer la façon dont Vim noms de ses swap//sauvegarde de fichiers d'annulation?

Pour éviter l'encombrement, j'ai mis des options dans mon ~/.vimrc pour vider ces fichiers dans ~/.vim/tmp/{swap,backup,undo}; cependant, comme je l'ai régulièrement modifier des fichiers dans des répertoires différents avec le même nom, j'ai souvent plein d'sinon impossible de distinguer les fichiers et Vim a parfois des difficultés à récupérer.

Idéalement, je voudrais utiliser le schéma de nommage que la persistance de l'annuler a (%path%to%file.undo) pour tous ces fichiers auxiliaires, il n'y a pas de moyen évident de le définir, mais peut-il être fait avec Buf{Read,Write} des macros?

InformationsquelleAutor Robbie | 2010-12-02
  1. 70

    J'ai cela dans mon .vimrc et il nomme les fichiers de swap avec le chemin complet des noms et des signes de pourcentage, juste comme vous le décrivez:

    " Store swap files in fixed location, not current directory.
set dir=~/.vimswap//,/var/tmp//,/tmp//,.

    La clé est la // à la fin de l'répertoires. Voir cette note de :help dir:

    • Pour Unix et Win32, si un répertoire se termine dans deux séparateurs de chemin "//"
      ou "\\", le nom de fichier d'échange sera construit à partir du chemin d'accès complet à
      le fichier avec tous les séparateurs de chemin substitué pour cent '%' signes.
      Ceci permettra d'assurer l'unicité du nom de fichier dans la préserver répertoire.
    • Merci, c'est le tour est joué. Espérons maintenant que je n'aurai pas de nom de collisions avec les fichiers de swap.
    • Yo ne pas avoir. si un répertoire se termine dans deux séparateurs de chemin // ou \\, le nom de fichier d'échange sera construit à partir du chemin d'accès complet vers le fichier avec tous les séparateurs de chemin substitué pour cent % signes. Ceci permettra d'assurer l'unicité du nom de fichier dans la préserver répertoire.
    InformationsquelleAutor John Kugelman supports Monica
  2. 64

    Voici une partie de mon .vimrc de github.

    Cela définit le undodir (et il tourne sur), définit la backupdir, et directory (utilisé pour .swp fichiers). Notez qu'il crée les répertoires s'ils n'existent pas déjà.

    " Save your backup files to a less annoying place than the current directory.
" If you have .vim-backup in the current directory, it'll use that.
" Otherwise it saves it to ~/.vim/backup or .
if isdirectory($HOME . '/.vim/backup') == 0
  :silent !mkdir -p ~/.vim/backup >/dev/null 2>&1
endif
set backupdir-=.
set backupdir+=.
set backupdir-=~/
set backupdir^=~/.vim/backup/
set backupdir^=./.vim-backup/
set backup

" Save your swap files to a less annoying place than the current directory.
" If you have .vim-swap in the current directory, it'll use that.
" Otherwise it saves it to ~/.vim/swap, ~/tmp or .
if isdirectory($HOME . '/.vim/swap') == 0
  :silent !mkdir -p ~/.vim/swap >/dev/null 2>&1
endif
set directory=./.vim-swap//
set directory+=~/.vim/swap//
set directory+=~/tmp//
set directory+=.

" viminfo stores the the state of your previous editing session
set viminfo+=n~/.vim/viminfo

if exists("+undofile")
  " undofile - This allows you to use undos after exiting and restarting
  " This, like swap and backup files, uses .vim-undo first, then ~/.vim/undo
  " :help undo-persistence
  " This is only present in 7.3+
  if isdirectory($HOME . '/.vim/undo') == 0
    :silent !mkdir -p ~/.vim/undo > /dev/null 2>&1
  endif
  set undodir=./.vim-undo//
  set undodir+=~/.vim/undo//
  set undofile
endif

    Espérons-le, c'est commenté assez bien pour comprendre ce qu'il se passe. Sinon, ajoutez un commentaire et je vais le corriger.

    Ciao!

    Mise à jour [07/16/2012]

    J'ai reçu un mail de Rob Kiné poser ces questions au sujet de la backupdir l'article que je voulais répondre pour tout le monde:

    1. Il semble que vous êtes en train de supprimer le répertoire courant, et puis re-ajouter. ce n'est que faire?
    2. Ce qui ne l' ^= opérateur de faire?
    3. Comment l'ordre de priorité dans l'utilisation des dossiers vérifiés travail dans Vim? (Comme l'est le dernier dossier a ajouté le premier il vérifie?)

    La première chose est de décrire les différents opérateurs. Ces opérateurs ont des significations différentes pour la non-string-options de la liste, alors soyez prévenus!

    • -= enlève de la valeur à partir d'une liste de chaînes;
    • += ajoute de la valeur à une liste de chaînes;
    • ^= ajoute de la valeur à une liste de chaînes.

    De sorte que le backupdir a la suite des opérations appliquées:

    1. Supprimer le répertoire courant à partir de la liste.
    2. Ajouter le répertoire courant à la liste (ce qui assure que c'est la dernière chose à vérifier).
    3. Supprimer le répertoire d'accueil de la liste (je n'aime pas les trucs d'être enregistrées).
    4. Ajouter ~/.vim/backup/.
    5. Ajouter ~/.vim-backup/.

    Quand Vim cherche l'emplacement où enregistrer les sauvegardes, il vérifie à partir de la première à la dernière; donc, il va vérifier pour ~/.vim-backup/, puis vérifier ~/.vim/backup, puis vérifiez la liste par défaut (sauf pour . et ~/ qui ont été supprimés), et enfin vérifier .

    Vous pouvez obtenir de l'aide pour tous ces Vim en utilisant (par exemple) :help ^= ou :help backupdir.

    • C'est l'un des meilleurs blocs de vim config relatives à ces fichiers. Merci!!!!
    • vous, monsieur, êtes un gentleman et un érudit. Je vous remercie. Que c'est beau.
    InformationsquelleAutor docwhat
  3. 2

    Créer le répertoire annuler

     $ mkdir ~/.vimundo

    Configurer votre .fichiers vimrc

     set undodir=~/.vimundo
    • Ce problème uniquement pour la première fois, vous mkdir, ai-je le droit?
    InformationsquelleAutor juque