Charger Jpg / Gif / Bitmap et convertir en bitmap

Delphi 2009 est livré avec un support intégré pour les fichiers JPEG, BMP, GIF et PNG.

Pour les versions antérieures de Delphi, vous devrez peut-être trouver tiers des implémentations pour le PNG et le GIF, mais en Delphi 2009 vous suffit d'ajouter la Jpegpngimage et GIFImg unités à votre clause uses.

Si le fichier a une extension, vous pouvez utiliser le code suivant, comme indiqué par d'autres, la TPicture.LoadFromFile regarde les extensions enregistrées par les classes héritées de déterminer l'image à charger.

uses
  Graphics, Jpeg, pngimage, GIFImg;

procedure TForm1.Button1Click(Sender: TObject);
var
  Picture: TPicture;
  Bitmap: TBitmap;
begin
  Picture := TPicture.Create;
  try
    Picture.LoadFromFile('C:\imagedata.dat');
    Bitmap := TBitmap.Create;
    try
      Bitmap.Width := Picture.Width;
      Bitmap.Height := Picture.Height;
      Bitmap.Canvas.Draw(0, 0, Picture.Graphic);
      Bitmap.SaveToFile('C:\test.bmp');
    finally
      Bitmap.Free;
    end;
  finally
    Picture.Free;
  end;
end;

Si l'extension du fichier n'est pas connu une seule méthode est de regarder les premiers octets de déterminer le type d'image.

procedure DetectImage(const InputFileName: string; BM: TBitmap);
var
  FS: TFileStream;
  FirstBytes: AnsiString;
  Graphic: TGraphic;
begin
  Graphic := nil;
  FS := TFileStream.Create(InputFileName, fmOpenRead);
  try
    SetLength(FirstBytes, 8);
    FS.Read(FirstBytes[1], 8);
    if Copy(FirstBytes, 1, 2) = 'BM' then
    begin
      Graphic := TBitmap.Create;
    end else
    if FirstBytes = #137'PNG'#13#10#26#10 then
    begin
      Graphic := TPngImage.Create;
    end else
    if Copy(FirstBytes, 1, 3) =  'GIF' then
    begin
      Graphic := TGIFImage.Create;
    end else
    if Copy(FirstBytes, 1, 2) = #$FF#$D8 then
    begin
      Graphic := TJPEGImage.Create;
    end;
    if Assigned(Graphic) then
    begin
      try
        FS.Seek(0, soFromBeginning);
        Graphic.LoadFromStream(FS);
        BM.Assign(Graphic);
      except
      end;
      Graphic.Free;
    end;
  finally
    FS.Free;
  end;
end;

Vous ne pouvez pas utiliser TPicture.LoadFromFile si vous ne savez pas quel format le graphique a, cette méthode utilise l'extension de fichier afin de déterminer lequel des graphiques enregistrés formats qui doit être chargé. Il y a une raison pour laquelle il n'y a pas de correspondance TPicture.LoadFromStream méthode.

Une bibliothèque externe qui peut examiner les données et de déterminer le format de graphique à l'exécution serait la meilleure solution. Vous pouvez utiliser le efg page comme un point de départ de votre recherche.

Un rapide et sale solution est d'essayer les quelques formats dont vous avez besoin pour gérer jusqu'à ce que l'on y réussit:

function TryLoadPicture(const AFileName: string; APicture: TPicture): boolean;
const
  GraphicClasses: array[0..3] of TGraphicClass = (
    TBitmap, TJPEGImage, TGIFImage, TPngImage);
var
  FileStr, MemStr: TStream;
  ClassIndex: integer;
  Graphic: TGraphic;
begin
  Assert(APicture <> nil);
  FileStr := TFileStream.Create('D:\Temp\img.dat', fmOpenRead);
  try
    MemStr := TMemoryStream.Create;
    try
      MemStr.CopyFrom(FileStr, FileStr.Size);
      // try various
      for ClassIndex := Low(GraphicClasses) to High(GraphicClasses) do begin
        Graphic := GraphicClasses[ClassIndex].Create;
        try
          try
            MemStr.Seek(0, soFromBeginning);
            Graphic.LoadFromStream(MemStr);
            APicture.Assign(Graphic);
            Result := TRUE;
            exit;
          except
          end;
        finally
          Graphic.Free;
        end;
      end;
    finally
      MemStr.Free;
    end;
  finally
    FileStr.Free;
  end;
  Result := FALSE;
end;

Edit:

La GraphicEx bibliothèque a un exemple convertir qui utilise

GraphicClass := FileFormatList.GraphicFromContent(...);

pour déterminer le format de graphique. Cela semble très similaire à l'VB6 façon de faire ce que vous mentionnez. Peut-être que vous pouvez utiliser cette bibliothèque pour votre but.