CoffeeScript: Getter/Setter dans les Initialiseurs d'Objets

Non, pas pour l'instant 🙁

De la CoffeeScript FAQ:

Q: allez-vous ajouter de la fonctionnalité X où X dépend de la plate-forme?

R: Non, la mise en œuvre de fonctionnalités spécifiques ne sont pas autorisés en tant que politique. Tout ce que vous écrivez en CoffeeScript doit être pris en charge et praticable, sur tout le JavaScript de mise en œuvre (dans la pratique, cela signifie que le plus petit dénominateur commun est IE6). Ainsi, les fonctionnalités suivantes ne seront pas mises en œuvre: les accesseurs & setters, le rendement.

Certains GitHub questions sur getter & poseur de syntaxe: #64, #451, #1165 (il y a une belle discussion dans le dernier).

Personnellement, je pense que le fait d'avoir getter & poseur de syntaxe littérale serait une belle fonctionnalité d'opt-in pour CoffeeScript maintenant que defineProperty est la partie de la norme ECMAScript. La nécessité pour les getters et les setters en JavaScript peut être discutable, mais vous n'êtes pas obligé de les utiliser, simplement parce qu'ils existent.

De toute façon, comme vous l'avez remarqué, il n'est pas difficile à mettre en œuvre pratique d'une fonction wrapper qui appelle Object.defineProperty pour les déclarations de classe. Personnellement, je voudrais utiliser l'approche proposée dans ici:

Function::property = (prop, desc) ->
  Object.defineProperty @prototype, prop, desc

class Person
  constructor: (@firstName, @lastName) ->
  @property 'fullName',
    get: -> "#{@firstName} #{@lastName}"
    set: (name) -> [@firstName, @lastName] = name.split ' '

p = new Person 'Robert', 'Paulson'
console.log p.fullName # Robert Paulson
p.fullName = 'Space Monkey'
console.log p.lastName # Monkey

Ou peut-être créer deux méthodes différentes:

Function::getter = (prop, get) ->
  Object.defineProperty @prototype, prop, {get, configurable: yes}

Function::setter = (prop, set) ->
  Object.defineProperty @prototype, prop, {set, configurable: yes}

class Person
  constructor: (@firstName, @lastName) ->
  @getter 'fullName', -> "#{@firstName} #{@lastName}"
  @setter 'fullName', (name) -> [@firstName, @lastName] = name.split ' '

Pour les objets simples que vous pouvez simplement utiliser Object.defineProperty (ou de l'Objet.defineProperties 😉 ) sur l'objet lui-même comme Jason proposé. Peut-être étirable dans un peu de fonction:

objectWithProperties = (obj) ->
  if obj.properties
    Object.defineProperties obj, obj.properties
    delete obj.properties
  obj

rectangle = objectWithProperties
  width: 4
  height: 3
  properties:
    area:
      get: -> @width * @height

console.log rectangle.area # 12
rectangle.width = 5
console.log rectangle.area # 15

Vous pouvez utiliser l'Objet.defineProperty directement sur les objets JSON ainsi.

obj = {}
Object.defineProperty obj, 'foo',
    get: ->
        return 'bar'

Les get/set notation ne fonctionne pas, pour diverses raisons, en CoffeeScript. La plus importante est que le compilateur n'a pas été construit pour compte pour obtenir/définir la notation.

Noter que les get/set n'est pas supporté par tous les navigateurs (en particulier, IE). Notons aussi que les nouvelles normes ECMA (ECMAScript5) mentionne l'Objet.defineProperty que la manière de définir des propriétés avec des getters/setters.

Une approche alternative:

get = (self, name, getter) ->
  Object.defineProperty self, name, {get: getter}

set = (self, name, setter) ->
  Object.defineProperty self, name, {set: setter}

prop = (self, name, {get, set}) ->
  Object.defineProperty self, name, {get: get, set: set}

class Demo 
  constructor: (val1, val2, val3) ->
    # getter only
    get @, 'val1', -> val1
    # setter only
    set @, 'val2', (val) -> val2 = val
    # getter and setter
    prop @, 'val3', 
      get: -> val3
      set: (val) -> val3 = val