Comment afficher la liste de tous les membres du groupe administrateurs local à l'aide de VBScript et WMI

J'ai besoin d'écrire un script qui récupère la liste des membres du groupe Administrateurs d'un serveur Windows à des fins de vérification. J'ai aussi besoin de montrer le nom de domaine de l'utilisateur/de groupe s'il n'est pas local.

Désolé pour la question ouverte, je pensais que je pouvais la fermer si c'est juste un partage de code, mais je ne peux pas encore 8 heures.
ce que vous pourriez faire est de poser la question "Comment puis-je liste de tous les membres..." et puis donner cela comme une réponse.
J'ai édité la réponse de la partie de la question dans la réponse. Veuillez utiliser cette méthode lorsque l'auto-répondeur sur. Ensuite, vous n'avez pas besoin de le fermer.

OriginalL'auteur Yanick Girouard | 2011-10-14

  1. 4

    Le script suivant fonctionne même sur un contrôleur de domaine:

    Sub GetAdministrators(strComputerName)
    Dim objWMIService, strQuery, colItems, Path, strMembers
    Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2")
    strQuery = "select * from Win32_GroupUser where GroupComponent = " & chr(34) & "Win32_Group.Domain='" & strComputerName & "',Name='Administrators'" & Chr(34)
    Set ColItems = objWMIService.ExecQuery(strQuery)
    strMembers = ""
    For Each Path In ColItems
        Dim strMemberName, NamesArray, strDomainName, DomainNameArray
        NamesArray = Split(Path.PartComponent,",")
        strMemberName = Replace(Replace(NamesArray(1),Chr(34),""),"Name=","")
        DomainNameArray = Split(NamesArray(0),"=")
        strDomainName = Replace(DomainNameArray(1),Chr(34),"")
        If strDomainName <> strComputerName Then
            strMemberName = strDomainName & "\" & strMemberName
        End If
        WScript.Echo strMemberName
    Next
End Sub

Function GetComputerName()
    Set objWMISvc = GetObject( "winmgmts:\\.\root\cimv2" )
    Set colItems = objWMISvc.ExecQuery( "Select * from Win32_ComputerSystem", , 48 )
    For Each objItem in colItems
        strComputerName = objItem.Name
        GetComputerName = strComputerName
    Next
End Function

GetAdministrators GetComputerName

    Pour l'exécuter, il suffit de lancer cette une fenêtre d'invite de commande:

    cscript //nologo script.vbs.

    OriginalL'auteur Yanick Girouard