Comment afficher une image en vbscript?

Je voudrais écrire un code pour afficher l'image de toutes les 20 minutes à l'aide de Vbscript. Est-il possible de charger les images à l'aide de VBscript? J'ai trouvé la LoadPicture() serait une option.

L'image devrait pop-up une fois toutes les 20 minutes dans ma fenêtre de bureau.

Comment l'utiliser? S'il vous plaît aider moi. Merci à l'avance.

Il ya des tonnes de fonds d'écran gratuits changeurs de là-bas. Une raison particulière pourquoi vous voulez le mettre en œuvre la énième (et en VBScript démarrage)?
En fait, je suis en train de créer une application qui affiche une image gif d'un clignement d'oeil toutes les 20 minutes avec un message "Veuillez cligner des yeux et de voir un objet qui est à 20 mètres de distance." J'ai pensé que je pouvais le faire avec VBScript.
Avez-vous essayé d'utiliser Windows Horaire de la Tâche à exécuter votre script ... vous pouvez planifier l'exécution après toutes les 20 minutes je crois
pourriez vous s'il vous plaît donnez-moi un exemple?
Avez posté une solution possible dans les Réponses. Laissez-moi savoir si cela fonctionne pour vous.
Connexes: Besoin d'un VBScript pour l'ouverture d'un Fichier d'Image à l'aide de l'invite de Commande
merci beaucoup pour votre aide 🙂

InformationsquelleAutor arunpandiyarajhen | 2013-12-04

image vbscript

Ok Arun. Voici ce que j'ai fait

Créer un fichier VBS avec le code suivant

Set objExplorer = CreateObject("InternetExplorer.Application")
With objExplorer
    .Navigate "about:blank"
    .Visible = 1
    .Document.Title = "Show Image"
    .Toolbar=False
    .Statusbar=False
    .Top=400
    .Left=400
    .Height=200
    .Width=200
    .Document.Body.InnerHTML = "<img src='C:\Users\pankaj\Desktop\a.jpg'>"
End With

Aller à la Fenêtre du Planificateur de Tâches et de créer une tâche
- Créer un Déclencheur pour 20 minutes Quotidiennes répétées de
- Spécifier l'Action que Démarrer un programme -> %systemroot%\system32\cscript.exe -> dans
  les arguments de donner le VBS emplacement du fichier

InformationsquelleAutor Pankaj Jaju

Vous pouvez donner un essai pour ce vbscript :

LoadImage.vbs

Option Explicit
If AppPrevInstance() Then 
MsgBox "There is an existing proceeding !" & VbCrLF & CommandLineLike(WScript.ScriptName),VbExclamation,"There is an existing proceeding !"    
WScript.Quit   
Else
Dim ws,fso,Srcimage,Temp,PathOutPutHTML,fhta
Set ws = CreateObject("wscript.Shell")
Set fso = CreateObject("Scripting.FileSystemObject")
Temp = WS.ExpandEnvironmentStrings("%Temp%")
PathOutPutHTML = Temp & "\image.hta"
Set fhta = fso.OpenTextFile(PathOutPutHTML,2,True)
Srcimage = "http://img.xooimage.com/files86/6/3/b/encode-decode-37ceb55.jpg"
Do
Call LoadImage(Srcimage)
ws.run "mshta.exe " & PathOutPutHTML
Call Pause(20)
Loop
End If
'********************************************************************************************************
Sub LoadImage(Srcimage)
fhta.WriteLine "<html>"
fhta.WriteLine "    <hta:application id=""oHTA"" "
fhta.WriteLine "        border=""none"" "
fhta.WriteLine "        caption=""no"" "
fhta.WriteLine "        contextmenu=""no"" "
fhta.WriteLine "        innerborder=""no"" "
fhta.WriteLine "        scroll=""no"" "
fhta.WriteLine "        showintaskbar=""no"" "
fhta.WriteLine "    />"
fhta.WriteLine "    <script language=""VBScript"">"
fhta.WriteLine "        Sub Window_OnLoad"
fhta.WriteLine "            'Resize and position the window"
fhta.WriteLine "            width = 760 : height = 580"
fhta.WriteLine "            window.resizeTo width, height"
fhta.WriteLine "            window.moveTo screen.availWidth\2 - width\2, screen.availHeight\2 - height\2"
fhta.WriteLine "            'Automatically close the windows after 5 seconds"
fhta.WriteLine "            idTimer = window.setTimeout(""vbscript:window.close"",10000)"
fhta.WriteLine "        End Sub"
fhta.WriteLine "    </script>"
fhta.WriteLine "<body>"
fhta.WriteLine "    <table border=0 width=""100%"" height=""100%"">"
fhta.WriteLine "        <tr>"
fhta.WriteLine "            <td align=""center"" valign=""middle"">"
fhta.WriteLine "                <img src= "& Srcimage & ">"
fhta.WriteLine "            </td>"
fhta.WriteLine "        </tr>"
fhta.WriteLine "    </table>"
fhta.WriteLine "</body>"
fhta.WriteLine "</html>"
End Sub
'**********************************************************************************************
Sub Pause(Min)
Wscript.Sleep(Min*1000*60)
End Sub  
'**********************************************************************************************
Function AppPrevInstance()   
With GetObject("winmgmts:" & "{impersonationLevel=impersonate}!\\.\root\cimv2")   
With .ExecQuery("SELECT * FROM Win32_Process WHERE CommandLine LIKE " & CommandLineLike(WScript.ScriptFullName) & _
" AND CommandLine LIKE '%WScript%' OR CommandLine LIKE '%cscript%'")   
AppPrevInstance = (.Count > 1)   
End With   
End With   
End Function   
'**************************************************************************
Function CommandLineLike(ProcessPath)   
ProcessPath = Replace(ProcessPath, "\", "\\")   
CommandLineLike = "'%" & ProcessPath & "%'"   
End Function
'**************************************************************************

InformationsquelleAutor Hackoo

Set objExplorer = CreateObject ("InternetExplorer.Application")
Do
Wscript.sleep 1200000
with objExplorer
.Navigate "about:blank"
.Document.Title = "title goes here"
.ToolBar = 0
.StatusBar = 0
.Left = (intHorizontal - 200) / 2
.Top = (intVertical - 400) / 2
.Width = 200
.Height = 400
.Visible = 1             
.Document.Body.Style.Cursor = "default"
.Document.Body.InnerHTML = "<img src='C:\Users\Administrator\Desktop\Virus\Image.jpg'>"
End With
Loop

Bienvenue à Débordement de Pile! Veuillez envisager la modification de ton post pour ajouter plus d'explications sur ce que votre code fonctionne et pourquoi il permettra de résoudre le problème. Une réponse qui, pour la plupart juste contient le code (même si ça fonctionne) généralement l'habitude d'aider les OP à comprendre leur problème.

InformationsquelleAutor Daniel

Vous devez vous connecter pour publier un commentaire.