Comment ajouter un nom de feuille à la fin de toutes les feuilles de calcul Excel?

Je suis en train d'ajouter une feuille Excel nommé "Temp" à la fin de toutes les feuilles, mais ce code ne fonctionne pas:

Private Sub CreateSheet()
    Dim ws As Worksheet
    ws.Name = "Tempo"
    Set ws = Sheets.Add(After:=Sheets(Sheets.Count))
End Sub

Pouvez-vous s'il vous plaît laissez-moi savoir pourquoi?

  • Parce que vous n'avez pas créé de ws avant l'attribution d'un .Name. Ne vous trompez pas: instanciation de la variable avant d'essayer d'accéder à ses propriétés.
  • Restaurer, c'est en effet la bonne réponse de toute façon.
InformationsquelleAutor Behseini | 2013-12-20
  1. 132

    Essayez ceci:

    Private Sub CreateSheet()
    Dim ws As Worksheet
    Set ws = ThisWorkbook.Sheets.Add(After:= _
             ThisWorkbook.Sheets(ThisWorkbook.Sheets.Count))
    ws.Name = "Tempo"
End Sub

    Ou utiliser un With clause pour éviter à plusieurs reprises d'appeler votre objet

    Private Sub CreateSheet()
    Dim ws As Worksheet
    With ThisWorkbook
        Set ws = .Sheets.Add(After:=.Sheets(.Sheets.Count))
        ws.Name = "Tempo"
    End With
End Sub

    Ci-dessus peut être simplifiée si vous n'avez pas besoin d'appel sur la même feuille de calcul dans le reste du code.

    Sub CreateSheet()
    With ThisWorkbook
        .Sheets.Add(After:=.Sheets(.Sheets.Count)).Name = "Temp"
    End With
End Sub
    • pourquoi ce qui est mauvais? vous n'êtes pas de la création de la feuille du même classeur?
    • ThisWorkbook est le classeur qui héberge l'exécution d'une macro. ActiveWorkbook est le classeur de l'utilisateur est de travail (dit en termes clairs). WorkBooks("abc") aborde un classeur
    • +1 court et doux 🙂
    • Sympa, mais ce qui se passe si une fiche existe déjà, ne Serait-il jeter une erreur ?
    • Oui. Si le même nom existe déjà ou si vous utilisez un nom valide.
    • Oh, j'ai testé et cela effectivement n', merci pour les commentaires

    InformationsquelleAutor L42
  2. 30

    Veuillez utiliser cette seule ligne:

    Sheets.Add(After:=Sheets(Sheets.Count)).Name = "new_sheet_name"
    • Désolé, mais le a accepté de répondre à l'air mieux. Celui-ci n'est pas explicitement indiquer ThisWorkbook ou ActiveWorkbook. Aussi, la nouvelle feuille de calcul de l'objet ici n'est pas affectée à une variable, alors que par la suite presque toujours, vous voulez l'utiliser pour mettre des données dans la feuille.
    • Je pense que cette réponse fait le truc le mieux. Il n'est pas précisé que la feuille doit être affectée à une variable. Il sais c'est un nom bien évidemment puisque c'est spécifié dans le code.
    InformationsquelleAutor Amar
  3. 6
    ThisWorkbook.Sheets.Add After:=Sheets(Sheets.Count)
ActiveSheet.Name = "XYZ"

    (lorsque vous ajoutez une feuille de calcul, de toute façon ça va être la feuille active)

    InformationsquelleAutor Saptarshi
  4. 5

    Essayez ceci:

    Public Enum iSide
iBefore
iAfter
End Enum
Private Function addSheet(ByRef inWB As Workbook, ByVal inBeforeOrAfter As iSide, ByRef inNamePrefix As String, ByVal inName As String) As Worksheet
    On Error GoTo the_dark

    Dim wsSheet As Worksheet
    Dim bFoundWS As Boolean
    bFoundWS = False
    If inNamePrefix <> "" Then
        Set wsSheet = findWS(inWB, inNamePrefix, bFoundWS)
    End If

    If inBeforeOrAfter = iAfter Then
        If wsSheet Is Nothing Or bFoundWS = False Then
            Worksheets.Add(After:=Worksheets(Worksheets.Count)).Name = inName
        Else
            Worksheets.Add(After:=wsSheet).Name = inName
        End If
    Else
        If wsSheet Is Nothing Or bFoundWS = False Then
            Worksheets.Add(Before:=Worksheets(1)).Name = inName
        Else
            Worksheets.Add(Before:=wsSheet).Name = inName
        End If
    End If

    Set addSheet = findWS(inWB, inName, bFoundWS)         ' just to confirm it exists and gets it handle

    the_light:
    Exit Function
    the_dark:
    MsgBox "addSheet: " & inName & ": " & Err.Description, vbOKOnly, "unexpected error"
    Err.Clear
    GoTo the_light
End Function
    InformationsquelleAutor Mr F
  5. 3

    Essayez d'utiliser:

    Worksheets.Add (After:=Worksheets(Worksheets.Count)).Name = "MySheet"

    Si vous voulez vérifier si une feuille avec le même nom existe déjà, vous pouvez créer une fonction:

    Function funcCreateList(argCreateList)
    For Each Worksheet In ThisWorkbook.Worksheets
        If argCreateList = Worksheet.Name Then
            Exit Function ' if found - exit function
        End If
    Next Worksheet
    Worksheets.Add (After:=Worksheets(Worksheets.Count)).Name = argCreateList
End Function

    Lorsque la fonction est créée, vous pouvez l'appeler à partir de votre principal secondaire, par exemple:

    Sub main

    funcCreateList "MySheet"

Exit Sub
    InformationsquelleAutor Ivan Tokarev
  6. 2

    Cela vous donnera la possibilité de:

    1. Écraser ou de Préserver un onglet qui porte le même nom.
    2. Placer la feuille à la Fin de tous les onglets ou à Côté de l'onglet en cours.
    3. Sélectionnez votre Nouvelle feuille ou Active.
    Call CreateWorksheet("New", False, False, False)


Sub CreateWorksheet(sheetName, preserveOldSheet, isLastSheet, selectActiveSheet)
  activeSheetNumber = Sheets(ActiveSheet.Name).Index

  If (Evaluate("ISREF('" & sheetName & "'!A1)")) Then 'Does sheet exist?
    If (preserveOldSheet) Then
      MsgBox ("Can not create sheet " + sheetName + ". This sheet exist.")
      Exit Sub
    End If
      Application.DisplayAlerts = False
      Worksheets(sheetName).Delete
    End If

    If (isLastSheet) Then
      Sheets.Add(After:=Sheets(Sheets.Count)).Name = sheetName 'Place sheet at the end.
    Else 'Place sheet after the active sheet.
      Sheets.Add(After:=Sheets(activeSheetNumber)).Name = sheetName
    End If

    If (selectActiveSheet) Then
      Sheets(activeSheetNumber).Activate
    End If

End Sub
    InformationsquelleAutor moberme
  7. 1


    Essayez de changer l'ordre de votre code. Vous devez créer la feuille de calcul en premier afin de le nommer.

    Private Sub CreateSheet()
    Dim ws As Worksheet
    Set ws = Sheets.Add(After:=Sheets(Sheets.Count))
    ws.Name = "Tempo"
End Sub

    merci,

    InformationsquelleAutor Developer
  8. -3

    C'est un moyen rapide et simple d'ajouter un onglet nommé à la feuille de calcul en cours:

    Sheets.Add.Name = "Tempo"
    InformationsquelleAutor Jan