Comment appeler une fonction/procédure de manière asynchrone en Delphi (Sans composants)

Si vous vous demandez si la VCL a quelque chose comme BeginInvoke .NET out-of-the-box, alors la réponse est non. Cependant, vous pouvez obtenir quelque chose d'assez semblable dans la forme d'un petit appareil que vous reliez à votre programme, le AsyncCalls bibliothèque par Andreas Hausladen. Ce n'est pas un composant, donc je suppose qu'il qualifie. Il prend également en charge Delphi à partir de la version 5 et suivants. Très recommandé.

Edit:

Je vais ajouter un exemple puisque vous ne l'avez pas en cours d'exécution. Si vous obtenez le blocage dans votre code appelant, alors votre problème est l'absence de référence est conservé à la IAsyncCall pointeur d'interface que la fonction se termine. L'objet de la mise en œuvre de l'interface sera donc détruit immédiatement lorsque le renvoi temporaire est hors de portée. Le destructeur sera appelé dans le contexte de la VCL fil, et il va appeler WaitForSingleObject() ou une fonction similaire à attendre que le thread de travail à terminer. Le résultat de cela est que votre VCL thread se bloque.

Vous obtiendrez le comportement correct si vous maintenez une référence pour le pointeur d'interface:

type
  TForm1 = class(TForm)
    Button1: TButton;
    Timer1: TTimer;
    procedure FormCloseQuery(Sender: TObject; var CanClose: Boolean);
    procedure Button1Click(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
  private
    fAsyncCall: IAsyncCall;
    procedure WaitForIt(ADelay: integer);
  end;

De régler la minuterie pour être désactivé et la laisser en un très court Interval, par exemple, de 50 ms. Cliquez sur le bouton lance l'opération asynchrone:

procedure TForm1.Button1Click(Sender: TObject);
begin
  Button1.Enabled := FALSE;
  fAsyncCall := AsyncCall(WaitForIt, 1000);
end;

procedure TForm1.WaitForIt(ADelay: integer);
begin
  Sleep(ADelay);

  EnterMainThread;
  try
    Randomize;
    Color := RGB(Random(256), Random(256), Random(256));
    Timer1.Enabled := TRUE;
  finally
    LeaveMainThread;
  end;
end;

Alors que l'opération est active aucune autre peut-être commencé. À la fin, il permet la minuterie pour informer la forme et de réinitialiser l'interface de référence:

procedure TForm1.Timer1Timer(Sender: TObject);
begin
  Timer1.Enabled := FALSE;
  Assert((fAsyncCall <> nil) and fAsyncCall.Finished);
  fAsyncCall := nil;
  Button1.Enabled := TRUE;
end;

procedure TForm1.FormCloseQuery(Sender: TObject; var CanClose: Boolean);
begin
  CanClose := (fAsyncCall = nil) or fAsyncCall.Finished;
end;

Remarque comment il est même possible d'accéder au formulaire directement à partir de la méthode appelée, en utilisant EnterMainThread() et LeaveMainThread().

Code ci-dessus n'est pas le minimum absolu, elle est destinée à illustrer certaines idées.

OriginalL'auteur mghie