Comment avez-vous bande de citations de l'ÉCHO ed chaîne de caractères dans un fichier de commandes Windows?

Vous pouvez utiliser le %var:x=y% de la construction, qui remplace tous x avec y.

Voir cet exemple ce qu'il peut faire:

set I="Text in quotes"
rem next line replaces " with blanks
set J=%I:"=%
echo original %I%
rem next line replaces the string 'in' with the string 'without' 
echo stripped %J:in=without%

Pour supprimer tous les guillemets à partir d'un ensemble de variables, vous avez besoin d'Expansion Retardée de Variables de façon sécurisée élargir la variable et de la traiter. L'Expansion à l'aide de signes de pourcentage (c'est à dire %VAR% et %1) sont intrinsèquement dangereux (ils sont vulnérables à la commande d'injection; lire ceci pour plus de détails).

SETLOCAL EnableDelayedExpansion
SET VAR=A ^"quoted^" text.
REM This strips all quotes from VAR:
ECHO !VAR:^"=!
REM Really that's it.

À la bande de citations à partir d'un fichier texte ou d'une sortie de commande, les choses vont se compliquer car, avec l'Expansion Retardée, la chaîne !VAR! dans le document texte obtiendrez élargi (au sein de la %%i expansion dans FOR /F) quand il ne devrait pas. (C'est une autre vulnérabilité de divulgation d'informations—qui n'est pas documentée ailleurs.)

En toute sécurité de parser le document, un commutateur entre retardée d'extension activé et désactivé de l'environnement est nécessaire.

REM Suppose we fetch the text from text.txt

SETLOCAL DisableDelayedExpansion
REM The FOR options here employs a trick to disable both "delims"
REM characters (i.e. field separators) and "eol" character (i.e. comment
REM character).
FOR /F delims^=^ eol^= %%L IN (text.txt) DO (

    REM This expansion is safe because cmd.exe expands %%L after quotes
    REM parsing as long as DelayedExpansion is Disabled. Even when %%L
    REM can contain quotes, carets and exclamation marks.
    SET "line=%%L"

    CALL :strip_quotes
    REM Print out the result. (We can't use !line! here without delayed
    REM expansion, so do so in a subroutine.)
    CALL :print_line
)
ENDLOCAL
GOTO :EOF

REM Reads !line! variable and strips quotes from it.
:strip_quotes
    SETLOCAL EnableDelayedExpansion
    SET line=!line:^"=!

    REM Make the variable out of SETLOCAL
    REM I'm expecting you know how this works:
    REM (You may use ampersand instead:
    REM `ENDLOCAL & SET "line=%line%"`
    REM I just present another way that works.)
    (
    ENDLOCAL
    SET "line=%line%"
    )
GOTO :EOF

:print_line
    SETLOCAL EnableDelayedExpansion
    ECHO !line!
    ENDLOCAL
GOTO :EOF

La delims^=^ eol^= dans le code ci-dessus a probablement besoin d'explication:
Cela permet de désactiver les deux "delims" des personnages (c'est à dire séparateurs de champ) et "fin de vie" (à savoir que caractère de commentaire). Sans elle, la "delims" sera, par défaut, à onglet et de l'espace et de la "fin de vie" par défaut, un point-virgule.

• La eol= jeton de toujours lire quel que soit le caractère suivant c'est après le signe égal. Pour désactiver ce jeton doit être à la fin de la chaîne d'options de sorte qu'aucun caractère ne peut être utilisé pour "eol", effectivement en le désactivant. Si la chaîne d'options est cité, il peut utiliser les guillemets (") comme la "fin de vie", donc il ne faut pas citer la chaîne d'options.
• La delims= option, lorsqu'elle n'est pas la dernière option dans les options de la chaîne, sera terminé par un espace. (Pour inclure l'espace dans "delims" il doit être la dernière option de FOR /F options.) Donc delims= suivi d'un espace puis une autre option désactive le "delims".

La réponse ci-dessus (en commençant par :DeQuote) suppose retardé l'expansion des variables d'environnement est définie sur on. Cmd /?:

Retardé l'expansion des variables d'environnement n'est PAS activé par défaut. Vous
pouvez activer ou désactiver retardé l'expansion des variables d'environnement pour un
particulier invocation de CMD.EXE avec le /V:SUR ou /V:OFF. Vous
pouvez activer ou désactiver la fin pour toutes les invocations de CMD.EXE sur un
machine et/ou de l'utilisateur d'ouverture de session de la session par la définition de l'une ou des deux
suivant REG_DWORD valeurs dans le registre à l'aide de REGEDT32.EXE:

HKEY_LOCAL_MACHINE\Software\Microsoft\Command Processor\DelayedExpansion

    and/or

HKEY_CURRENT_USER\Software\Microsoft\Command Processor\DelayedExpansion

à la valeur 0x1 ou 0x0. L'utilisateur paramètre spécifique l'emporte sur
le paramètre de la machine. Les commutateurs de ligne de commande prévalent sur les
les paramètres du registre.

Si le retard expansion des variables d'environnement est activée, le point d'exclamation
caractère qui peut être utilisé pour remplacer la valeur d'une variable d'environnement
au moment de l'exécution.

Je sais qu'il n'est pas fait pour l'auteur, mais si vous avez besoin d'envoyer du texte le fichier sans les guillemets - la solution ci-dessous fonctionne pour moi. Vous n'avez pas besoin d'utiliser des guillemets dans l'écho de commande, il suffit d'entourer la commande complète avec des crochets.

(
    echo first very long line
    echo second very long line with %lots% %of% %values%
) >"%filename%"

Daniel Budzyński la réponse est génial. Il fonctionne même dans les situations où il y a des caractères spéciaux dans la sortie. Par exemple:

C:\> for /f "usebackq tokens=2 delims=:" %i in (`%comspec%\..\ping -n 1 -w 200 10.200.1.1 ^| \
     findstr /c:"TTL="`) do echo|set /p="%i"

bytes=32 time<1ms TTL=255

Si vous essayez essayé de faire un simple echo sans les guillemets, vous obtenez une erreur, en raison de la "<" dans la variable:

C:\> set "output=bytes=32 time<1ms TTL=255"
C:\> echo %output%
The system cannot find the file specified.

C:\> echo|set /p="%output%"
bytes=32 time<1ms TTL=255

http://unxutils.sourceforge.net/ est un natif win32 port d'un tas d'utilitaires GNU, y compris sed, gawk, grep et wget. (désolé que je n'ai pas assez de rep à la poste comme un commentaire!)