Comment basculer entre plusieurs vim configurations avec une commande locale ou fichiers vimrc?

En Résumé

Il ya quelques façons de le faire, dont la plupart ont été suggérées, mais j'ai pensé que je devais résumer avec deux de plus:

• Répertoire vimrc - a l'inconvénient que Vim doit être démarré dans le bon répertoire: si votre projet est en ~/project1 et vous avez ~/project1/.vim.custom et ne cd ~ ; vim project1/file.c, les paramètres personnalisés ne sera pas trouvé.
• Modelines - très efficace, mais a l'inconvénient d'avoir besoin d'ajouter tous les fichiers (et n'oubliez pas d'ajouter de nouveaux fichiers)
• Répertoire spécifique autocommands - c'est très efficace
• Analyse pour un en-tête spécifique dans le fichier (voir ci-dessous) - c'est celui que j'ai le plus utilisés dans le passé, travaillant pour des sociétés différentes ou sur des projets
• Répertoire vimrc c'est cochée lorsque le fichier est ouvert (voir ci-dessous). Un autre assez facile à mettre en œuvre, surtout si votre projet de code est tous en un seul endroit.

De numérisation pour un en-Tête

Dans beaucoup d'organisations, il y a un en-tête standard (avec un avis de droit d'auteur et le nom du projet, etc) en haut de chaque fichier source. Si c'est le cas, vous pouvez obtenir Vim pour scanner automatiquement la première (par exemple) 10 lignes du fichier à la recherche pour un mot clé. Si il le trouve, il peut modifier vos paramètres. J'ai modifié cela pour faire plus simple que la forme que j'utilise (ce qui fait beaucoup d'autres choses), mais de créer un ~/.vim/after/filetype.vim (si vous n'en avez pas encore) et d'ajouter quelque chose comme ceci:

au FileType * call <SID>ConfigureFiletypes(expand("<amatch>"))

" List of file types to customise
let s:GROUPNAMETypes = ['c', 'cpp', 'vhdl', 'c.doxygen']

func! <SID>CheckForGROUPNAMECode()
    " Check if any of the first ten lines contain "GROUPNAME".

    " Read the first ten lines into a variable
    let header = getline(1)
    for i in range(2, 10)
        let header = header . getline(i)
    endfor

    if header =~ '\<GROUPNAME\>'
        " Change the status line to make it clear which
        " group we're using
        setlocal statusline=%<%f\ (GROUPNAME)\ %h%m%r%=%-14.(%l,%c%V%)\ %P
        " Do other customisation here
        setlocal et
        " etc
    endif
endfunc

func! <SID>ConfigureFiletypes(filetype)
    if index(s:GROUPNAMETypes, a:filetype) != -1
        call <SID>CheckForGROUPNAMECode()
    endif
endfunc

Chaque fois qu'un fichier de n'importe quel type s'ouvre et le fichier est de type set (le au FileType * ligne), le ConfigureFiletypes fonction est appelée. Celui-ci vérifie que le type de fichier dans la liste des types de fichier associée avec le groupe actuel (GROUPNAME), dans ce cas, 'c', 'rpc', 'vhdl' ou 'c.doxygen'. Si elle l'est, elle appelle CheckForGROUPNAMECode(), qui lit les 10 premières lignes du fichier et si elles contiennent GROUPNAME, il fait un peu de personnalisation. Ainsi que la mise en expandtabs ou que ce soit, cela change aussi la barre d'état pour afficher le nom du groupe clairement alors que vous savez qu'il est travaillé en un clin d'œil.

La vérification de la Configuration Lors de l'Ouverture de

Comme JS Bangs " suggestion, d'avoir un fichier de configuration personnalisé peut être utile. Cependant, au lieu de le charger dans vimrc, pensez à quelque chose de ce genre, qui va vérifier si une .c fichier est ouvert pour un .vim.personnalisé dans le même répertoire que le .c fichier.

au BufNewFile,BufRead *.c call CheckForCustomConfiguration()

function! CheckForCustomConfiguration()
    " Check for .vim.custom in the directory containing the newly opened file
    let custom_config_file = expand('%:p:h') . '/.vim.custom'
    if filereadable(custom_config_file)
        exe 'source' custom_config_file
    endif
endfunction

Vous pouvez aussi mettre autocommands dans votre .vimrc qui définir des options spécifiques par chemin de base.

au BufRead,BufNewFile /path/to/project1/* setl sw=4 et
au BufRead,BufNewFile /path/to/project2/* setl sw=3 noet

En supposant que vos collègues développeurs de ne pas se plaindre à ce sujet, vous pouvez toujours ajouter vim paramètres de chaque fichier dans les commentaires.

/*
 * vim:ts=4:sw=4:expandtab:...
 */

int main(int argc, char **argv)
{
    ...

Après avoir essayé le localvimrc plugin proposé par le commentaire précédent, j'aime beaucoup de non-futzy par projet de contrôle sur vim paramètres.

Il n'demander confirmation avant de charger une .lvimrc de fichier par défaut, mais il y a un paramètre à se charger automatiquement .lvimrc fichiers. Certains pourraient voir cela comme un trou de sécurité, mais il fonctionne comme annoncé.

Que j'ai choisi .gitignore l' .lvimrc fichiers. Sinon, vous pouvez les consulter en tant que forme de partage des paramètres (onglet/espace expansion, tabulations, d'autres configurations spécifiques au projet).

Ici une variation sur le jamessan de

function! ConditionalLoad()
    let cwd = getcwd()
    if getcwd() =~ $HOME . "/src/mobile"
        so $HOME/.vim.mobile
    endif
endfunction
autocmd VimEnter * call ConditionalLoad()

Je vais souvent lancer vi sans un fichier spécifique que je suis de sauter à donc cela permet de chargement config conditionnelle basée sur le répertoire de travail courant. Inconvénient, c'est que la config n'est pas basé sur fichier, mais hors de répertoire de travail.