Comment boucler toutes les propriétés d'une classe

J'ai une classe dans mon application Delphi où je voudrais un moyen facile et dynamique de la réinitialisation de toutes les propriétés de la chaîne d' " et toutes les propriétés booléennes à False
Aussi loin que je peux voir sur le web, il devrait être possible de faire une boucle d'une certaine sorte, mais comment faire, il n'est pas clair pour moi.

source d'informationauteur OZ8HP

  1. 10

    Veuillez noter que le code suivant ne fonctionne que pour la publication des propriétés d'une classe! Aussi, l'instance d'une classe est passée à la fonction ci-dessous doit au moins avoir publié l'article défini!

    Ici est de savoir comment définir la publication de la chaîne de valeurs de propriété à une chaîne vide et la valeur booléenne False en utilisant le style ancien de la RTTI.

    Si vous avez Delphi âgés de plus de Delphi 2009, vous pourriez être à côté de la tkUString type. Si oui, il suffit de retirer
    à partir du code suivant:

    uses
  TypInfo;

procedure ResetPropertyValues(const AObject: TObject);
var
  PropIndex: Integer;
  PropCount: Integer;
  PropList: PPropList;
  PropInfo: PPropInfo;
const
  TypeKinds: TTypeKinds = [tkEnumeration, tkString, tkLString, tkWString,
    tkUString];
begin
  PropCount := GetPropList(AObject.ClassInfo, TypeKinds, nil);
  GetMem(PropList, PropCount * SizeOf(PPropInfo));
  try
    GetPropList(AObject.ClassInfo, TypeKinds, PropList);
    for PropIndex := 0 to PropCount - 1 do
    begin
      PropInfo := PropList^[PropIndex];
      if Assigned(PropInfo^.SetProc) then
      case PropInfo^.PropType^.Kind of
        tkString, tkLString, tkUString, tkWString:
          SetStrProp(AObject, PropInfo, '');
        tkEnumeration:
          if GetTypeData(PropInfo^.PropType^)^.BaseType^ = TypeInfo(Boolean) then
            SetOrdProp(AObject, PropInfo, 0);
      end;
    end;
  finally
    FreeMem(PropList);
  end;
end;

    Ici est un simple test de code (notez les propriétés doivent être publiées; si il n'y a pas publié les propriétés de la classe, au moins vide publié l'article doit être là):

    type
  TSampleClass = class(TObject)
  private
    FStringProp: string;
    FBooleanProp: Boolean;
  published
    property StringProp: string read FStringProp write FStringProp;
    property BooleanProp: Boolean read FBooleanProp write FBooleanProp;
  end;

procedure TForm1.Button1Click(Sender: TObject);
var
  SampleClass: TSampleClass;
begin
  SampleClass := TSampleClass.Create;
  try
    SampleClass.StringProp := 'This must be cleared';
    SampleClass.BooleanProp := True;
    ResetPropertyValues(SampleClass);
    ShowMessage('StringProp = ' + SampleClass.StringProp + sLineBreak +
      'BooleanProp = ' + BoolToStr(SampleClass.BooleanProp));
  finally
    SampleClass.Free;
  end;
end;
  2. 15

    si vous êtes un Delphi 2010 (et plus) de l'utilisateur il est une nouvelle RTTI unité (rtti.pas). vous pouvez l'utiliser pour obtenir les informations d'exécution sur votre classe et de ses propriétés (propriétés publiques par défaut, mais vous pouvez utiliser {$RTTI} directive du compilateur d'inclure privé et protégé des champs d'information).
    Par exemple, nous avons à côté de la classe de test avec 3 champs publics (1 booléenne et 2 champs de type chaîne (l'un d'eux est readonly)).

        TTest = class(TObject)
      strict private
        FString1 : string;
        FString2 : string;
        FBool : boolean;
      public
        constructor Create();
        procedure PrintValues();

        property String1 : string read FString1 write FString1;
        property String2 : string read FString2;
        property BoolProp : boolean read FBool write FBool;
    end;

constructor TTest.Create();
begin
    FBool := true;
    FString1 := 'test1';
    FString2 := 'test2';
end;

procedure TTest.PrintValues();
begin
    writeln('string1 : ', FString1);
    writeln('string2 : ', FString2);
    writeln('bool: ', BoolToStr(FBool, true));
end;

    pour énumérer toutes les propriétés de l'objet et de définir les valeurs de par défaut vous pouvez utiliser quelque chose comme le code ci-dessous.
    Tout d'abord à tous vous avez à init TRttiContext structure (il n'est pas nécessaire, parce que c'est un record). Alors vous devriez obtenir rtti informations sur votre obejct, après que vous pouvez boucler vos propriétés et le filtre (sauter readonly propriétés et d'autres que booléen et stirng). Prendre en compte qu'il y a peu de type de cordes : tkUString, tkString et d'autres (jetez un coup d'oeil à TTypeKind dans typinfo.pas)

        TObjectReset = record
      strict private
      public
        class procedure ResetObject(obj : TObject);  static;
    end;

{ TObjectReset }

class procedure TObjectReset.ResetObject(obj: TObject);
var ctx : TRttiContext;
    rt : TRttiType;
    prop : TRttiProperty;
    value : TValue;
begin
    ctx := TRttiContext.Create();
    try
        rt := ctx.GetType(obj.ClassType);

        for prop in rt.GetProperties() do begin
            if not prop.IsWritable then continue;

            case prop.PropertyType.TypeKind of
                tkEnumeration : value := false;
                tkUString :      value := '';
                else continue;
            end;
            prop.SetValue(obj, value);
        end;
    finally
        ctx.Free();
    end;
end;

    simple code à tester:

    var t : TTest;
begin
    t := TTest.Create();
    try
        t.PrintValues();
        writeln('reset values'#13#10);
        TObjectReset.ResetObject(t);
        t.PrintValues();
    finally
        readln;
        t.Free();
    end;
end.

    et le résultat est

    string1 : test1
string2 : test2
bool: True
reset values

string1 :
string2 : test2
bool: False

    aussi jeter un oeil à Attributsde l'omi, il est bon de marquer les propriétés (dont vous avez besoin pour réinitialiser) avec un certain attribut, et peut-être avec la valeur par défaut comme:

    [ResetTo('my initial value')]
property MyValue : string read FValue write FValue;

    ensuite, vous pourrez filtrer uniquement les propriétés qui sont marqués avec ResetToAttribute