Comment calculer MIPS de mon processeur?

En ligne avec ce que tu voulais, voici quelques bootloader code qui s'exécute une sorte de repère qui peuvent être probablement utilisé pour mesurer le MIPS. Le principal objectif ici était de bas niveau, et je crois que c'est le niveau le plus bas auquel vous pouvez réellement programme avec le PC, sauf si vous êtes prêt à remplacer votre BIOS ou quelque chose.

De toute façon, c'est le code pour une image de disquette qui, lorsqu'il est démarré, vous essayez d'exécuter quatre instructions (deux adds, l'une sub, et un saut conditionnel) un million de fois. Combien de fois les instructions sont exécutées est contrôlée par le ITERS macro. En soulevant ou en abaissant vous pouvez spécifier le nombre d'itérations est censé être fait.

Temps est mesuré à l'aide de la rdtsc instruction, qui retourne le nombre de processeur tiques accomplis depuis sa mise sous tension, comme un nombre de 64 bits dans les registres edx et eax. Par calcul de la différence de cette valeur avant l'exécution de la boucle, et avant, nous obtenons le nombre de tiques que le processeur passé à l'exécution. Cette valeur est ensuite sortie à l'écran à l'aide du BIOS 10h appel comme une valeur hexadécimale. Le temps réel passé sur il est, évidemment, dépend du processeur de fréquence de l'horloge.

Voici le code source. Si vous le compiler à l'aide de MSNA avec -f bin, vous obtiendrez l'image de la disquette qui devrait être écrit sur une disquette à l'aide de certains bloc brut programme d'écriture, par exemple dd. Puis, lors du démarrage, choisissez le lecteur de disquette comme le support d'amorçage. Tout ce qui peut également fonctionner avec une clé USB, mais c'est beaucoup plus dépendant du BIOS. Comme avec tous les trucs qui est tellement faible niveau, je ne prends aucune responsabilité pour les résultats de l'exécution de ce logiciel sur votre ordinateur.

bits 16
org 0x7c00

ITERS equ 1000000

jmp 0x0000:start

start:
    cli
    xor ax, ax
    mov ds, ax
    mov ss, ax
    mov sp, stack_end

    rdtsc
    mov [old_rdtsc], eax
    mov [old_rdtsc+4], edx
    mov eax, ITERS

.loop:
    add ebx, ecx
    add ecx, edx

    sub eax, 1
    jnz .loop

    rdtsc

    sub eax, [old_rdtsc]
    sbb edx, [old_rdtsc+4]

    mov si, 15

.fillbuf_eax:
    mov edi, eax
    shr eax, 4
    and di, 0xf
    mov bl, [hex_chars+di]
    mov [str_buf+si], bl
    sub si, 1
    cmp si, 7
    ja .fillbuf_eax

.fillbuf_edx:
    mov edi, edx
    shr edx, 4
    and di, 0xf
    mov bl, [hex_chars+di]
    mov [str_buf+si], bl
    sub si, 1
    jns .fillbuf_edx

    mov ah, 0xe
    xor bx, bx
.bios_write:
    pusha
    mov al, [str_buf+bx]
    int 10h
    popa
    add bx, 1
    cmp bx, 16
    jb .bios_write

    sti

.halt:
    hlt
    jmp .halt

hex_chars db "0123456789ABCDEF"
old_rdtsc resq 1
str_buf resb 16

STACK_SIZE equ 200
stack resb STACK_SIZE
stack_end equ $

times 510-($-$$) db 0x90
db 0x55, 0xaa

Sur mon vieux AMD Athlon XP 1700+, j'obtiens 0x1e8596 comme un résultat de l'exécution de ce code, qui est égal à 2000278 CPU tiques. Que le CPU tourne à 1466MHz, c'est plus ou moins égal à environ 1,36 ms.

OriginalL'auteur Daniel Kamil Kozar

Il y a une liste de MIPS par processortype à un certain GHZ être trouvé sur

http://en.wikipedia.org/wiki/Instructions_per_second

Sinon, vous pouvez programmer l'indice de référence et l'exécuter (dans une console, sans beaucoup de course) ou à télécharger à l'indice de référence à partir de quelque part adn exécuter que.....

OriginalL'auteur IvoTops