Comment changer le nom de la série en VBA

J'ai une série de tableaux, je suis entrain de créer à l'aide de VBA (code ci-dessous).

Je vais avoir du mal à changer le nom de la série à partir de la série 1 et de série 2 à l'État Actuel et l'État de la Solution.

Je reçois un

Variable objet ou Variable Bloc with non définie

erreur.

Toutefois sans le srs1 et srs2 code les cartes fonctionnent très bien (juste avec le mauvais noms de série).

J'ai regardé comment résoudre ce problème et la réponse que j'ai reçue n'est cependant pas de travail pour moi.
Quelqu'un sait-il un autre moyen pour ce faire?

Sub MA()
    Dim Srs1 As Series
    Dim Srs2 As Series
    Dim i  As Integer
    Dim MAChart As Chart
    Dim f As Integer
    f = 2 * Cells(2, 14)
     For i = 1 To f Step 2
        Set MAChart = ActiveSheet.Shapes.AddChart(Left:=750, Width:=400, Top:=130 + 50 * (i - 1), Height:=100).Chart
         With MAChart
         .PlotBy = xlRows
         .ChartType = xlColumnClustered
         .SetSourceData Source:=ActiveSheet.Range("Q" & 1 + i & ":Z" & 2 + i)
         .Axes(xlValue).MaximumScale = 4
         .Axes(xlValue).MinimumScale = 0
         .HasTitle = True
         .ChartTitle.Text = "Provider Load for " & Cells(i + 1, 15)
         'where errors start- works fine up to this point
         Set Srs1 = ActiveChart.SeriesCollection(1) 
         Srs1.Name = "Current State"
         Set Srs2 = ActiveChart.SeriesCollection(2) 
         Srs2.Name = "Proposed Solution"
         End With
    Next i
End Sub
Il n'y a pas de graphique actif. Utilisation Set Srs1 = .SeriesCollection(1) etc.

OriginalL'auteur Cam | 2015-07-21

  1. 8

    Essayez de modifier ces lignes ...

         Set Srs1 = ActiveChart.SeriesCollection(1) 
     Srs1.Name = "Current State"
     Set Srs2 = ActiveChart.SeriesCollection(2) 
     Srs2.Name = "Proposed Solution"

    ... 

         .SeriesCollection(1).Name = "Current State"
     .SeriesCollection(2).Name = "Proposed Solution"

    Vous utilisez déjà MAChart à l'intérieur de votre bloc de sorte que vous devriez être en mesure d'accéder à ses .SeriesCollection(x).Name propriétés de la même manière que vous l'avez fait pour les autres propriétés.

    OriginalL'auteur 3-14159265358979323846264

  2. 2

    Je crois que le problème est avec le référencement - dans le code de référence ActiveChart (je suppose qu'il n'existe pas), alors que vous avez créé MAChart dans le code ci-dessus.

     Set Srs1 = MAChart.SeriesCollection(1) 
 Srs1.Name = "Current State"
 Set Srs2 = MAChart.SeriesCollection(2) 
 Srs2.Name = "Proposed Solution"
    Ou tout simplement Set Srs1 = .SeriesCollection(1) etc.

    OriginalL'auteur Juliusz