Comment code un spinner pour les processus en attente dans un fichier Batch?

Cela peut être fait assez facilement avec de la pure native des commandes, vous avez juste à savoir comment utiliser le plus délicat d'entre eux. Pas d'utilisation d'outils externes tels que VBScript ou des effets secondaires désagréables comme l'effacement de l'écran sont nécessaires.

Ce que vous cherchez est l'équivalent de la fête "echo -n" de commande qui génère une ligne, sans saut de ligne. Dans XP lot, ceci est réalisé en utilisant "set /p" (demander à l'utilisateur pour la réponse à une invite de commandes) avec vide d'entrée comme suit:

<nul (set /p junk=Hello)
echo. again.

sera la sortie de la chaîne de caractères "Bonjour." sans le moindre saut de ligne.

Ce truc (et l'utilisation de CTRL-H, le caractère de retour arrière peut être vu dans le script de test suivant qui commence (l'un après l'autre) 10-deuxième sous-tâche avec 20 secondes de délai d'attente et 15 de la deuxième sous-tâche avec un 10 secondes de délai d'attente.

La charge utile script est créé par le script et sa seule exigence est qu'il ne le travail qu'il a à faire, puis supprimez un fichier flag lorsque vous avez terminé, de sorte que la fonction de moniteur sera en mesure de le détecter.

Garder à l'esprit que le ^H des chaînes dans ce script sont en fait CTRL-H caractères, le ^| est deux caractères distincts utilisés pour échapper à la pipe symbole.

@echo off

:: Localise environment.
setlocal enableextensions enabledelayedexpansion

:: Specify directories. Your current working directory is used
:: to create temporary files tmp_*.*
set wkdir=%~dp0%
set wkdir=%wkdir:~0,-1%

:: First pass, 10-second task with 20-second timeout.
del "%wkdir%\tmp_*.*" 2>nul
echo >>"%wkdir%\tmp_payload.cmd" ping 127.0.0.1 -n 11 ^>nul
echo >>"%wkdir%\tmp_payload.cmd" del "%wkdir%\tmp_payload.flg"
call :monitor "%wkdir%\tmp_payload.cmd" "%wkdir%\tmp_payload.flg" 20

:: Second pass, 15-second task with 10-second timeout.
del "%wkdir%\tmp_*.*" 2>nul:
echo >>"%wkdir%\tmp_payload.cmd" ping 127.0.0.1 -n 16 ^>nul
echo >>"%wkdir%\tmp_payload.cmd" del "%wkdir%\tmp_payload.flg"
call :monitor "%wkdir%\tmp_payload.cmd" "%wkdir%\tmp_payload.flg" 10

goto :final

:monitor
    :: Create flag file and start the payload minimized.
    echo >>%2 dummy
    start /min cmd.exe /c "%1"

    :: Start monitoring.
    ::    i is the indicator (0=|,1=/,2=-,3=\).
    ::    m is the number of seconds left before timeout.
    set i=0
    set m=%3
    <nul (set /p z=Waiting for child to finish: ^|)

    :: Loop here awaiting completion.
    :loop
        :: Wait one second.
        ping 127.0.0.1 -n 2 >nul

        :: Update counters and output progress indicator.
        set /a "i = i + 1"
        set /a "m = m - 1"
        if %i% equ 4 set i=0
        if %i% equ 0 <nul (set /p z=^H^|)
        if %i% equ 1 <nul (set /p z=^H/)
        if %i% equ 2 <nul (set /p z=^H-)
        if %i% equ 3 <nul (set /p z=^H\)

        :: End conditions, complete or timeout.
        if not exist %2 (
            echo.
            echo.   Complete.
            goto :final
        )
        if %m% leq 0 (
            echo.
            echo.   *** ERROR: Timed-out waiting for child.
            goto :final
        )
        goto :loop
:final
endlocal

OriginalL'auteur

Si vous n'avez pas l'esprit de l'écran de compensation...essayez ceci:

@ECHO OFF

SETLOCAL ENABLEDELAYEDEXPANSION
SET COUNT=1

START CALC

:BEGIN
  CLS
  IF !COUNT! EQU 1 ECHO \
  IF !COUNT! EQU 2 ECHO -
  IF !COUNT! EQU 3 ECHO /
  IF !COUNT! EQU 4 ECHO -
  IF !COUNT! EQU 4 (
    SET COUNT=1
  ) ELSE (
    SET /A COUNT+=1
  )
  PSLIST CALC >nul 2>&1
  IF %ERRORLEVEL% EQU 1 GOTO END
GOTO BEGIN

:END

EDIT: dans Cet exemple, vous démarrer la Calculatrice, puis d'afficher un "spinner" jusqu'à la fermeture de la Calculatrice. J'utilise pslist pour vérifier l'existence d'CALC.EXE. Le >nul 2>,&1 redirige la sortie standard STDOUT et STDERR à nul, donc rien de PSLIST sera affiché.

OriginalL'auteur

Le spinner PEUT être fait dans le script de traitement par lot, vous avez juste besoin de quelques variables:

@echo off

:spinner
set mSpinner=%mSpinner%.
if %mSpinner%'==..............................' set mSpinner=.
cls
echo %mSpinner%

rem Check if the process has finished via WMIC and/or tasklist.

goto spinner


:exit

Pour la chauve-souris elle-même pour détecter un processus en cours d'exécution/sorties. Vous pouvez le faire via le WMI interface de ligne de commande ou la commande tasklist dont j'ai une connaissance limitée.

Si elle était de retour dans le DOS jours, vous pourriez même ne fait que sans effacer l'écran... bref de l'aide d'une combinaison de caractères d'échappement. Je ne sais pas si c'est encore possible sur Vista/XP.

OriginalL'auteur

Vous pouvez utiliser un compteur qui imprime un caractère différent à partir d'un ensemble donné (comme "\|/-") et que vous changez le caractère selon comme "compteur modulo 4". De toute façon, vous ne dites pas la langue dans laquelle vous travaillez en tant qu'il est un peu difficile d'être plus précis.

EDIT: maintenant que nous savons de l'environnement dans lequel vous jouez, je dirais que la chauve-souris/CMD langue n'est pas vraiment à la hauteur... je le recommande importe quel langage de script Ruby être mon préféré.

OriginalL'auteur

paxdiablos a une étonnante réponse, mais d'avoir à l'écho de vos commandes dans un payload fichier est ennuyeux. C'est dur à lire et difficile à déboguer. J'ai pris son code et l'a modifié un peu pour mon propre usage:

@echo off

:: Localise environment.
setlocal enableextensions enabledelayedexpansion

set wkdir=%~dp0%
set wkdir=%wkdir:~0,-1%
set done_flag="%wkdir%\tmp_payload.flg"
set timeout=7


:controller

IF (%1)==() (
    call :monitor step1 "Getting stuff from SourceSafe: "
    call :monitor step2 "Compiling some PHP stuff: "
    call :monitor step3 "Finishing up the rest: "
) ELSE ( goto %1 )

goto final


:step1
::ping for 5 seconds
    ping 127.0.0.1 -n 6 >nul
    del "%wkdir%\tmp_payload.flg"
goto final

:step2
::ping for 10 seconds
    ping 127.0.0.1 -n 11 >nul
    del "%wkdir%\tmp_payload.flg"
goto final

:step3
::ping for 5 seconds
    ping 127.0.0.1 -n 6 >nul
    del "%wkdir%\tmp_payload.flg"
goto final

:monitor
:: Create flag file and start the payload minimized.
:: echo the word "dummy" to the flag file (second parameter)
    echo >>%done_flag% dummy
:: start the command defined in the first parameter
    start /min cmd.exe /c "test2.bat %1"

:: Start monitoring.
::    i is the indicator (0=|,1=/,2=-,3=\).
::    m is the number of seconds left before timeout.
set i=0
set m=%timeout%
set str=%2
for /f "useback tokens=*" %%a in ('%str%') do set str=%%~a

<nul (set /p z=%str%^|)

:: Loop here awaiting completion.
:loop
    :: Wait one second.
    ping 127.0.0.1 -n 2 >nul

    :: Update counters and output progress indicator.
    set /a "i = i + 1"
    set /a "m = m - 1"
    if %i% equ 4 set i=0
    if %i% equ 0 <nul (set /p z=^|)
    if %i% equ 1 <nul (set /p z=/)
    if %i% equ 2 <nul (set /p z=-)
    if %i% equ 3 <nul (set /p z=\)

    :: End conditions, complete or timeout.
    if not exist %done_flag% (
        ::echo.
        echo Complete
        goto :final
    )
    if %m% leq 0 (
        echo.
        echo.   *** ERROR: Timed-out waiting for child.
        goto :final
    )
    goto :loop

:final
endlocal

OriginalL'auteur

démarrage de l'application, attendez le chargement

@echo off & setlocal enabledelayedexpansion
start application.exe
:1
for %%a in (^| ^/^- ^\ ^| ^/^- ^\) do (
for %%b in (^| ^/^- ^\ ^| ^/^- ^\) do (
for %%c in (^| ^/^- ^\ ^| ^/^- ^\) do (
cls &echo processing..%%c%%b%%a
sleep -m 20
IF EXIST "result file" (exit)
)))
goto 1

OriginalL'auteur