comment compter le nombre d'enregistrements en ASP classique?

Je ne suis pas assez familier avec la programmation ASP classique. J'ai juste besoin d'un petit code à exécuter sur ma page web. Comment dois-je compter de l'enregistrement de la requête?

<%
Set rsscroll = Server.CreateObject("ADODB.Recordset")
Dim strSQLscroll, rsscroll
strSQLscroll = "SELECT * FROM tblItems where expiration_date > getdate() order by expiration_date desc;"
rsscroll.open strSQLscroll,oConn
%>

merci,

OriginalL'auteur | 2009-06-29

asp-classic

8

Il est possible (mais non recommandé) d'utiliser la propriété RecordCount sur l'objet Recordset comme suit:
```
iTotalRecords = rsscroll.RecordCount
```
Si votre table est vraiment grand, cela peut prendre un certain temps à s'exécuter. Je voudrais lancer à la place séparée requête SQL pour obtenir le nombre total d'enregistrements
```
SQL = "SELECT COUNT(*) AS TotalRecords FROM tblItems WHERE expiration_date > getdate() "
set rsRecordCount = conn.Execute(SQL)
if not rsRecordCount.Eof then
  iTotalRecords = rsRecordCount.Fields("TotalRecords")
else
  iTotalRecords = 0
end if
rsRecordCount.Close
set rsRecordCount = nothing
```
Bonne approche, qui Fonctionne pour moi 🙂

OriginalL'auteur Bork Blatt
6

rsscroll.RecordCount

Qui pourrait fonctionner, mais il peut également renvoyer -1. Par exemple, la valeur par défaut de SQL server firehose ensemble de lignes à ne pas céder un nombre de lignes jusqu'à ce que tous les records ont été consommés par l'appelant.
Gardez à l'esprit que vous devez avoir nocount réglé sur on. voir stackoverflow.com/a/16617637/356544

OriginalL'auteur Chris Klepeis

Une solution simple est d'utiliser le SQL COMPTER de la méthode. Cela suppose que vous voulez que le nombre de lignes et de ne pas les données elles-mêmes.

<%
    Set rsscroll = Server.CreateObject("ADODB.Recordset")
    Dim strSQLscroll, rsscroll, intRow
    strSQLscroll = "SELECT COUNT(*) AS Total FROM tblItems WHERE expiration_date > getdate();"
    rsscroll.open strSQLscroll, oConn
    response.write rsscroll("Total")
    rsscroll.close: set rsscroll = nothing 
    oConn.close: set oConn = nothing 
%>

Cela renvoie une ligne avec une valeur unique appelé "Total". (Lisez la suite si vous le souhaitez, le nombre de lignes et de données.)

Votre code de requête utilise une valeur par défaut du jeu d'enregistrements, qui renvoie des données en "forward-only" mode pour plus d'efficacité. Il franchit la ligne-par-ligne, mais ne sait pas le nombre réel. (Ce mode définit également le jeu d'enregistrements.RecordCount de -1, de sorte que le champ n'est pas utile pour vous.)

Jeu d'enregistrements.Ouvrez le "Curseur" Type de paramètre vous permet de changer de "Clavier" mode (valeur de paramètre 1), qui ne définir le champ RecordCount pour le nombre de lignes de données. ("Type de serrure" et "Type de Commande" paramètres inclus pour l'intégralité, mais ils ne figure pas dans cette réponse.)

RecordsetObject.Open "TableName|SQLStatement", ConnectionObject [,Cursor Type] [,Lock Type] [,Command Type]

Ajouter ce paramètre à votre code de jeu d'enregistrements.Appel ouvert, puis vérifier RecordCount.

<%
    Set rsscroll = Server.CreateObject("ADODB.Recordset")
    Dim strSQLscroll, rsscroll, intRow
    strSQLscroll = "SELECT * FROM tblItems where expiration_date > getdate() order by expiration_date desc;"
    rsscroll.open strSQLscroll, oConn, 1
    intRow = rsscroll.RecordCount
    ' ... do something with intRow
    rsscroll.close: set rsscroll = nothing 
    oConn.close: set oConn = nothing 
%>

Si les performances de la base signifie quoi que ce soit à votre situation, l' jeu d'enregistrements.GetRows() méthode est beaucoup plus efficace.

<% 
    Dim rsscroll, intRow, rsArray
    Set oConn = CreateObject("ADODB.Connection") 
    oConn.open "<connection string>" 
    strSQLscroll = "SELECT * FROM tblItems where expiration_date > getdate() order by expiration_date desc" 
    Set rsscroll = conn.execute(strSQLscroll) 
    if not rsscroll.eof then 
        rsArray = rsscroll.GetRows() 
        intRow = UBound(rsArray, 2) + 1 
        response.write "rows returned: " & intRow
        ' ... do any other operations here ... 
    end if 
    rsscroll.close: set rsscroll = nothing 
    oConn.close: set oConn = nothing 
%>

OriginalL'auteur Matthew Glidden

1

Vous pouvez simplement modifier votre SQL à compter le nombre d'enregistrements:
```
strSQLscroll = "SELECT count(*) as Total FROM tblItems where expiration_date > getdate();"
```
Ensuite vous avez juste besoin de response.write rsscroll("Total")

OriginalL'auteur Dan
1

J'ai l'habitude utiliser une requête "select count(*) from table" pour obtenir compte car habituellement, j'ai besoin non seulement le comte, mais une somme du nombre d'unités ou le prix moyen ou quoi que ce soit et il est plus facile d'écrire une requête distincte que de faire plus de variables et de dire "TotalUnits = TotalUnits + rs (les"Parts").valeur" à l'intérieur de la boucle pour afficher les résultats. Il est également très utile pour les fois où vous avez besoin pour afficher les totaux ci-dessus, les résultats et vous ne voulez pas de boucle si le jeu d'enregistrements en double.

OriginalL'auteur tooshel

Obtenir dans le habbit de stocker les données renvoyées dans des tableaux. C'est incroyablement plus rapide pour effectuer une itération que l'utilisation d'ouvrir un jeu d'enregistrements. Aussi, spécifier les champs à sélectionner lorsque vous faites ce que vous avez à faire référence explicitement à l'index du tableau.

<%
Set rsscroll = Server.CreateObject("ADODB.Recordset")
Dim strSQLscroll, rsscroll
Dim arrCommon

'Open recordset, copy data to array
strSQLscroll = "SELECT field1, field2, field3 FROM tblItems where expiration_date > getdate() order by expiration_date desc;"
rsscroll.open strSQLscroll,oConn
    arrCommon = rsscroll.getRows()
rsscroll.close

'Get the total records in this array
response.write ubound(arrCommon, 2);

'Loop...
for i = 0 to ubound(arrCommon, 2)

    ' This prints field 3
    response.write arrCommon(2, i)

next
%>

OriginalL'auteur Tom Gullen

<%
'TableID = vos tables ID...

Set rsscroll = Server.CreateObject("ADODB.Recordset") Dim strSQLscroll, rsscroll strSQLscroll = "SELECT *,(SELECT TableID FROM tblItems where expiration_date > getdate()) As Count FROM tblItems where expiration_date > getdate() order by expiration_date desc;" 
rsscroll.open strSQLscroll,oConn
Count = rsscroll("Count")

OriginalL'auteur Chris Dowdeswell

Vous pouvez essayer ce

    Dim count
    count = 0
    if strSQLscroll.eof <> true or strSQLscroll.bof <> true then
       while not strSQLscroll.eof
          count = count+1
          strSQLscroll.movenext
       wend
    end if
    response.write(count)

OriginalL'auteur Mandeep Singh

Si vous utilisez MySQL, essayez ceci:

Dim strSQLscroll, rsscroll, countrs

Set rsscroll = Server.CreateObject("ADODB.Recordset")
rsscroll.CursorLocation = 3
rsscroll.open "SELECT * FROM tblItems where expiration_date > getdate()
order by expiration_date desc;",oConn

countrs = rsscroll.recordcount

Bienvenue à Débordement de Pile! Alors que ce code peut répondre à la question, en fournissant plus de contexte sur pourquoi et/ou comment ce code répond à la question améliore sa valeur à long terme.

OriginalL'auteur Marcolla M

Vous devez vous connecter pour publier un commentaire.