comment connecter un utilisateur de Drupal (ou d'obtenir de l'utilisateur actuellement connecté) à partir de Flex/Flash?

J'ai une application Flash qui est hébergée dans une page Drupal. Certaines parties de l'application Flash devrait être disponible pour tous les utilisateurs, mais certains ne devraient être à la disposition d'un utilisateur connecté. (Le rôle spécifique n'a pas d'importance, juste qu'ils sont tout utilisateur autorisé du site).

À partir de Flash, je peux détecter si l'utilisateur est connecté par grattage d'écran de l' "?q=user" de la page, mais c'est très fragile. Quelle est la "bonne" façon de faire cela? Je peux installer d'autres Modules si nécessaire, mais ils doivent être compatibles avec Drupal 6, pas 5.

De même, si aucun utilisateur n'est actuellement connecté, comment puis-je prendre un nom d'utilisateur et le mot de passe qu'ils m'apportent et les enregistre dans (ou déterminer que le mot de passe est mauvais)?

InformationsquelleAutor Eric | 2008-11-11
  1. 4

    La "bonne" solution

    vous avez probablement envie de regarder quelque chose comme la module de services. fondamentalement, vous voulez exposer l'utilisateur de services pour votre flash app, de sorte que vous pouvez envoyer des demandes (via XML-RPC ou que ce soit la mise en œuvre de votre choix) pour obtenir de l'information comme "ce que l'accès ne l'actuel connecté en utilisateur", ou "de connexion de cet utilisateur avec le nom d'utilisateur x et le mot de passe y", etc...

    Le faire vous-même rapidement la solution

    si vous êtes familier avec le développement de modules, vous pouvez créer votre propre module rapidement pour obtenir exactement les fonctionnalités dont vous avez besoin, sans avoir à passer par un "vrai" couche de services web. voici un exemple rapide, la création d'un module appelé "myservices":

    <?php
//myservices.info
   name = My Services
   description = Expose basic services
   core = 6.x

<?php
//myservices.module

   function myservices_menu() {
       $items['myservices/user'] = array(
         'title' => 'Get auth',
         'page callback' => 'myservices_get_user',
         'access arguments' => array('access content'),
       );
       return $items;
   }

   function myservices_get_user() {
       global $user;
       if (in_array('authenticated user', $user->roles) ) {
           print 'yes';
       } else {
           print 'no';
       }
   }

    mettre ces deux fichiers dans un répertoire "myservices" dans votre répertoire de modules, l'activer, puis aller à http://yourdomain.com/myservices/user

    si vous êtes authentifié, il va tout simplement de retour yes, et si pas no, etc... que vous pouvez trouver dans votre flash app.

    InformationsquelleAutor Owen
  2. 2

    J'ai été en mesure de le faire à l'aide de Drupal dans le "système" et "utilisateur" services:

    • installer le Module De Services
    • activer le "système" et "utilisateur" services
    • pour le code ci-dessous, désactiver les Clés API. (Ou de le laisser activé et à l'approvisionnement des arguments supplémentaires)
    • la permission à la fois authentifié utilisateurs anonymes et à des services d'accès

    De cette écriture, la AMFPHP service n'est pas encore porté sur Drupal 6, j'ai donc utilisé XMLRPC. Pour utiliser XMLRPC à partir d'ActionScript, j'ai utilisé la bibliothèque d'aide à as3-rpclib. Cette bibliothèque a été écrite pour ActionScript2, afin de l'utiliser avec Flex3 m'a obligé à le patcher, comme décrit à la cette page (faites défiler la page et de recherche pour un commentaire le 10 Mai 2008, par "jameshyu").

    Une fois toutes ces conditions préalables sont pris en charge, vous pouvez vérifier l'utilisateur actuellement connecté (le cas échéant) et/ou une ouverture de session d'un utilisateur avec un code comme suit.

    Voici le module qui fait met en œuvre la connexion:

    package
{
import com.ak33m.rpc.xmlrpc.XMLRPCObject;
import flash.events.*;
import flash.net.*;
import mx.collections.ItemResponder;
import mx.rpc.AsyncToken;
import mx.rpc.events.FaultEvent;
import mx.rpc.events.ResultEvent;
public class DrupalLogin
{
private var _api:XMLRPCObject;
public function DrupalLogin( url:String )
{
_api = new XMLRPCObject();
_api.endpoint = url;
_api.destination = "";
}
public function set LoginResult( fn:Function ):void {_handleLoginResult = fn; }
public function set CheckResult( fn:Function ):void {_handleCheckResult = fn; }
public function set LogoutResult( fn:Function ):void {_handleLogoutResult = fn; }
public function get User():String { return _user; }
public function set TraceResult( fn:Function ):void {_handleTrace = fn; }
private var _handleLoginResult:Function;
private var _handleCheckResult:Function;
private var _handleLogoutResult:Function;
private var _handleTrace:Function;
private function onTrace( st:String ):void
{
_handleTrace(st);
}
private var _firstCheckDone:Boolean = false;
private var _loggedIn:Boolean = false;
//The logged-in user's ID (if any)
private var _user:String = "";
//*****************************************
//doLogin
//*****************************************
//Function doLogin kicks off the process.
public function doLogin( user:String, pwd:String ):void
{
onTrace( "******************* doLogin ********************" );
if( !_firstCheckDone )
{
_handleLoginResult( false, "ALWAYS CALL doCheck() FIRST TO SEE IF YOU NEED TO LOG IN OR NOT" );
return;
}
if( _loggedIn )
{
_handleLoginResult( true, "YOU ARE ALREADY LOGGED IN" );
return;
}
var token:AsyncToken = _api.call( "user.login", _sid, user, pwd );
var tresponder:ItemResponder = new ItemResponder(this.onLoginInfo,this.onLoginFault);
token.addResponder(tresponder);
}
private function onLoginInfo (event:ResultEvent,token:Object = null):void
{
onTrace( "... got onLoginInfo" );
_user = event.result.user.name;
_loggedIn = true;
_handleLoginResult( true, "logged in ok" );         
}
private function onLoginFault (event:FaultEvent, token:Object=null):void
{
onTrace( "   got onLoginFault" );
_loggedIn = false;
_handleLoginResult( false, "Fault: " + event.fault.faultString + " -- " + event.fault.faultCode);
}
//*****************************************
//doLogout
//*****************************************
public function doLogout():void
{
onTrace( "******************* doLogout ********************" );
if( !_firstCheckDone )
{
_handleLogoutResult( false, "ALWAYS CALL doCheck() FIRST TO SEE IF YOU ARE ABLE TO LOG OUT OR NOT" );
return;
}
if( !_loggedIn )
{
_handleLogoutResult( true, "YOU ARE ALREADY LOGGED OUT" );
return;
}
var token:AsyncToken = _api.call( "user.logout", _sid );
var tresponder:ItemResponder = new ItemResponder(this.onLogoutInfo,this.onLogoutFault);
token.addResponder(tresponder);
}
private function onLogoutInfo (event:ResultEvent,token:Object = null):void
{
onTrace( "got onLogoutInfo" );
_loggedIn = false;
_handleLogoutResult( true, "logged out ok" );           
}
private function onLogoutFault (event:FaultEvent, token:Object=null):void
{
onTrace( "got onLogoutFault" );
_loggedIn = false;
_handleLogoutResult( false, "Fault: " + event.fault.faultString + " -- " + event.fault.faultCode);
}
//*****************************************
//doCheckLogin
//*****************************************
private var _sid:String;
public function doCheckLogin():void
{
onTrace( "******************* doCheckLogin ********************" );
var token:AsyncToken = _api.call( "system.connect" );
var tresponder:ItemResponder = new ItemResponder(this.onCheckInfo,this.onCheckFault);
token.addResponder(tresponder);
}
private function onCheckInfo (event:ResultEvent,token:Object = null):void
{
onTrace( "got onCheckInfo" );
_user = event.result.user.name;
_sid = event.result.user.sid;
var roles:Object = event.result.user.roles;
_loggedIn = false;
for( var i:int=0; i<10; i++ )
{
var tmp:String = roles[i.toString()];
if( tmp == "authenticated user" )
_loggedIn = true;
}
trace( "user = " + _user + ", sid=" + _sid + ", loggedIn=" + _loggedIn );
_firstCheckDone = true;
_handleCheckResult( _loggedIn, _loggedIn?("Currently logged in as " + _user):"Not logged in yet" );
}
private function onCheckFault (event:FaultEvent, token:Object=null):void
{
onTrace( "got onCheckFault" );
_handleCheckResult( false, "Fault: " + event.fault.faultString + " -- " + event.fault.faultCode);
}
}
}

    et voici un exemple d'utilisation:

    <?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute">
<mx:Script source="LoginExample.as" />
<mx:Button id="btnGoodLogin" click="btnGoodLogin_onClick()"  label="Good Login" enabled="true" y="28"/>
<mx:Button id="btnBadLogin" click="btnBadLogin_onClick()"  label="Bad Login" enabled="true" y="28" x="112"/>
<mx:Button id="btnLogout" click="btnLogout_onClick()"  label="Logout" enabled="true" y="28" x="219"/>
<mx:Button id="btnCheck" click="btnCheck_onClick()"  label="Check" enabled="true" y="28" x="325"/>
<mx:Text id="txtResult"  y="58" width="263"/>
</mx:Application>
import flash.events.*;
import flash.net.*;
private var _login:DrupalLogin;
private function setup():void
{
if( _login==null )
{
var url:String = "http://myserver/mydrupal?q=services/xmlrpc";
_login = new DrupalLogin(url);
_login.CheckResult = handleCheckResult;
_login.LoginResult = handleLoginResult;
_login.LogoutResult = handleLogoutResult;
_login.TraceResult = handleTraceResult;
}
}
private function btnGoodLogin_onClick():void
{
setup();
_login.doLogin( "goodname", "goodpwd" );
}
private function btnBadLogin_onClick():void
{
setup();
_login.doLogin( "badname", "badpwd" );
}
private function btnLogout_onClick():void
{
setup();
_login.doLogout();
}
private function btnCheck_onClick():void
{
setup();
_login.doCheckLogin();
}
private function showResult( result:String):void
{
trace( "showResult: " + result );
txtResult.text = result;    
}
private function handleTraceResult( text:String ):void
{
trace( text );
}
private function handleCheckResult( loggedIn:Boolean, txt:String="" ):void
{
if( txt != "" )
txt = " (" + txt + ")";
if( loggedIn )
showResult( "ALREADY LOGGED IN AS " + _login.User + txt);
else
showResult( "NOT LOGGED IN YET" + txt );
}
private function handleLoginResult( loggedIn:Boolean, txt:String="" ):void
{
if( txt != "" )
txt = " (" + txt + ")";
if( loggedIn )
showResult( "LOGIN ATTEMPT SUCCEEDED" + txt);
else
showResult( "LOGIN ATTEMPT FAILED" + txt );
}
private function handleLogoutResult( loggedOut:Boolean, txt:String="" ):void
{
if( txt != "" )
txt = " (" + txt + ")";
if( loggedOut )
showResult( "LOGOUT ATTEMPT SUCCEEDED" + txt );
else
showResult( "LOGOUT ATTEMPT FAILED" + txt);
}
    InformationsquelleAutor Eric
  3. 0

    Je sais que c'est un long chemin à partir de quand ce post a été à l'origine, mais si vous êtes toujours intéressé par ce et n'a jamais pris le temps de faire des recherches beaucoup, j'ai compris la façon de traiter avec succès une connexion par le biais d'un document flash. (Celui qui est intégré ou externe pour cette question.) Il n'a même pas besoin d'AMFPHP à être installé sur le système. (Ce qui est bien parce que la dernière que j'ai vérifié le module de services qui AMFPHP dépend n'a pas encore un état recommandé.)

    J'ai créé une page de démonstration ici: AS3 Login Page de Démonstration

    Vous pouvez de connexion et de déconnexion, et il permet de détecter si vous êtes déjà connecté. C'est toujours un travail en cours, mais la plupart des choses que vous avez besoin est aménagé pour vous.

    Si vous voulez voir la documentation et souhaitez qu'une copie de la source de tout cela est disponible ici: http://www.andrewnprice.com

    J'espère que ça aide. Je doit faire une mise à jour de la démo dans le courant de la semaine prochaine, alors revenez si vous voulez quelques autres fonctionnalités que j'ai oublier d'ajouter dans le post.

    InformationsquelleAutor