Comment créer des options de dialogue avec VbScript?

J'ai une application tierce partie qui invoque un vsbscript fichier pour certaines opérations. Je voudrais mettre en place une invite utilisateur avec un choix d'options, soit une liste déroulante ou une case à cocher ou quelque chose du genre. Cependant, tout ce que je peux trouver est la zone d'entrée de l'option.

Je ne pense pas que l'Hta sont une option dans mon cas (sauf si il y a un moyen de les appeler à partir d'un .fichier vbs?)

Mon autre pensée était une sorte de contrôle ActiveX, mais je ne peut pas localiser un construit-dans ce qui serait disponible par défaut sur windows xp/Vista.

Quelqu'un a des idées sur comment je pourrais y arriver?

Pouvez-vous modifier la 3ème partie de VBScript? Si vous pouvez nous donner un peu plus de détails, nous pourrions avoir des meilleures options pour vous.
Oui, l'édition du vbscript est exactement ce que nous faisons. La 3ème partie du produit entraîne automatiquement si elle est présente.

OriginalL'auteur Nathan | 2009-05-28

vbscript

La réponse est simple, vous ne pouvez vraiment pas. Tmdean la solution est la seule façon que je peux penser. Cela dit, vous pouvez embellir l'entrée de la boîte de sorte qu'il n'a pas l'air horrible. Donner à ce terme, je ne pense pas que c'est un épique échouer:

Dim bullet
Dim response
bullet = Chr(10) & "   " & Chr(149) & " "
Do
    response = InputBox("Please enter the number that corresponds to your selection:" & Chr(10) & bullet & "1.) Apple" & bullet & "2.) Bannana" & bullet & "3.) Pear" & Chr(10), "Select Thing")
    If response = "" Then WScript.Quit  'Detect Cancel
    If IsNumeric(response) Then Exit Do 'Detect value response.
    MsgBox "You must enter a numeric value.", 48, "Invalid Entry"
Loop
MsgBox "The user chose :" & response, 64, "Yay!"

OriginalL'auteur Oorang

Si vous souhaitez utiliser une hta pour cela, il peut être fait comme ceci.

Le VBScript:


Set WshShell = CreateObject("WScript.Shell")
'Run the hta.
WshShell.Run "Test.hta", 1, true
'Display the results.
MsgBox "Return Value = " & getReturn
Set WshShell = Nothing

Function getReturn
'Read the registry entry created by the hta.
On Error Resume Next
     Set WshShell = CreateObject("WScript.Shell")
    getReturn = WshShell.RegRead("HKEY_CURRENT_USER\Volatile Environment\MsgResp")
    If ERR.Number  0 Then
        'If the value does not exist return -1
         getReturn = -1
    Else
        'Otherwise return the value in the registry & delete the temperary entry.
        WshShell.RegDelete "HKEY_CURRENT_USER\Volatile Environment\MsgResp"
    End if
    Set WshShell = Nothing
End Function

Ensuite de concevoir le code de la route comme vous le souhaitez, et comprennent les méthodes suivantes



'Call this when the OK button is clicked.
Sub OK_Click
    For Each objradiobutton In Opt
         If objradiobutton.Checked Then
              WriteResponse objradiobutton.Value
        End If
    Next
    window.Close
End Sub

'Call this when the Cancel button is clicked.
Sub Cancel_Click
     WriteResponse("CANCEL")
     window.Close
End Sub

'Write the response to the registry
Sub WriteResponse(strValue)
    Set WshShell = CreateObject("WScript.Shell")
    WshShell.RegWrite "HKEY_CURRENT_USER\Volatile Environment\MsgResp", strValue
     Set WshShell = Nothing
End Sub

J'ai utilisé un groupe de boutons radio nommé "Opt" à faire un choix, mais vous pouvez utiliser toutes les commandes que vous souhaitez.

Parce que l'hta est impossible de valeurs de retour, cela permettra de créer un temperary entrée de registre. Si vous n'êtes pas comforatable déconner avec le registre, vous pouvez également écrire le résultat dans un temperary fichier texte.

Cette approche est agréable parce que vous pouvez concevoir le code de la route comme vous le souhaitez, plutôt que de l'aide de la fonction inputbox et de choisir des numéros (c'est afin que le DOS).

Cela pourrait aussi être sympa si vous élargi le code de la route pour créer de lui-même fondé sur des arguments qui lui sont transmis, comme passer dans un titre, un message à l'écran, un tableau d'options, un ensemble de boutons. De cette façon, vous pouvez utiliser le même hta tout moment vous avez besoin pour obtenir l'entrée de l'utilisateur.

OriginalL'auteur Tester101

3

Vous pouvez utiliser DialogLib pour créer des formulaires avec des listes déroulantes et des cases à cocher. DialogLib en est encore à ce ealy étapes, mais il est déjà très utile: http://www.soren.schimkat.dk/Blog/?p=189

OriginalL'auteur Søren Schimkat
1

Essayer WshShell.Popup. En fonction de vos données qui peut travailler pour vous...

Sinon, vous pourriez enquêter sur PowerShell.

Si je comprends WshShell.Popup correctement, cela ne me donne pas les options pour créer mon propre arbitraire de la liste, par exemple, "Queue1, Queue2, Queue3" etc, donc je ne vois pas qu'elle gagne moi rien de différent de ce que l'régulier de la zone de saisie (wsh2.uw.hu/ch08b.html)
Vous pouvez l'utiliser à plusieurs reprises-à-dire, aimeriez-vous que l'option 1, puis aimeriez-vous de l'option 2, etc. Pas l'idéal, mais c'EST un langage de script avec à peu près pas d'INTERFACE utilisateur.
Vous pouvez toujours utiliser le Oui Non Peut-être de boutons Annuler et ensuite expliquer à l'utilisateur que Oui dire bla, Pas de dire oui, Annuler signifie bon....etc. mais vraiment c'est le genre de laid.

OriginalL'auteur RedFilter
1

Une option est de faire un script de Internet Explorer. Vous pouvez utiliser VBScript pour lancer IE et de charger un fichier HTML local, et de joindre un VBScript sous une forme de soumission du bouton (ou tout autres événements JavaScript), qui peut alors fermer la fenêtre de IE dans le cadre de son exécution.

OriginalL'auteur Tmdean
1

Vous pouvez lancer une HTA à partir d'un script VBScript.
```
Set shell = CreateObject("WScript.Shell")
shell.Run "Test.hta"
```
MODIFIER

Puisque vous avez le plein contrôle du VBScript, pourriez-vous faire de la 3e partie VBScript simplement appeler votre HTA? Vous pourriez mettre l'INTERFACE utilisateur et quel que soit le traitement de code à l'intérieur de l'HTA.

Une chose aphoria oublié de mentionner, c'est que vous devez inclure le chemin d'accès complet du fichier hta, et parfois vous avez besoin de nonne "mshta.exe ____" où ____ est le chemin d'accès à l'hta.
Je pense que le problème ce n'est pas de départ le code de la route, mais l'obtention de valeurs de retour de l'hta.
Oui, j'aurais besoin pour être en mesure d'obtenir les valeurs de retour de l'hta.
Downvoted? Soin d'expliquer?
Downvoted parce que la réponse ne permet pas de répondre à la question. Si la question était "comment puis-je commencer une hta à partir de VBScript" j'aurais upvoted.

OriginalL'auteur aphoria

Comme un exemple de @TmDean de la suggestion, il y a cette classe que j'ai parfois l'utilisation des scripts IE (bien, il scénarise IE6, je n'ai pas essayé les plus récentes incarnations.)

class IEDisplay
'~ Based on original work by Tony Hinkle, [email protected]
private TEMPORARY_FOLDER
private objShell
private objIE
private objFSO
private objFolder
private strName
private streamOut
private objDIV
private numHeight
private numWidth
private numTop
private numLeft
private sub Class_Initialize()
Dim strComputer
Dim objWMIService
Dim colItems
Dim objItem
Dim arrMonitors( 10, 1 )
Dim numMonitorCount
Set objShell = WScript.CreateObject("WScript.Shell")
Set objIE = CreateObject("InternetExplorer.Application")
strComputer = "."
Set objWMIService = GetObject( "winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery( "Select  * from Win32_DesktopMonitor")
numMonitorCount = 0 
For Each objItem in colItems
arrMonitors( numMonitorCount, 0 ) = objItem.ScreenHeight
arrMonitors( numMonitorCount, 1 ) = objItem.ScreenWidth
numMonitorCount = numMonitorCount + 1
Next
numHeight = arrMonitors( 0, 0 )
numWidth = arrMonitors( 0, 1 )
Set objFSO = CreateObject("Scripting.FileSystemObject")
TEMPORARY_FOLDER = 2
set objFolder = objFSO.GetSpecialFolder( TEMPORARY_FOLDER )
strName = objFSO.BuildPath( objFolder, objFSO.GetTempName ) & ".html"
WriteFileU strName, Join( Array( "<HTML><HEAD><TITLE>Information</TITLE></HEAD>", _
"<BODY SCROLL='NO'><CENTER><FONT FACE='arial black'> <HR COLOR='BLACK'>", _
"<DIV id='MakeMeAnObject'></DIV>", _
"<HR COLOR='BLACK'></FONT></CENTER></BODY></HTML>" ), vbCRLF ), WF_CREATE        
numTop = 0
numLeft = 0
end sub
Sub Init( strPosition )
'NW, N, NE, W, CENTRE, E, SW, S, SE
Select Case strPosition
Case "NW"
numTop = 0
numLeft = 0
Case "N"
numTop = 0
numLeft = ( numWidth / 2 ) - 250
Case "NE"
numTop = 0
numLeft = numWidth - 500
Case "W"
numTop = ( numHeight / 2 ) - 55
numLeft = 0
Case "CENTRE"
numTop = ( numHeight / 2 ) - 55
numLeft = ( numWidth / 2 ) - 250
Case "E"
numTop = ( numHeight / 2 ) - 55
numLeft = numWidth - 500
Case "SW"
numTop = numHeight - 110
numLeft = 0
Case "S"
numTop = numHeight - 110
numLeft = ( numWidth / 2 ) - 250
Case "SE"
numTop = numHeight - 110
numLeft = numWidth - 500
Case Else
numTop = 0
numLeft = 0
End Select
SetupIE( strName )
Set objDIV = objIE.Document.All("MakeMeAnObject")
end sub
private sub Class_Terminate()
'Close IE and delete the file
objIE.Quit
'~ optionally you may want to get rid of the temp file
end sub
public sub Display( strMsg, numMillisec )
objDIV.InnerHTML = strMsg
WScript.Sleep numMillisec
end sub
Private Sub SetupIE(File2Load)
objIE.Navigate File2Load
objIE.ToolBar = False
objIE.StatusBar = False
objIE.Resizable = False
Do
Loop While objIE.Busy
objIE.Width = 500
objIE.Height = 110
objIE.Left = numLeft
objIE.Top = numTop
objIE.Visible = True
objShell.AppActivate("Microsoft Internet Explorer")
End Sub
end class

ici est l'absence (à partir du post d'origine) WriteFileU fonction

Const WF_APPEND = 1
Const WF_CREATE = 2
Const WF_FOR_APPENDING = 8
Const WF_FOR_WRITING = 2
Const WF_CREATE_NONEXISTING = True
Const CONST_READ = 1, CONST_WRITE = 2, CONST_APPEND = 8
Const AS_SYSTEMDEFAULT = -2, AS_UNICODE = -1, AS_ASCII = 0
Sub WriteFileU( sFilename, sContents, nMode )
Dim oStream
If nMode = WF_APPEND Then
Set oStream = oFSO.OpenTextFile( sFilename, WF_FOR_APPENDING, WF_CREATE_NONEXISTING, AS_UNICODE )
ElseIf nMode = WF_CREATE Then
Set oStream = oFSO.OpenTextFile( sFilename, WF_FOR_WRITING, WF_CREATE_NONEXISTING, AS_UNICODE )
Else
STOP
End If
oStream.Write sContents
oStream.Close
Set oStream = Nothing
End Sub

et puis, comme un exemple de son utilisation

set i = new IEDisplay 
a = array("NW", "N", "NE", "W", "CENTRE", "E", "SW","S","SE")
for each aa in a
i.init aa
i.display "Here in " & aa & " of screen", 1000
next

Maintenant, ce n'est pas immédiatement utile (surtout, il y a un tas d'appels à mes propres routines utilitaires), mais il donne un cadre. En modifiant ce que le HTML est stocké, vous pouvez ajouter le support pour les listes déroulantes, etc.

OriginalL'auteur bugmagnet

Vous devez vous connecter pour publier un commentaire.