Comment créer %tab% dans CMD

J'ai besoin de moyen fiable de créer %tab% (contenant un caractère de tabulation (tab) pour les deux, Windows et XP.

SET TAB=" "

Devrait fonctionner pour Windows 7 (pas testé) mais pas pour Win XP (testé).

Ce

for /F "skip=4 delims=pR tokens=1,2" %%a in ( 'reg query hkcu\environment /v temp' ) do set TAB=%%b

œuvres pour Win XP.

reg query hkcu\environnement /v temp vous donne l'emplacement du répertoire temporaire. Comment est-ce lié à ce que vous devez faire? Quelle devrait être la tab variable contient-il?
J'ai besoin de générer caractère de tabulation pour être utilisé pour la boucle. La commande a créé un caractère de tabulation sur Win XP.

OriginalL'auteur user1141649 | 2012-06-04

  1. 9

    Vous devez utiliser un éditeur qui prend en charge les caractères de TABULATION sans changer espaces.

    Et vous devez réorganiser les guillemets, comme avec set TAB=" " vous avez obtenu une variable à trois personnages.

    ONGLET contient également les guillemets. 

    set "TAB=   "

    Actuellement il semble y avoir aucun moyen fiable d'utiliser un programme pour créer un caractère de TABULATION dans toutes les versions de Windows sur toutes les plates-formes de la langue.

    Mais vous pouvez également utiliser un intégré à l'extrait de code Jscript.

    @if (@X)==(@Y) @goto :Dummy @end/* Batch part

@echo off
SETLOCAL ENABLEEXTENSIONS
for /f "delims=" %%x in ('cscript //E:JScript //nologo "%~f0"') do set TAB=%%x
echo Tab character is "%tab%"
goto :EOF

***** Now JScript begins *****/
WScript.Echo(String.fromCharCode(9));

    OriginalL'auteur jeb

  2. 2

    Intégrer le caractère de tabulation dans votre fichier de commandes. En particulier, le placer sur la première ligne, devant @ECHO OFF, puis de lire la première ligne avec la SET /P de commande. Il va lire l'ensemble de la ligne, bien sûr, alors un de plus SET de commande seront nécessaires pour réduire le caractère de tabulation de la ligne. Voici un exemple:

        @ECHO OFF
<%0 SET /p tab=
SET tab=%tab:~0,1%
ECHO Every%tab%word%tab%is%tab%tabulated

    Remarque que les espaces précédant @ECHO OFF ici sont censés être un caractère de tabulation, comme je l'ai dit plus tôt.

    C'est une bonne idée, mais de plus simple devrait être de créer un nouveau fichier avec un onglet à l'intérieur, et de lire ce fichier. Et de grâce.
    J'avais ça en tête, mais vous avez dit que vous vouliez création le caractère de tabulation, donc j'ai pensé en le conservant dans le script batch serait plus proche de ce que tu voulais. Et avec un fichier externe, vous devez n'oubliez pas de le conserver avec le fichier batch (je veux dire, si vous avez besoin de déployer le script quelque part). De toute façon, vous avez raison, ce serait de travailler avec un fichier externe.
    Oups, on remarque, cependant: cela ne fonctionne pas si le fichier contient un caractère de tabulation sur la ligne. Vous auriez encore besoin d'ajouter plus de personnages ou le caractère de tabulation serait tronquée.

    OriginalL'auteur Andriy M

  3. 2

    Cette méthode universellement la même sur Win2k, WinXP, Vista, Win7, Win8, Win10

    Il faut profiter du fait que la MZ en-tête de PE exécutable images qui sont produites par le compilateur de Microsoft outils demeurée la même depuis près de 25 ans dans les jours de NT3.1 jusqu'à aujourd'hui, à l'époque de Windows 10.

    La valeur de l'octet au décalage 0x46 de la MZ-tête est 0x09 qui est le ONGLET caractère
    Donc il suffit de choisir n'importe quel fichier exécutable à partir de windows et de saisir la languette il.

    Et le plus pratique et logique option est d'utiliser l'exécutable de la Commande du Processeur lui-même.

    @echo off
setlocal EnableExtensions

set "TAB="
for /F "delims=" %%Z in (
    '^(type "%COMSPEC%"^|^(^(for /L %%P in ^(1^,1^,70^) do @pause^>nul^)^&set /p "TAB="^&call echo^,%%TAB%%^)^)2^>nul'
) do set "TAB=%%Z"
set "TAB=%TAB:~0,1%"

echo,
echo TAB---^>[%TAB%]^<---TAB  SPACE---^>[ ]^<---SPACE  EMPTY---^>[]^<---EMPTY
echo,
pause

    Mise à JOUR avril,23,2018

    Ceci est une autre et plus compréhensible syntaxe d'éviter l'utilisation de la pipe et est beaucoup plus rapide que le ci-dessus

    ((for /L %%P in (1,1,70) do pause>nul)&set /p "TAB=")<"%COMSPEC%"
set "TAB=%TAB:~0,1%"

    /Mise à JOUR

    faire l'écho de l'ONGLET à utiliser ce formulaire:

    echo,%TAB%

    Pour écrire le caractère de TABULATION dans un fichier:

    :: Creates a new file with TAB character
echo,%TAB%>"NewFile.txt"

:: Appends the TAB character to end of the existing file
echo,%TAB%>>"ExistingFile.txt"

    Noter que echo toujours ajoute une nouvelle ligne (CRLF) à la fin. Si vous voulez juste le caractère de TABULATION sans nouvelle utilisation en ligne de l'invite de technique, mais gardez à l'esprit que cette méthode est extrêmement lent par rapport à l'écho donc ne l'utilisez pas trop 

    setlocal
set "prompt=%TAB%"
"%COMSPEC%" /d /k<nul>"TAB_Without_NewLine.txt"
endlocal

    OriginalL'auteur sst

  4. 1

    La :makeTab sous-routine ci-dessous crée un caractère de tabulation et les stocke dans le nom de la variable passée. Nécessite certutil, ce qui n'est pas installé sur certaines versions de Windows XP.

    @echo off & setLocal enableExtensions disableDelayedExpansion

call :makeTab tab
echo(words%tab%separated%tab%by%tab%tabs

endLocal & goto :EOF

:makeTab result=
:: returns tab char in var name given as param
:: requires certUtil
setLocal
set "tabFile=%tmp%\tab.tmp"

if not exist "%tabFile%" (
    >"%tabFile%" echo(09
    certUtil -decodeHex -f "%tabFile%" "%tabFile%" >nul
) %= if =%

for /f "useBack delims=" %%T in ("%tabFile%") do (
    endLocal & set "%1=%%T"
) %= for /f =%
exit /b 0 %= makeTab =%

    PS: Venez pour penser à elle, au-dessus de la sous-routine pourrait être facilement étendu pour générer n'importe quel personnage que vous voulez (en dehors de NUL). Surveillez la page de code de problèmes avec les caractères ASCII 128 et ASCII 255.

    OriginalL'auteur Sponge Belly

  5. 1

    Avec robocopy ONGLET peuvent également être générés.
    Robocopy est pas disponible dans windows xp par Défaut.

    for /f "delims= " %%T in ('robocopy /L . . /njh /njs') do set "TAB=%%T"

    OriginalL'auteur pieh-ejdsch

  6. 1

    L'obscur forfiles de commande peuvent être utilisés (abusé?) pour créer un caractère de tabulation (ou tout autre caractère que vous préférez, en dehors de NUL), comme indiqué dans le présent DosTips sujet.

    Ici, il est en un mot:

    @echo off & setLocal enableExtensions disableDelayedExpansion

for /f "delims= " %%T in ('
    forFiles /p "." /m "%~nx0" /c "cmd /c echo(0x09"
') do set "tab=%%T"
echo(words%tab%separated%tab%by%tab%tabs

endLocal & goto :EOF

    Cependant, forfiles est disponible seulement sur Windows Vista et au-dessus. Mais rassurez-vous, mon petit XP lapins! Vous pouvez télécharger une fossilisées copie de forfiles.zip (22.1 ko) grâce à la merveilleuse Wayback Machine.

    OriginalL'auteur Sponge Belly

  7. 1

    DosTips utilisateur aGerman première signalé la présence d'un caractère de tabulation dans la sortie de shutdown /? en 2011, et jeb raffiné la technique d'extraction d'elle en Mai dernier comme suit:

    @echo off & setLocal enableExtensions disableDelayedExpansion

for /f "delims=abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789 " %%T in ('
    shutDown /?
') do set "tab=%%T"
set "tab=%tab:~0,1%"
echo(words%tab%separated%tab%by%tab%tabs

endLocal & goto :EOF

    AVERTISSEMENT: Pas garanti pour fonctionner sur toutes les versions de Windows ou tous les paramètres régionaux. J'ai testé avec succès le dessus sur ma version en langue anglaise de HP Windows 7 32 bits, mais ymmv.

    OriginalL'auteur Sponge Belly

  8. 0

    Merci pour les réponses.

    Enfin j'ai utilisé cette méthode simple:

    FOR /f "delims=" %%x IN (delimiter.ini) DO set TAB=%%x

    OriginalL'auteur user1141649

  9. 0

    J'ai gardé le meilleur pour la fin! 😉

    Réticents que je suis contredire une autorité telle que jeb, son réponse est de plus de 5 ans, et une technique a depuis été développé pour créer un caractère de tabulation à l'aide de seulement natif lot les commandes, qui fonctionne sur toutes les versions de Windows de XP partir.

    La :makeTab sous-programme ci-dessous est basée sur le code développé dans le marathon Créer Tous les Caractères ASCII sujet sur DosTips. Il utilise makecab pour créer un caractère de tabulation (ASCII 9) et l'enregistre comme une variable avec le nom passé en paramètre:

    @echo off & setLocal enableExtensions disableDelayedExpansion

call :makeTab tab
echo(words%tab%separated%tab%by%tab%tabs

endLocal & goto :EOF

:makeTab result=
:: returns tab char in var name given as param
:: based on http://consolesoft.com/batch/binary/genchr.cmd
setLocal
set "tabFile=%tmp%\tab.tmp"

if not exist "%tabFile%" (goto makeTabFile) else goto readTabFile

:makeTabFile
type nul >"%tabFile%"
makeCab /d compress=off /d reservePerDataBlockSize=0 ^
/d reservePerFolderSize=9 "%tabFile%" "%tabFile%" >nul
for /f "skip=28 delims=" %%F in ('find /v "" "%tabFile%"') do (
    >"%tabFile%" echo(%%F
    goto readTabFile
) %= for /f =%

:readTabFile
for /f "useBack delims= " %%T in ("%tabFile%") do (
    endLocal & set "%1=%%T"
) %= for /f =%
exit /b 0 %= makeTab =%

    La sous-routine peut être facilement modifié pour créer n'importe quel personnage que vous préférez (en dehors de NUL), tant que vous savez le code ASCII pour le caractère que vous voulez. Méfiez-vous de la page de code questions entre ASCII 128 et 255.

    OriginalL'auteur Sponge Belly