Comment créer une gamme à partir de 2 gammes en VBA

J'ai deux gammes de chacun contenant une seule cellule (par exemple "A1" et "C3")

Quelle est la meilleure façon d'obtenir une nouvelle gamme contenant toutes les cellules entre ces deux ("A1:C3").

Je suis en train d'écrire quelque chose comme cela, mais cela ne fonctionne pas:

 Set NewRange = Range(Range1.Address:Range2.Address)

J'ai une autre question est de savoir comment définir une plage en L1C1 format? Je veux utiliser quelque chose comme Range("R1C2") au lieu de Range("A2").

Merci!

InformationsquelleAutor grozhd | 2012-09-21
  1. 24

    Comme ça?

    Sub Sample()
    Dim rng1 As Range, rng2 As Range
    Dim NewRng As Range

    With ThisWorkbook.Sheets("Sheet1")
        Set rng1 = .Range("A1")
        Set rng2 = .Range("C3")

        Set NewRng = .Range(rng1.Address & ":" & rng2.Address)

        Debug.Print NewRng.Address
    End With
End Sub

    Au lieu de R1C1 format Cells(r,c). Qui vous donnera plus de flexibilité + contrôle

    Donc Range("A2") peut être écrite comme Cells(2,1)

    • Pouah juste écrit exactement ceci, trop lent! +1! 🙂
    • Merci! Juste ce que je cherchais.
    • Comment arrivez-vous à concilier deux gammes? Set fromRng = Union(monthWS.Range("A2:D" & lastRow), monthWS.Range("I2:I" & lastRow)) ne fonctionne pas :/
    • Erreur qui vous geting?
    • pas d'erreur. Vous vous demandez juste. Ne vous inquiétez pas à ce sujet.
    InformationsquelleAutor Siddharth Rout
  2. 13

    Vous pouvez définir une nouvelle gamme de différentes façons. Ci-dessous sont quelques exemples. Pour obtenir R1C1 format - personnellement, je trouve plus facile d'entrer la formule de normale puis à l'aide de VBA pour extraire la R1C1 format requis. Voir le débogage.imprimer les instructions ci-dessous.

    Sub test()
Dim rng1 As Range
Dim rng2 As Range
Dim newRng As Range

    With Sheet1

        Set rng1 = .Range("A1")
        Set rng2 = .Range("C3")

        Debug.Print rng1.FormulaR1C1
        Debug.Print rng1.FormulaR1C1Local

        'Method1
        Set newRng = .Range(rng1, rng2)

        'method2
        Set newRng = .Range(rng1.Address, rng2.Address)

        'method3 (Only works if rng1 & rng2 are single cells
        Set newRng = .Range(rng1.Address & ":" & rng2.Address)

        'method4
        Set newRng = Union(rng1, rng2)


    End With
End Sub
    • L'Union ne sera pas vous donner $A$1:$C$3. Il vous donnera $A$1,$C$3
    • Yep - votre droite. De même que la méthode 1. J'ai été montrant les différentes façons de faire les plages ne seront pas tous en A1:C3. Je répond à la question dans le titre 🙂
    • + 1 Pour montrer les 2 méthodes supplémentaires 🙂
    InformationsquelleAutor user3357963
  3. 10

    4 de la méthode n'est pas la même que la Méthode 1 lorsque les plages ne sont pas adjacentes.

    With Sheet1
Set rng1 = .Range("A1:A3")
Set rng2 = .Range("C1:C3")

'This combines the two separate ranges, so select A1, A2, A3, C1, C2, C3
set newRng = Union(rng1, rng2)

'This combines the two ranges in the same way as when using "A1:C3", 
'so including the cells from column B
set newRng = .Range(rng1, rng2)
    • C'est beaucoup plus utile de répondre - je suis en train de faire le travail pour lequel j'ai besoin de combiner plusieurs plages qui peuvent être n'importe où sur la feuille de calcul (les utilisateurs peuvent effectuer plusieurs sélections et ils doivent être suivis de). Application.De l'Union (et de l'Application.Se croisent!) sera très utile pour certains aspects de ce!
    InformationsquelleAutor user3484615
  4. 2

    Il est aussi possible quelque chose comme:

        Dim newRange as Range
    Set newRange = Range("A1:A4,A7:A9,C1:D9")  'Three different regions grouped
    'or
    Set newRange = Range("A1:A4,A7:A9,C1:D9, D10:D11")  'Four different regions grouped.
    'or
    Set newRange = Range("A1:A4,A7:A9,C1:D9, D10:D11, ...")  'N different regions grouped.
    InformationsquelleAutor Roberto Santos
  5. 2

    Mettre cela dans un module:

    Private Function CombineRanges(rng1 As Range, rng2 As Range) As Range

    Set CombineRanges = ActiveSheet.Range(rng1.Address & ":" & rng2.Address)

End Function

    L'utiliser comme:

    Dim NewRange As Range
Set NewRange  = CombineRanges(Range1, Range2)
    • Cela fonctionne, mais il semble avoir le même but que Union() mais ne fonctionne qu'avec 2 gammes
    InformationsquelleAutor thanos.a