Comment définir “Exécuter en tant qu'administrateur” drapeau sur le raccourci créé par le programme d'installation MSI

Je sais que c'est tout à fait une vieille question, mais j'avais besoin de trouver une réponse et j'ai pensé que je pourrais aider d'autres chercheurs. J'ai écrit une petite fonction pour effectuer cette tâche en VBScript (collé ci-dessous). Il s'adapte facilement à VB.net /VB6.

Codes de retour de la fonction:

0 - le succès, a changé le raccourci.

99 - raccourci drapeau déjà défini pour s'exécuter en tant qu'administrateur.

114017 - fichier non trouvé

114038 - format de fichier de Données non valide (en particulier le fichier est trop petit)

Tous les autres non-zéro = des erreurs inattendues.

Comme mentionné par Chada dans un post plus tard, ce script ne fonctionnera pas sur msi Annoncé raccourcis. Si vous utilisez cette méthode pour manipuler les bits dans le raccourci, il doit y avoir une norme, non annoncé raccourci.

Références:
MS LNK Raccourci format: http://msdn.microsoft.com/en-us/library/dd871305

Un peu d'inspiration: Lire et écrire un fichier binaire en VBscript

Veuillez noter que la fonction ne vérifie pas la validité de l'LNK raccourci. En fait, vous pouvez le nourrir n'IMPORTE quel fichier et il va modifier Hex octet 15h dans le fichier de bit de 32 à.

Si des copies de l'original raccourci de %TEMP% avant de la modifier.

Daz.

'# D.Collins - 12:58 03/09/2012
'# Sets a shortcut to have the RunAs flag set.  Drag an LNK file onto this script to test

Option Explicit

Dim oArgs, ret

Set oArgs = WScript.Arguments

If oArgs.Count > 0 Then
    ret = fSetRunAsOnLNK(oArgs(0))
    MsgBox "Done, return = " & ret
Else
    MsgBox "No Args"
End If

Function fSetRunAsOnLNK(sInputLNK)
    Dim fso, wshShell, oFile, iSize, aInput(), ts, i
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set wshShell = CreateObject("WScript.Shell")
    If Not fso.FileExists(sInputLNK) Then fSetRunAsOnLNK = 114017 : Exit Function
    Set oFile = fso.GetFile(sInputLNK)
    iSize = oFile.Size
    ReDim aInput(iSize)
    Set ts = oFile.OpenAsTextStream()
    i = 0
    Do While Not ts.AtEndOfStream
        aInput(i) = ts.Read(1)
        i = i + 1
    Loop
    ts.Close
    If UBound(aInput) < 50 Then fSetRunAsOnLNK = 114038 : Exit Function
    If (Asc(aInput(21)) And 32) = 0 Then 
        aInput(21) = Chr(Asc(aInput(21)) + 32)
    Else
        fSetRunAsOnLNK = 99 : Exit Function
    End If
    fso.CopyFile sInputLNK, wshShell.ExpandEnvironmentStrings("%temp%\" & oFile.Name & "." & Hour(Now()) & "-" & Minute(Now()) & "-" & Second(Now()))
    On Error Resume Next
    Set ts = fso.CreateTextFile(sInputLNK, True)
    If Err.Number <> 0 Then fSetRunAsOnLNK = Err.number : Exit Function
    ts.Write(Join(aInput, ""))
    If Err.Number <> 0 Then fSetRunAsOnLNK = Err.number : Exit Function
    ts.Close
    fSetRunAsOnLNK = 0
End Function

OriginalL'auteur Daz

Désolé pour la confusion - je comprends maintenant ce que vous êtes après.

Il existe bien des façons de définir le raccourci drapeau, mais aucun de ceux que je connais directement dans Visual Studio. J'ai trouvé un certain nombre de fonctions écrites en C++ que l'ensemble de la SLDF_RUNAS_USER drapeau sur un raccourci.

Quelques liens vers ces fonctions comprennent:

• http://blogs.msdn.com/b/oldnewthing/archive/2007/12/19/6801084.aspx
• http://social.msdn.microsoft.com/Forums/en-US/windowssecurity/thread/a55aa70e-ae4d-4bf6-b179-2e3df3668989/

Un autre débat intéressant sur le même sujet a été réalisée à l'INS forums, le fil peut être de l'aide. Il y a une fonction figurant qui peut être établie comme la mention d'un emplacement de registre qui stocke raccourci paramètres (cela semble être le moyen le plus facile pour y aller, si cela fonctionne) - je ne suis pas en mesure de tester la méthode d'enregistrement pour le moment, mais peut faire un peu plus tard pour voir si elle fonctionne.

Ce fil peut être trouvé ici: http://forums.winamp.com/showthread.php?t=278764

Si vous êtes très désireux de le faire par programmation, alors peut-être que vous pourriez adapter l'une des fonctions ci-dessus pour être exécuté comme un post-installation de la tâche? Ce serait le drapeau du raccourci après votre installation, mais une fois de plus doit être fait sur la Non-Annoncé des raccourcis pour la MSI devrait être fixée comme je l'ai mentionné plus tôt.

Je vais continuer à chercher et tester le paramètre de registre méthode pour voir si elle fonctionne et de faire rapport.

Chada

OriginalL'auteur Chada