Comment demander un accès Administrateur à l'intérieur d'un fichier de commandes

Je suis en train d'écrire un fichier de commandes pour mes utilisateurs à exécuter à partir de leurs machines Vista avec l'UAC. Le fichier est à nouveau de la rédaction de leur fichier hosts, il doit être exécuté avec des autorisations d'Administrateur. J'ai besoin d'être en mesure d'envoyer un e-mail avec un lien à la .le fichier bat. Le comportement souhaité est que quand vous cliquez-droit sur le fichier et Ouvrez, ils vont obtenir une de ces boîtes de dialogue contrôle de compte d'utilisateur qui fait que l'écran s'éteignent et que les forces de leur répondre s'ils veulent donner à la demande de l'autorisation d'exécuter en tant qu'administrateur. Au lieu de cela, ils sont juste de voir "Accès refusé" sur la fenêtre de ligne de commande.

Est-ce possible de faire différemment?

Si vous êtes dans cet et qui, comme moi, sont heureux avec l'aide de PowerShell, ne manquez pas le seul-liner à partir de @toster-cx. Parfait!

InformationsquelleAutor skb | 2009-12-12

318

Ce script est le tour est joué! Il suffit de le coller en haut de votre fichier bat. Si vous voulez revoir la sortie de votre script, ajouter une "pause" de commande au bas de votre fichier de commandes.

Mise à JOUR: Ce script est maintenant légèrement modifié pour soutenir les arguments de ligne de commande et une version 64 bits de l'OS.

Merci Eneerge @ https://sites.google.com/site/eneerge/scripts/batchgotadmin
```
@echo off

:: BatchGotAdmin
:-------------------------------------
REM  --> Check for permissions
    IF "%PROCESSOR_ARCHITECTURE%" EQU "amd64" (
>nul 2>&1 "%SYSTEMROOT%\SysWOW64\cacls.exe" "%SYSTEMROOT%\SysWOW64\config\system"
) ELSE (
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
)

REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
    echo Requesting administrative privileges...
    goto UACPrompt
) else ( goto gotAdmin )

:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    set params= %*
    echo UAC.ShellExecute "cmd.exe", "/c ""%~s0"" %params:"=""%", "", "runas", 1 >> "%temp%\getadmin.vbs"

    "%temp%\getadmin.vbs"
    del "%temp%\getadmin.vbs"
    exit /B

:gotAdmin
    pushd "%CD%"
    CD /D "%~dp0"
:--------------------------------------    
    <YOUR BATCH SCRIPT HERE>
```
- Je déteste avoir à faire cette saleté de dos lot de bêtises, mais parfois, vous êtes obligés de et cela fonctionne très bien. Cheers!
- Cette méthode n'a pas d'avancer des arguments. Savez-vous Comment cela peut être fait? Fondamentalement, ce que j'observe, c'est que sur la première ligne %1 a une certaine valeur et sur la dernière ligne %1 est nulle. J'ai besoin d'avancer les arguments.
- J'ai édité le script d'ajout d'un %* pour le deuxième argument de shellexecute pour passer la ligne de commande arguments pour l'admin du script.
- Que faire si les arguments contiennent de l'espace? ensuite, il y a une erreur dans %temp%\getadmin.vbs. Il est dans la forme de UAC.ShellExecute("filename", ""args"", "", "runas", 1). J'ai donc changé "%*" à %* sans les guillemets. Puis, dans la dernière ligne %1 etc. changement. Que faire alors?
- Je ne suis pas sûr de ce que vous demandez? J'ai testé en passant plusieurs arguments qui inclus les espaces et il a travaillé. Vous pouvez poster les arguments que vous utilisez?
- href="https://gist.github.com/4565567" >gist.github.com/4565567. Le fichier de commandes recevront le nom du répertoire dans cite toujours. Vous voyez dans le fichier vbs, il y a ""C:\bin"" qui est à l'origine d'une erreur.
- J'ai oublié de mentionner, l'erreur est: Expected End of Statement
- J'ai ajouté un peu de code pour échapper à " avec "" qui est la bonne syntaxe pour vbscript. Mon test a travaillé à l'aide de votre "C:\bin" exemple.
- Juste comme pour info ce n'est testé que sous Windows 8 Embedded
- Ce lève ma machine dans une spirale de fenêtres de commande d'ouverture et de fermeture en diagonale à travers l'écran. La seule façon de l'arrêter est de supprimer le fichier de commandes. C'est l'exécution répétée de mon fichier de commandes et l'écriture sur le fichier vbs. La première fois, il a demandé l'autorisation, mais après qu'il vient de boucles.
- Désolé que cela vous cause des problèmes, @TomDestry. Pouvez-vous résoudre le problème? Pouvez-vous dire pourquoi il les boucles? Quel système d'exploitation utilisez-vous? Sur mon installation de windows 7 et de nombreux autres systèmes windows 7, j'ai utilisé cette sur, il a travaillé sans échec. Heureux de vous aider à améliorer le script, si vous pouvez fournir de plus d'informations.
- Grande script! J'ai trouvé 2 améliorations: 1) sous XP, j'ai été faire une erreur lors de l'exécution en tant qu'utilisateur limité. Pour se débarrasser de cette erreur de changer de ligne à: écho de contrôle de compte d'utilisateur.ShellExecute "cmd.exe", "/c %~s0 %params%", "", "runas", 1 >> "%temp%\getadmin.vbs" 2) getadmin.vbs n'était pas supprimé parce admin utilisateur dispose de différents dossier temp, alors ajoutez-del "%temp%\getadmin.vbs" juste avant la sortie /B et de se débarrasser de la ligne actuelle qui supprime
- J'ai testé et publié les modifications que vous avez suggéré. Cela fonctionne pour vous sur XP maintenant?
- Ben, je suis sur Windows 7 aussi, SP1. Il semble que le vbs appel renvoie le code d'erreur 2, ce qui provoque le script de goto UACPrompt encore, et encore, et encore. Je ne sais pas ce code d'erreur 2 moyens, donc je ne peux pas aller beaucoup plus loin.
- Oui, il fonctionne pour moi sur XP maintenant. Merci! Vous pouvez supprimer la ligne après :gotAdmin qui supprime getadmin.vbs puisque vous avez maintenant le supprimer après qu'elle s'exécute. @TomDestry Généralement le code d'erreur 2 signifie ERROR_FILE_NOT_FOUND
- si JHigs est juste sur le code d'erreur 2 sens de fichier n'est pas trouvé, il semble que le compte d'utilisateur ne peut pas droit dans le répertoire temp. Pas sûr qu'il y en est rien, le script peut faire pour résoudre ce problème. Le fichier doit être écrit quelque part d'autre? JHigs, j'ai enlevé le deuxième supprimer. Merci pour l'entrée.
- Après la grande! Je suis curieux de savoir pourquoi vous mettez le stdout/stderr redirige en face de la commande (par exemple, > nul 2>&1 foo.exe au lieu de foo.exe > null 2>&1). Je me sens compétent dans windows batch script, mais je n'ai jamais vu ce style avant; j'ai été surpris, il a même travaillé. Est-il un avantage à cela? Merci!
- runas échouera si vous êtes sous WOW64 (un processus 32 bits sur 64 bits de Windows) par exemple %systemroot%\syswow64\cmd.exe...source: ss64.com/vb/shellexecute.html
- J'ai trouvé ce script sur Eneerge du site web qui a été donné de crédit ci-dessus. Généralement, comme vous, j'ai mis les arguments et les redirections après l'exe. Mais quand quelque chose fonctionne, il semble préférable de le laisser être.
- vous avez un projet de modifier de sorte qu'il fonctionne pour WOW64 et les scénarios typiques?
- Honnêtement, la meilleure solution que j'ai trouvé est de ne pas utiliser un script de commandes, et à la place il suffit d'écrire un fichier exécutable, triste comme elle est, et pas nécessairement la réponse à cette question...quelque chose comme cela peut faire le travail mieux et de manière plus fiable, et moins de chance d'échec si c'est bien fait, et moins à sauter à travers des cerceaux: pastebin.com/kfivGEvt (note: Je suis en supposant que vous souhaitez contrôle de compte d'utilisateur pour quelque chose en particulier, pas juste pour le plaisir de l'obtention de l'UAC, comme pour le lancement de l'outil dism...et...vous pouvez déjà lancer l'application élevée par l'édition du manifeste pour cela)...
- J'ai rencontré exactement le même problème que TomDestry avec la boucle infinie et code de retour 2. C'était sur Windows 8.1. Je sais qu'il a travaillé sur Windows 8.0, et ne peux pas dire pour sûr que c'est la 8.1 mise à jour ou quelque chose d'autre qui a provoqué l'isssue. La solution qui a fonctionné pour moi a été de ne pas utiliser cacls.exe (ou icacls), plutôt: net session >nul 2>,&1 if ERRORLEVEL 1 goto UACPrompt ...
- Je suis désolé, j'ai suivi les conseils ici, mais garder pour la boucle infinie nouvelle invite de commande de lancement avec "demande de privilèges d'administration" lorsque j'exécute ce script. Win 7 Pro SP1.
- Je me demande ce qu'il est censé se produire dans la ligne set params = %*:"="". Quelqu'un pourrait-il m'expliquer ce qu'il se passe ici? Pour commencer, %params% ne pas affectés parce qu'il y a un espace avant le signe égal. Ensuite, il semble qu'il y ait un supplément de devis sur la fin. Est-il une raison à cela?
- Sur Windows 8.1, à l'aide de "/c %~s0 %params%" ne semble pas passer des arguments. Pour résoudre ce problème, les guillemets doubles (échappé de guillemets) sont nécessaires autour de la params, comme "/c %~s0 ""%params%""".
- En fait, attendre... Le ci-dessus ne fonctionne pas comme prévu... Et comme je l'ai dit, il ne passe pas des arguments... je suis toujours à la recherche d'une solution (ne me dérangerait pas d'aide ici, tout de même). La cause en est apparemment que le devis de remplacement conduit à une chaîne vide pour une raison quelconque.
- J'ai eu le même problème que @TomDestry sur windows 8. Pour moi le problème était que "%SYSTEMROOT%\system32\config\system" n'existe pas, donc la cacls échoue toujours causant la boucle infinie. J'ai corrigé simplement en faisant >nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config".
- Cette solution exécute le script dans le répertoire du script vit. J'en avais besoin pour sortir dans le répertoire, j'ai couru à partir (j'ai les chemins d'accès relatifs...). J'ai donc ajouté cd %CD% & dans le "cmd.exe", "/c cd %CD% & %~s0...
- Quand je lance le VBS, accorder l'autorisation, et le fichier de commandes est redémarré, il semble fonctionner comme prévu, mais la nouvelle session CMD commence dans la même fenêtre CMD, et n'a toujours pas de droits d'admin, je ne peux pas écrire à la C;\ répertoire, par exemple. C'est sur un nouveau Win7 installer (dans un VMware VM).
- Remarque cacls est obsolète depuis Windows 7.
- Ne fonctionne pas pour moi, mais stackoverflow.com/a/28467343/586754 travaillé.
- Lors de l'appel à partir d'un fichier batch, il a provoqué une boucle. Résolu en remplaçant le shell, exécutez la commande suivante: echo de contrôle de compte d'utilisateur.ShellExecute "cmd.exe", "/c regsvr32 /s ""%~dp0myfile.ocx""", "", "runas", 1 >> "%temp%\getadmin.vbs"
- Si vous rencontrez des problèmes pour exécuter ce script batch à partir d'un partage réseau, essayez de le copier à un lecteur local d'abord.
- J'ai finalement compris la boucle sans fin et posté un modifier. Une référence à system32\cals.exe lors de l'exécution d'un 64 bits processus. Il peut y avoir d'autres raisons de l'échec, mais au moins maintenant 64 bits processus sont pris en charge.
- Ont suggéré une modification à affecter les paramètres de la variable, puis de remplacer " à ", " en deux lignes distinctes. Cela semble résoudre le passage d'arguments problème pour moi.
- Deux ont suggéré des modifications ont été approuvées en 2016 qui a changé votre réponse. Êtes-vous d'accord avec les changements? Si non, faire reculer.
- Je viens de tester le script change et dans mon environnement, tout fonctionne comme il le faisait avant les modifications. Comme beaucoup l'ont signalé, il y a une boucle infinie problème dans certains environnements. J'ai pensé que je vous ai adressée qu'à un changement, sur Décembre 2015 9 mais aussi, potentiellement, cette modification était nécessaire pour résoudre ce problème dans d'autres environnements. Je peux dire que l'édition n'a pas mal, mais je ne peux pas dire avec certitude qu'il a aidé.
- Bon, j'ai été demander, car votre réponse est venue dans le suggéré des modifications de la file d'attente et je n'étais pas tout à fait sûr de savoir si je doit approuver les modifications ou non. Si la réponse fonctionne toujours, alors peut-être que les modifications ne sont pas trop mauvais.
- Est-il possible de se débarrasser de la quantité de code en le mettant dans un autre fichier batch? Ce que je voudrais voir, c'est une evaluate.bat que je peux mettre dans %windir%\System32 ou le même répertoire et ensuite, je pourrais simplement appeler evaluate.bat %0 ou quelque chose et il va relancer mon script en tant qu'admin si il n'a pas obtenu les droits d'admin à ce jour. Même si cette solution fonctionne, il n'est pas très pratique pour un accès rapide et l'utilisation.
- Donc, il n'y a pas d'autre solution, sans l'aide de VB pièces? Pas de plaine BS alternativity? Stupide Windows.
- Veuillez voir ma réponse (stackoverflow.com/a/41036456/395879) sur les boucles infinies et comment les résoudre. Notez également que "amd64" était "AMD64" dans mon cas (avec les majuscules). Et même si je suis sur x64, seule la case pour cacls dans system32 a fonctionné pour moi. Cependant, je voudrais supprimer ce contrôle à tous - voir ma réponse
- Cela fonctionne pour moi mais je dois remplacer les lignes comme ceci :-------------------------------------- dans ce ::-------------------------------------- Il vient remplacer les deux points, deux points, peut-être remplacer REM à deux points de trop. Je vous remercie.
- les arguments n'ont pas réussi à le code. Ma ligne de commande: mybatchscript 5.6 Mon code: echo "nombre: %1" L'5.6 est de l'argument, mais il n'a pas envoyé le code
- Je fixe les paramètres de la partie à l'aide de cette ligne de set params=%* (sans les espaces), quel est la version originale de faire? ...les espaces autour de = sont évidemment faux...
- Les principaux bugs corrigés concernant la préservation des arguments. Normalement, je ne ferait pas de telles modifications de fond d'un autre utilisateur de réponse. Mais ce acceptée réponse est évidemment important pour beaucoup de gens, et il a été mis sur écoute depuis janvier 2013, alors que l'OP a tenté d'améliorer le code pour préserver arguments. Une explication complète de la bogue et correctif peut être trouvé à l'adresse superuser.com/a/1249855/109090
- Remarque - je n'ai pas enquêter sur la "boucle sans fin" de l'émission. Peut-être certaines techniques à partir de la en arête de poisson réponse besoin d'être plié dans le présent code.
- La Version 11(courante) est rompu pour windows 10 (cliquez sur "édition" pour voir toutes les versions), il faisait écho au "contrôle de compte d'utilisateur.ShellExecute" ligne plutôt que de l'écrire dans le fichier, je ne sais pas comment régler le problème, alors j'ai simplement utilisé la version 10.
- Comme Dan le souligne, cela ne fonctionne pas sur windows10, il y a un problème avec echo-ing à la temp de fichier vbs
- Mon fix pour la préservation des arguments a eu un bug si aucun argument n'a été adopté. Le var params serait pas défini, de sorte que le devis de doubler code résultat déséquilibré parens, qui permettrait d'échapper à la redirection. J'ai corrigé le code à l'aide de set params= %* au lieu de set params=%*, donc params est garanti d'être défini
- Voir mon commentaire ci-dessus pour rahuldottech
- Merci beaucoup! Je veux juste vous faire savoir que vos scripts m'ont aidé beaucoup au cours des deux dernières années. Merci une tonne.
- Je ne sais pas pourquoi vous utilisez "%~s0 " dans le fichier vbs qui me préoccupait beaucoup, quand j'ai essayé d'utiliser le %cd% dans mon script de commandes.Maintenant, j'utilise %~0 au lieu de cela et n'ai pas trouvé quelque chose de mauvais encore.
InformationsquelleAutor Ben Gripka
39

Voici un one-liner j'ai été en utilisant:
```
@echo off
if not "%1"=="am_admin" (powershell start -verb runas '%0' am_admin & exit /b)

echo main code here
pause
```
Notes:
- Uniquement testé sur windows 7 et 10, vous pourriez avoir à déranger le citant
- Ne prend pas en charge le passage des arguments pour l'instant
- Si vous savez comment beaucoup params il pourrait être, vous pouvez passer des paramètres par y compris après am_admin if not "%1"=="am_admin" (powershell start -verb runas '%0' 'am_admin "%~1" "%~2"' & exit) Les params sera l'un au-dessus de là où ils étaient
- Également possible d'utiliser 'am_admin %*' passer tout, n'est pas de bien jouer avec des citations et des espaces tho :/ Vous pouvez utiliser shift dans le lot à la pop la première arg off, ce qui permet de corriger tous les arguments sauf %0.
InformationsquelleAutor toster-cx
18

Voici mon code! Il semble grand, mais c'est surtout des lignes de commentaires (les lignes commençant par ::).

Caractéristiques:
- Plein argument transfert
- Ne pas modifier le dossier de travail
- Erreur de manipulation
- Accepte les chemins avec la parenthèse (sauf pour le dossier %TEMP%)
- Prend en charge les chemins d'accès UNC
- Dossier mappé vérifier (vous Avertit si l'admin ne peut pas accéder lecteur mappé)
- Peut être utilisé comme une bibliothèque externe (vérifier mon post à ce sujet: https://stackoverflow.com/a/30417025/4932683)
- Peut être appelée lorsque/si besoin n'importe où dans votre code
Il suffit de fixer ce jusqu'à la fin de votre fichier de commandes, ou l'enregistrer comme une bibliothèque (case ci-dessus)
```
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:RequestAdminElevation FilePath %* || goto:eof
:: 
:: By:   Cyberponk,     v1.5 - 10/06/2016 - Changed the admin rights test method from cacls to fltmc
::          v1.4 - 17/05/2016 - Added instructions for arguments with ! char
::          v1.3 - 01/08/2015 - Fixed not returning to original folder after elevation successful
::          v1.2 - 30/07/2015 - Added error message when running from mapped drive
::          v1.1 - 01/06/2015
:: 
:: Func: opens an admin elevation prompt. If elevated, runs everything after the function call, with elevated rights.
:: Returns: -1 if elevation was requested
::           0 if elevation was successful
::           1 if an error occured
:: 
:: USAGE:
:: If function is copied to a batch file:
::     call :RequestAdminElevation "%~dpf0" %* || goto:eof
::
:: If called as an external library (from a separate batch file):
::     set "_DeleteOnExit=0" on Options
::     (call :RequestAdminElevation "%~dpf0" %* || goto:eof) && CD /D %CD%
::
:: If called from inside another CALL, you must set "_ThisFile=%~dpf0" at the beginning of the file
::     call :RequestAdminElevation "%_ThisFile%" %* || goto:eof
::
:: If you need to use the ! char in the arguments, the calling must be done like this, and afterwards you must use %args% to get the correct arguments:
::      set "args=%* "
::      call :RequestAdminElevation .....   use one of the above but replace the %* with %args:!={a)%
::      set "args=%args:{a)=!%" 
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
setlocal ENABLEDELAYEDEXPANSION & set "_FilePath=%~1"
  if NOT EXIST "!_FilePath!" (echo/Read RequestAdminElevation usage information)
  :: UAC.ShellExecute only works with 8.3 filename, so use %~s1
  set "_FN=_%~ns1" & echo/%TEMP%| findstr /C:"(" >nul && (echo/ERROR: %%TEMP%% path can not contain parenthesis &pause &endlocal &fc;: 2>nul & goto:eof)
  :: Remove parenthesis from the temp filename
  set _FN=%_FN:(=%
  set _vbspath="%temp:~%\%_FN:)=%.vbs" & set "_batpath=%temp:~%\%_FN:)=%.bat"

  :: Test if we gave admin rights
  fltmc >nul 2>&1 || goto :_getElevation

  :: Elevation successful
  (if exist %_vbspath% ( del %_vbspath% )) & (if exist %_batpath% ( del %_batpath% )) 
  :: Set ERRORLEVEL 0, set original folder and exit
  endlocal & CD /D "%~dp1" & ver >nul & goto:eof

  :_getElevation
  echo/Requesting elevation...
  :: Try to create %_vbspath% file. If failed, exit with ERRORLEVEL 1
  echo/Set UAC = CreateObject^("Shell.Application"^) > %_vbspath% || (echo/&echo/Unable to create %_vbspath% & endlocal &md; 2>nul &goto:eof) 
  echo/UAC.ShellExecute "%_batpath%", "", "", "runas", 1 >> %_vbspath% & echo/wscript.Quit(1)>> %_vbspath%
  :: Try to create %_batpath% file. If failed, exit with ERRORLEVEL 1
  echo/@%* > "%_batpath%" || (echo/&echo/Unable to create %_batpath% & endlocal &md; 2>nul &goto:eof)
  echo/@if %%errorlevel%%==9009 (echo/^&echo/Admin user could not read the batch file. If running from a mapped drive or UNC path, check if Admin user can read it.)^&echo/^& @if %%errorlevel%% NEQ 0 pause >> "%_batpath%"

  :: Run %_vbspath%, that calls %_batpath%, that calls the original file
  %_vbspath% && (echo/&echo/Failed to run VBscript %_vbspath% &endlocal &md; 2>nul & goto:eof)

  :: Vbscript has been run, exit with ERRORLEVEL -1
  echo/&echo/Elevation was requested on a new CMD window &endlocal &fc;: 2>nul & goto:eof
:::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
```
Exemple sur la façon de l'utiliser
```
:EXAMPLE
@echo off

 :: Run this script with elevation
 call :RequestAdminElevation "%~dpfs0" %* || goto:eof

  echo/I now have Admin rights!
  echo/
  echo/Arguments using %%args%%:    %args%
  echo/Arguments using %%*: %*
  echo/%%1= %~1
  echo/%%2= %~2
  echo/%%3= %~3

  echo/
  echo/Current Directory: %CD%
  echo/
  echo/This file: %0
  echo/

pause &goto:eof

[here you paste the RequestAdminElevation function code]
```
- Fonctionne très bien mais j'ai dû changer une ligne à le faire fonctionner. Le &fc;: 2>nul dans set "_FN=_%~ns1" & echo/%TEMP%| findstr /C:"(" >nul && (echo/ERROR: %%TEMP%% path can not contain parenthesis &pause &endlocal &fc;: 2>nul & goto:eof) était paramètre errorlevel 1. J'ai enlevé que peu, et ça a marché parfaitement. Je suis à l'aide de Windows 10 à la Maison.
- Est-ce que votre dossier %temp% ont parenthèse dans son parcours ? Seulement dans ce cas la variable errorlevel 1 est censé être ensemble.
- Nope. Est-il besoin de le fc;: puisqu'il va :eof juste après? Je ne suis pas sûr pourquoi un peu qui a causé le problème, car il doit être exécuté.
- "le fc;: 2>nul" est-il intentionnellement pour définir ERRORLEVEL 1 avant de quitter, pour signaler une erreur. Pourriez vous s'il vous plaît supprimer le @echo off et de faire une course et m'envoyer le résultat dans un message privé? Merci!
- De toute façon, le echo/%TEMP%| findstr /C:"(" >nul tests si il y a un ( char dans yout %temp% variable d'environnement, et doit s'exécuter uniquement la partie après le && si le résultat est positif. Il est étrange que votre ( test revient positif si.
- Ok, il semble que ce problème se produit uniquement si je suis en cours d'exécution à partir d'une console que j'ai commencé avec les droits admin. Voici la sortie; les Nettoyer pour des raisons de concision. appelez le :RequestAdminElevation "...\OXYGÈNE~1.Chauve-souris" || goto:eof setlocal ... ErrorLevel est 0 "_FN=_OXYGEN~1" & echo/C:\Users****\AppData\Local\Temp | findstr /C:"(" 1>nul && (echo/ERREUR: ... goto:eof) ErrorLevel est de 1 ... l'Élévation a été demandé sur une nouvelle fenêtre CMD Nouvelle fenêtre de sortie des miroirs au-dessus de la sortie.
- Une fois élevé, est-il possible de revenir à la non-élevée ? Donc, dans un .fichier bat vous auriez echo/j'ai actuellement non-admin/des droits d'utilisateur standard :: la prochaine Exécution de la partie avec l'élévation appel :RequestAdminElevation "%~dpfs0" %* || goto:eof echo/j'ai maintenant les droits d'Admin! :: La prochaine exécution de la partie non élevée (ie. sans élévation) appel :RequestNonAdminRights "%~dpfs0" %* || goto:eof echo/j'ai maintenant non-admin/des droits d'utilisateur standard à nouveau!
- Cela pourrait être fait, mais pas avec ce script. Im curieux de savoir si, pourquoi voudriez-vous faire cela ?
- J'avais prévu d'avoir un seul script, là où j'ai envie de faire certaines opérations dans un ordre spécifique. Certains de ces exiger d'altitude, tandis que d'autres ne le font pas. Par exemple, la commande pourrait être quelque chose comme NORMAL,NORMAL,ADMIN,ADMIN,NORMAL,ADMIN,ADMIN,NORMAL
- Quels sont les avantages de votre script, par opposition à la accepté de répondre ? Aussi, quel est le motif pour passer fltmc pour l'administration de vérifier, au lieu de cacls ?
- Vous pouvez faire des activités normales après l'élévation est demandé, je ne pense pas que ce serait un problème. Seul problème serait le cas si vous utilisez des dossiers partagés sur le réseau, en raison des autorisations. Mais vous pouvez faire toutes les opérations normales d'abord, et ensuite, demande de elevarion et faire toutes les opérations d'administration, si l'ordre n'est pas important.
- Les avantages de ce script est tout ce qui est inscrit dans les "Caractéristiques" une partie de la réponse. En gros, je travail en tant que gestionnaire de réseau et j'ai été en utilisant la accepté de répondre mais trouvé beaucoup de problèmes avec elle, j'ai donc créé une solution alternative et se débarrasser de tous ses bugs. J'ai changé de cacls à fltmc pour une meilleure compatibilité. Cacls ne fonctionne pas sur certaines versions de windows, et a été à l'origine erreur dans certaines situations. Merci!
- Est-il possible d'écrire la sortie de l'élévation de script à la main-cmd? Je vais appeler mon cmd-fichier de java application et je veux extraire la sortie, mais je ne reçois "Demande d'élévation..." et "Élévation a été demandé sur une nouvelle fenêtre CMD", mais pas l'écho de mon cmd-Fichier
- Im peur qui n'est pas possible avec le code tel quel, parce que pour la demande d'élévation le script doit ouvrir une nouvelle fenêtre CMD. Vous pourriez être en mesure d'écrire la sortie de votre script dans un fichier, puis ouvrez le fichier dans votre application java.
InformationsquelleAutor cyberponk
7

Une autre approche consiste à
- créer un raccourci localement et mis à demander la permission d'un Administrateur [Propriétés, Avancé, Exécuter en tant qu'Admin]
et puis
- envoyer à vos utilisateurs le raccourci [ou un lien vers le raccourci plutôt que pour le fichier de commandes lui-même].
Denis

[Ajouté par la suite - Oui, je n'ai pas manquer de remarquer la date de ce fil.]

InformationsquelleAutor Tryx3
5

Ben Gripka la solution provoque une boucle infinie. Son lot d'œuvres de ce genre (pseudo-code):
```
IF "no admin privileges?"
    "write a VBS that calls this batch with admin privileges"
ELSE
    "execute actual commands that require admin privileges"
```
Comme vous pouvez le voir, ce qui provoque une boucle infinie, si le VBS échoue demander des privilèges d'administrateur.

Cependant, la boucle infinie peut se produire, bien qu'admin privilèges ont été demandé.

De l'enregistrement Ben Gripka du fichier de commandes est juste de faire des erreurs. J'ai joué un peu avec le lot et a observé que des privilèges d'administrateur sont disponibles bien que l'échec de la vérification. Fait intéressant, la vérification a fonctionné comme prévu, si j'ai commencé le fichier de commandes à partir de l'explorateur windows, mais il n'avait pas quand je l'ai commencé de mon IDE.

Alors je vous suggérons d'utiliser deux fichiers batch. La première génère le SCRIPT qui appelle la deuxième fichier de commandes:
```
@echo off

echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
set params = %*:"=""
echo UAC.ShellExecute "cmd.exe", "/c ""%~dp0\my_commands.bat"" %params%", "", "runas", 1 >> "%temp%\getadmin.vbs"

"%temp%\getadmin.vbs"
del "%temp%\getadmin.vbs"
```
Le second, nommé "my_commands.chauve-souris" et situé dans le même répertoire que le premier contient vos commandes à exécuter:
```
pushd "%CD%"
CD /D "%~dp0"
REM Your commands which require admin privileges here
```
Cela ne cause pas de boucle infinie et supprime également le risque d'erreur de privilège admin vérifier.
- A fonctionné pour vous? Malheureusement pour moi, ce et tous les autres ici et à partir de la autre thread fail à cause de ce même problème sous-jacent. Le "runas" parm (ou de commande) échoue à chaque fois que l'Objet Shell est créé le indirectement à partir de l'intérieur d'un autre programme. Fil d'intérêts ici.
InformationsquelleAutor fishbone
4

Je sais que ce n'est pas une solution pour l'OP, mais depuis que je suis sûr qu'il y a de nombreux autres cas d'utilisation ici, je pensais que je voudrais partager.

J'ai eu des problèmes avec tous les exemples de code dans ces réponses, mais ensuite, j'ai trouvé :
http://www.robotronic.de/runasspcEn.html

Il vous permet non seulement d'exécuter en tant qu'administrateur, il vérifie le fichier pour vérifier qu'il n'a pas été altéré et stocke les informations nécessaires en toute sécurité. Je vais vous avouer que c'est pas le plus évident outil pour comprendre comment l'utiliser, mais pour ceux d'entre nous de l'écriture de code, il devrait être assez simple.

InformationsquelleAutor trex005
3

@echo off et title peut être saisie de ce code:
```
net session>nul 2>&1
if %errorlevel%==0 goto main
echo CreateObject("Shell.Application").ShellExecute "%~f0", "", "", "runas">"%temp%/elevate.vbs"
"%temp%/elevate.vbs"
del "%temp%/elevate.vbs"
exit

:main
    <code goes here>
exit
```
Beaucoup d'autres réponses sont trop si vous n'avez pas besoin de s'inquiéter au sujet de ce qui suit:
- Paramètres
- Répertoire de travail (cd %~dp0 va changer le répertoire contenant le fichier de commandes)
InformationsquelleAutor FluorescentGreen5
1

Depuis j'ai des problèmes avec ce script éclater une nouvelle invite de commande avec lui-même exécuter de nouveau dans une boucle infinie (à l'aide de Win 7 Pro), je vous suggère d'essayer une autre approche :Comment puis-je auto-élever mon fichier batch, de sorte qu'il demande de l'UAC des droits d'administrateur, si nécessaire?

Attention, vous devez ajouter cette ligne à la fin du script, comme indiqué dans un edit, de sorte que vous êtes de retour au répertoire du script, une fois les privilèges ont été élevés :
cd /d %~dp0
- De vérifier ma réponse à cette question. Il gère l'ensemble de ces problèmes.
InformationsquelleAutor barbara.post

Basé sur le poteau par toster-cx et autres messages intéressants sur cette page, je me suis aperçu sur la façon de configurer et résoudre mon problème. J'ai eu le même problème lorsque j'ai voulu que l'utilitaire de Nettoyage de Disque s'exécute chaque semaine deux fois le lundi et le jeudi pendant les heures de déjeuner (disons 2 pm). Cependant, cette élévation des droits.

De partage de fichier de lot qui pourrait aider d'autres débutants comme moi -

@echo off
echo  Welcome to scheduling 'PC Maintenance Activity'
ping localhost -n 3 >nul
echo -- Step - 1 of 3 : Please give 'Admin' rights on next screen
ping localhost -n 5 >nul
if not "%1"=="am_admin" (powershell start -verb runas '%0' am_admin & exit)
cls
echo -- Step - 2 of 3 : In next screen, select temp areas for cleaning 
during routine scheduled activity
ping localhost -n 3 >nul
C:\Windows\System32\cleanmgr.exe /sageset:112
cls
echo    Now scheduling maintenance activity...
SchTasks /Create /SC WEEKLY /D MON,THU /TN PC_Cleanup /TR 
"C:\Windows\System32\cleanmgr.exe "/sagerun:112 /ST 14:00

cls

echo                         -- Thanks for your co-operation --
echo                    -- Maintenance activity is scheduled for --
echo                       -- Every Monday and Thursday at 2 pm --

ping localhost -n 10 >nul

Merci beaucoup pour ce forum et Rems POST ici [https://www.petri.com/forums/forum/windows-scripting/general-scripting/32313-schtasks-exe-need-to-pass-parameters-to-script%5D%5B1%5D

Son poste aidé pour la configuration de l'argument optionnel lors de la planification de la tâche.

InformationsquelleAutor Anand

0

Vous ne pouvez pas demander de droits d'administrateur à partir d'un fichier de commandes, mais vous pourriez écrire un windows scripting host script dans %temp% et le lancer (et qui à son tour s'exécute votre lot en tant qu'admin) que Vous souhaitez appeler le ShellExecute méthode dans le Shell.Objet de l'Application avec "runas" comme le verbe

InformationsquelleAutor Anders
-3

utiliser la commande runas. Mais, je ne pense pas que vous pouvez envoyer un email à un .fichier bat facilement.
- Cette réponse est incorrecte. Le runas commande ne peut pas être utilisé pour provoquer l'élévation.
InformationsquelleAutor Josh

Vous devez vous connecter pour publier un commentaire.