Comment dois-je faire référence à des tables dans Excel vba?

Peut-être cela peut vous aider à

La création d'une table

La conversion d'une gamme à une table commence avec le même code que dans Excel 2003 (comme décrit dans cette réponse):

Sub CreateTable()
    ActiveSheet.ListObjects.Add(xlSrcRange, Range("$B$1:$D$16"), , xlYes).Name = _
        "Table1"
        'No go in 2003
    ActiveSheet.ListObjects("Table1").TableStyle = "TableStyleLight2"
End Sub

Un "tableau" dans Excel est en effet connu comme un ListObject.

La "bonne" façon de faire référence à une table est en obtenant sa ListObject à partir de sa Feuille de calcul c'est à dire SheetObject.ListObjects(ListObjectName).

Si vous voulez faire référence à un tableau sans l'aide de la feuille, vous pouvez utiliser un hack Application.Range(ListObjectName).ListObject.

REMARQUE: Ce hack repose sur le fait que Excel crée toujours une plage nommée pour la table DataBodyRange avec le même nom que la table. Cependant, ce nom de la gamme de peut être changé...si ce n'est pas quelque chose que vous aimeriez faire depuis le nom sera remise à zéro si vous modifiez le nom de la table! Vous pouvez également obtenir une plage nommée sans associé ListObject.

Donné Excel n'est pas-très-utile 1004 message d'erreur lorsque vous obtenez le nom de mal, vous pouvez créer un wrapper...

Public Function GetListObject(ByVal ListObjectName As String, Optional ParentWorksheet As Worksheet = Nothing) As Excel.ListObject
On Error Resume Next

    If (Not ParentWorksheet Is Nothing) Then
        Set GetListObject = ParentWorksheet.ListObjects(ListObjectName)
    Else
        Set GetListObject = Application.Range(ListObjectName).ListObject
    End If

On Error GoTo 0 'Or your error handler

    If (Not GetListObject Is Nothing) Then
        'Success
    ElseIf (Not ParentWorksheet Is Nothing) Then
        Call Err.Raise(1004, ThisWorkBook.Name, "ListObject '" & ListObjectName & "' not found on sheet '" & ParentWorksheet.Name & "'!")
    Else
        Call Err.Raise(1004, ThisWorkBook.Name, "ListObject '" & ListObjectName & "' not found!")
    End If

End Function

Aussi quelques bonnes ListObject info ici.

En plus de ce qui précède, vous pouvez le faire (où "YourListObjectName" est le nom de votre table):

Dim LO As ListObject
Set LO = ActiveSheet.ListObjects("YourListObjectName")

Mais je pense que cela ne fonctionne que si vous voulez faire référence à un objet de la liste qui est sur la feuille active.

J'ai trouvé votre question parce que je voulais pour faire référence à un objet de la liste (un tableau) sur une feuille de calcul d'un tableau croisé dynamique sur une autre feuille de calcul se réfère. Depuis la liste des objets font partie de la collection de Feuilles de calcul, vous devez connaître le nom de la feuille de calcul que l'objet de la liste est dans l'ordre de la consulter. Donc, pour obtenir le nom de la feuille de calcul que l'objet de la liste est sur, j'ai obtenu le nom de la table pivot de la source objet de la liste (encore une fois, d'une table) et boucle à travers les feuilles de travail et de leurs objets de la liste jusqu'à ce que j'ai trouvé la feuille de calcul qui contenait la liste d'objet que je cherchais.

Public Sub GetListObjectWorksheet()
' Get the name of the worksheet that contains the data
' that is the pivot table's source data.

    Dim WB As Workbook
    Set WB = ActiveWorkbook

    ' Create a PivotTable object and set it to be
    ' the pivot table in the active cell:
    Dim PT As PivotTable
    Set PT = ActiveCell.PivotTable

    Dim LO As ListObject
    Dim LOWS As Worksheet

    ' Loop through the worksheets and each worksheet's list objects
    ' to find the name of the worksheet that contains the list object
    ' that the pivot table uses as its source data:
    Dim WS As Worksheet
    For Each WS In WB.Worksheets
        ' Loop through the ListObjects in each workshet:
        For Each LO In WS.ListObjects
            ' If the ListObject's name is the name of the pivot table's soure data,
            ' set the LOWS to be the worksheet that contains the list object:
            If LO.Name = PT.SourceData Then
                Set LOWS = WB.Worksheets(LO.Parent.Name)
            End If
        Next LO
    Next WS

    Debug.Print LOWS.Name

End Sub

Peut-être quelqu'un sait d'une manière plus directe.