Comment dois-je re-raise un Delphi exception après l'enregistrement?

Connaissez-vous un moyen de piéger, de journal, et re-raise exception dans le code Delphi?
Un exemple simple:

procedure TForm3.Button1Click(Sender: TObject);
begin
  try
    raise Exception.Create('Bum');
  except
    on E: Exception do
    begin
      MyHandleException(E);
    end;
  end;
end;

procedure TForm3.MyHandleException(AException: Exception);
begin
  ShowMessage(AException.Message);
  LogThis(AException.Message);  
  // raise AException; - this will access violate
end;

J'ai donc besoin de la relancer dans le bloc except mais je me demandais si il ya une meilleure façon d'écrire ma propre méthode pour gérer et (dans certaines conditions) à re-lever des exceptions.

  • Viens de re-lever de la manière habituelle. Il maintient votre code d'auto-documentation et de ne pas gâcher la trace de la pile.
  • yep j'ai vraiment envie de préserver la pile!
  • Si c'est la journalisation des exceptions que vous êtes après, vous devriez jeter un oeil à madExcept, EurekaLog et/ou Jedi. Ont chacun une meilleure gestion de l'enregistrement d'exception que vous pourriez jamais rêver de faire vous-même.
  • Oui je sais les outils, je préfère EurekaLog, mais il n'est pas à moi de les utiliser et comment les utiliser ceux de l'outil avec les clients .. donc je fais ce que je peux 🙂
  • Les Exceptions sont un décompte de références. Le déclenchement de l'exception est décrémenté lorsque l'EXCEPTION de bloquer les sorties. ÉLEVER par lui-même w/o une instance exception incrémente le compteur de référence. SOULEVER suivie par une instance exception (par exemple, pour relever E; ) ne sera pas, d'où l'AV noté. Exception à la règle.Créer (), une exception avec les ref compter du 1er et, si cela est fait dans un bloc d'exception, n'est pas soumis à l'arbitre de compter décrémenter lorsque l'EXCEPTION de bloquer les sorties. Écrire du code où élever seul peut être appelé, de créer une nouvelle exception, ou utiliser le AcquireExceptionObject() pour incrémenter la ref nombre, comme par le ci-dessous des solutions.
InformationsquelleAutor Nik Todorov | 2010-05-27
  1. 32

    Si vous voulez relancer l'exception seulement sous certaines conditions, écrire

    procedure TForm3.Button1Click(Sender: TObject);
begin
  try
    raise Exception.Create('Bum');
  except
    on E: Exception do
    begin
      if MyHandleException(E) then
        raise;
    end;
  end;
end;

function TForm3.MyHandleException(AException: Exception): boolean;
begin
  ShowMessage(AException.Message);
  result := true/false;
end;
    • c'est une bonne idée et je l'ai eu dans l'esprit, mais encore j'ai décliné, à savoir est-il un autre code-moins de chemin à faire dans une fonction distincte. Merci.
    • alors que c'est la plus bonne façon de résoudre ce problème, il existe des situations où vous ne pouvez pas modifier la méthode d'appel (c'est peut-être quelqu'un d'autre code, par exemple, un gestionnaire d'événements d'un composant, j'ai exactement ce scénario) donc, pour moi, Craig et surtout de Wes solutions sont la vraie réponse à cette question.
    InformationsquelleAutor Andreas Rejbrand
  2. 10

    La suite de Craig Young post, j'ai utilisé quelque chose le long des lignes de code suivant avec succès. Vous pouvez conserver l'original de l'exception de l'emplacement à l'aide de la "au" identifiant à l'ExceptAddr fonction. L'exception d'origine type de classe et de l'information est également préservé. 

    procedure MyHandleException(AMethod: string);
var
  e: Exception;
begin
  e := Exception(AcquireExceptionObject);
  e.Message := e.Message + ' raised in ' + AMethod; 
  raise e at ExceptAddr;
end;

try
  ...
except
  MyHandleException('MyMethod');
end;
    InformationsquelleAutor Wes
  3. 6

    Ce qui suit fonctionnera, mais n'est évidemment pas idéal pour 2 raisons:

    • L'exception est générée à partir d'un endroit différent dans la pile d'appel.
    • Vous n'obtenez pas une copie exacte de l'exception - en particulier ceux des classes qui ajouter des attributs. I. e. vous devrez explicitement copier les attributs dont vous avez besoin.
    • Copie des attributs personnalisés peuvent être source de confusion due à la nécessaire vérification de type.

    .

    procedure TForm3.MyHandleException(AException: Exception);
begin
  ShowMessage(AException.Message);
  LogThis(AException.Message);  
  raise ExceptClass(AException.ClassType).Create(AException.Message);
end;

    Les avantages sont que vous conservez l'original de la classe d'exception, et un message (et tous les autres attributs que vous souhaitez copier).

    Idéalement, vous voulez les appeler System._RaiseAgain, mais, hélas, ce qu'est un "compilateur-magie' de routine et ne peut être appelée que par raise;.

    • +1 : j'ai été à la recherche d'un moyen de relancer une exception à l'extérieur de l'essayer...sauf bloc pour un certain temps maintenant. Je me rends compte que vous perdez la pile d'appel, mais pour reraising une exception dans les principaux VCL thread qui s'est produite dans un autre thread -- cela fonctionne très bien. Merci!
    InformationsquelleAutor Disillusioned
  4. 4

    Vous pouvez essayer d'utiliser (système d'.pas):

    function AcquireExceptionObject: Pointer;

    AcquireExceptionObject retourne un pointeur vers l'actuel objet d'exception et empêche l'objet de l'exception d'être libéré lorsque l'actuel gestionnaire d'exception issues de secours.

    Remarque: AcquireExceptionObject incréments l'objet de l'exception du compte de référence. Assurez-vous que le compteur de référence est décrémenté lorsque l'objet de l'exception n'est plus nécessaire. Cela se fait automatiquement si vous utilisez l'objet de l'exception à re-lever l'exception. Dans tous les autres cas, chaque appel AcquireExceptionObject doit correspondre une appel à ReleaseExceptionObject. AcquireExceptionObject/ReleaseExceptionObject séquences peuvent être imbriquées.

    • Intéressant, je vais essayer cela. Merci pour les détails.
    • Méfiez-vous--En Delphi 2007 au moins, ReleaseExceptionObject est une méthode vide. De l'utiliser conjointement avec AcquireExceptionObject entraîne une fuite de mémoire. J'ai trouvé FreeAndNil de travailler comme une alternative.
    • Dans D2009 ReleaseExceptionObject est également vide. Je me demande si la documentation est correcte à propos de ce comptage de référence. Exception est dérivé de TObject pas de TInterfacedObject.
    InformationsquelleAutor André
  5. 2

    Vous devriez être en mesure d'utiliser seulement la Raise commande par lui-même à re-lever l'exception:

    begin
  MyHandleException(E);
  Raise;
end;
    • Je pense que c'est exactement ce qu'il essaie de ne pas faire: mettre une augmenter après MyHandleException chaque fois qu'il appelle, en mettant le augmenter à l'intérieur de MyHandleException lui-même.
    • Vous avez peut-être raison. J'étais probablement en train de lire de façon incorrecte. Je vais supprimer ma réponse ... après un peu de sorte que vous avez une chance de voir ce commentaire 🙂
    • Je pense que c'est juste. Il a mis le raise dans une procédure appelée dans la except bloc, qui ne fonctionne pas. Le raise doit être exactement dans le except bloc. Si vous écrivez raise AException dans la procédure externe, vous obtenez une violation d'accès.
    • Ne supprimez pas votre réponse. Votre extrait de code pourrait être utile à d'autres me demandais comment faire pour re-raise une exception au sein de la except bloc. Et apprendre qu'il n'est pas possible de le faire n'importe où ailleurs.
    • Que sens - je vais le laisser en place car je ne pense pas que l'information est intrinsèquement mauvais.
    • Yep je vais essayer d'éviter de soulever sur tous essayer à l'exception des blocs. Mais il semble inévitable à ce stade 🙂 Merci les gars!

    InformationsquelleAutor Mark Wilkins
  6. 1

    Vieux sujet, mais, qu'en est cette solution?

    procedure MyHandleException(AException: Exception);
begin
  ShowMessage(AException.Message);
  AcquireExceptionObject;
  raise AException;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  try
    raise Exception.Create('Bum');
  except
    on E: Exception do
      MyHandleException(E);
  end;
end;

    Il est basé sur le premier code posté par Eduardo.

    InformationsquelleAutor Roberto Schuster
  7. 1

    Cette façon de travailler pour moi!

    procedure RaiseExceptionFmt(const AFormat: string;
  const AArgs: array of const);
begin
  raise Exception.CreateFmt(AFormat, AArgs) at ExceptAddr;
end;

    J'ai réécrit ma méthode, et maintenant, la relance sera de même avant de.

    procedure RaiseInternalExceptionFmt(const AFormat: string;
  const AArgs: array of const);
var
  LExceptionPtr: Pointer;
begin
  LExceptionPtr := AcquireExceptionObject();
  try
    Exception(LExceptionPtr).Message := Format(AFormat, AArgs);
    raise Exception(LExceptionPtr) at ExceptAddr;
  finally
    ReleaseExceptionObject();
  end;
end;
    • Cela fonctionne, mais il soulève toujours une exception de type Exception, même si l'original est de type différent, l'e.g EFileNotFound.
    InformationsquelleAutor Jerônimo Zanella
  8. 0

    Vous pourriez acquérir l'objet de l'exception avant d'appeler votre gestionnaire et de garder le gestionnaire lui-même un liner. Cependant, vous avez encore beaucoup de "Try/except/Faire/à la Fin de la charge.

    Procedure MyExceptionHandler(AException: Exception);
Begin
  Log(AException); // assuming it accepts an exception
  ShowMessage(AException.Message);
  raise AException; // the ref count will be leveled if you always raise it
End;

Procedure TForm3.Button1Click(Sender: TObject);
Begin
  Try
    Foo;
  Except On E:Exception Do
    MyExceptionHandler(Exception(AcquireExceptionObject));
  End;
End;

    Cependant, si vous ne voulez faire est de se débarrasser d'une répétition de code de gestion d'erreur dans les gestionnaires d'événements, vous pouvez essayer ceci:

    Procedure TForm3.ShowException(AProc : TProc);
Begin
  Try
    AProc;
  Except On E:Exception Do Begin
    Log(E);
    ShowMessage(E.Message);
  End; End;
End;

    Réduire votre code de gestionnaire d'événements à ceci:

    Procedure TForm3.Button1Click(Sender: TObject);
Begin
  ShowException(Procedure Begin // anon method
    Foo; // if this call raises an exception, it will be handled by ShowException's handler
  End);
End;

    Vous pouvez également faire travailler les fonctions à l'aide de fonctions paramétrées:

    Function TForm3.ShowException<T>(AFunc : TFunc<T>) : T;
Begin
  Try
    Result := AFunc;
  Except On E:Exception Do Begin
    Log(E);
    ShowMessage(E.Message);
  End; End;
End;

    Et de faire ShowException retourner une valeur (agissant comme un passthru):

    Procedure TForm3.Button1Click(Sender: TObject);
Var
  V : Integer;
Begin
  V := ShowException<Integer>(Function : Integer Begin // anon method
    Result := Foo; // if this call raises an exception, it will be handled by ShowException's handler
  End);
End;

    Ou même faire le anon procédure de toucher directement à l'extérieur de la portée de la variable(s):

    Procedure TForm3.Button1Click(Sender: TObject);
Var
  V : Integer;
Begin
  ShowException(Procedure Begin // anon method
    V := Foo; // if this call raises an exception, it will be handled by ShowException's handler
  End);
End;

    Il y a quelques limitations sur l'interaction des variables à partir de l'intérieur du corps de la fonction anonyme et celles définies à l'extérieur de la portée, mais pour les cas simples comme celles-ci, vous serez plus que bien.

    InformationsquelleAutor Eduardo