Comment envoyer et gérer Http Post asp?

httpRequest.Open "POST", "www.example.com/handle.asp", False
httpRequest.setRequestHeader "Content-Type", "application/x-www-form-urlencoded"
httpRequest.send data
postResponse = httpRequest.response

Comment gérer le poste le code ci-dessus. dans la poignée.asp. Dans la poignée, je veux prendre les données envoyées et les ajouter à, puis l'envoyer quelque chose en retour à l'appel de la page?

OriginalL'auteur Beginner | 2011-03-14

  1. 21

    @Uzi: Voici un exemple -

    somefile.asp appel handle.asp qui est le script de traitement:

    Option Explicit

Dim data, httpRequest, postResponse

data = "var1=somevalue"
data = data & "&var2=someothervalue"
data = data & "&var3=someothervalue"

Set httpRequest = Server.CreateObject("MSXML2.ServerXMLHTTP")
httpRequest.Open "POST", "http://www.example.com/handle.asp", False
httpRequest.SetRequestHeader "Content-Type", "application/x-www-form-urlencoded"
httpRequest.Send data

postResponse = httpRequest.ResponseText

Response.Write postResponse ' or do something else with it

    Exemple de handle.asp:

    Option Explicit

Dim var1, var2, var3

var1 = Request.Form("var1")
var2 = Request.Form("var2")
var3 = Request.Form("var3")

' Silly example of a condition /test '
If var1 = "somecondition" Then
    var1 = var1 & " - extra text"
End If

' .. More processing of the other variables .. '

' Processing /validation done... '
Response.Write var1 & vbCrLf
Response.Write var2 & vbCrLf
Response.Write var3 & vbCrLf

    OriginalL'auteur stealthyninja

  2. 0

    Exactement comme vous le feriez pour gérer les données publiées, généralement en ASP en utilisant Request.Form("parameter") lire Posté valeurs et faire ce que vous voulez avec eux.

    Vous avez juste besoin de s'assurer de renvoyer les données à partir de la manipulation de script dans un format facilement décodable/utilisable par le script qui fait la requête POST.

    OriginalL'auteur RobV