Comment faire défiler un TScrollbar à l'aide de la molette de la souris?

J'ai un TScrollBar avoir un code dans l'événement OnScroll.

Je veux la faire défiler à l'aide de la molette de la souris, mais en tournant la molette de la souris ne permet pas de faire défiler la barre de défilement et ne déclenche pas l'événement OnScroll.

Une idée?

Ce qui ne fonctionne pas?
Compte tenu de vos rep, vous devriez le savoir maintenant que la plupart d'entre nous ne peuvent pas faire beaucoup sans vous nous montrer votre code et de nous dire ce que vous avez essayé et comment il n'a pas de travail (qu'avez-vous attendre et ce qu'il s'est réellement passé).
Une question plus générale qui se passe pour moi la lecture de ce. J'ai fait un mod qui intercepte la molette de la souris message à faire TListBox etc travail correctement". Je suis encore en train de faire cela dans le XE. Est-ce exact? Pourquoi n'est-il pas encore "corriger" le comportement de la boîte de XE? Est-ce pour des raisons d'héritage?
-1 pour "ça ne fonctionne pas."
Triste. Donc, beaucoup de gens se sont précipités pour critiquer la question; aucun de ceux qui se précipita pour répondre. Conclusion: DONC, est tellement facile de critiquer, surtout quand vous n'avez pas de réponse.

OriginalL'auteur XBasic3000 | 2011-08-15

  1. 21
    procedure TForm1.FormMouseWheel(Sender: TObject; Shift: TShiftState;
  WheelDelta: Integer; MousePos: TPoint; var Handled: Boolean);
var
  I: Integer;
begin
  Handled := PtInRect(ScrollBox1.ClientRect, ScrollBox1.ScreenToClient(MousePos));
  if Handled then
    for I := 1 to Mouse.WheelScrollLines do
    try
      if WheelDelta > 0 then
        ScrollBox1.Perform(WM_VSCROLL, SB_LINEUP, 0)
      else
        ScrollBox1.Perform(WM_VSCROLL, SB_LINEDOWN, 0);
    finally
      ScrollBox1.Perform(WM_VSCROLL, SB_ENDSCROLL, 0);
    end;
end;
    -1 C'est à propos d'une barre de Défilement, pas un ScrollBox. En outre, l'exécution des œuvres uniquement pour les/sur la VCL internes.

    OriginalL'auteur Stefan

  2. 4

    La valeur par défaut TScrollBar composant, en effet, ne semble pas avoir la OnMouseWheel* les événements présents. Mais vous pouvez simplement les affecter comme suit:

    type
  TForm1 = class(TForm)
    ScrollBar1: TScrollBar;
    procedure FormCreate(Sender: TObject);
    procedure ScrollBar1Scroll(Sender: TObject; ScrollCode: TScrollCode;
      var ScrollPos: Integer);
  private
    procedure ScrollBarMouseWheel(Sender: TObject; Shift: TShiftState;
      WheelDelta: Integer; MousePos: TPoint; var Handled: Boolean);
  end;

...

procedure TForm1.FormCreate(Sender: TObject);
begin
  ScrollBar1.OnMouseWheel := ScrollBarMouseWheel;
end;

procedure TForm1.ScrollBarMouseWheel(Sender: TObject; Shift: TShiftState;
  WheelDelta: Integer; MousePos: TPoint; var Handled: Boolean);
var
  NewScrollPos: Integer;
begin
  NewScrollPos := ScrollBar1.Position - WheelDelta;
  //Trigger the OnScroll event:
  ScrollBar1.Scroll(scPosition, NewScrollPos);
  //Scroll the bar into the new position:
  ScrollBar1.Position := NewScrollPos;
  Handled := True;
end;

    Vous êtes libre de mettre en œuvre la présente certains plus créatif:

      if WheelDelta > 0 then
    NewScrollPos := ScrollBar1.Position - ScrollBar1.PageSize
  else
    NewScrollPos := ScrollBar1.Position + ScrollBar1.PageSize;

    Et vous pourriez interposer le TScrollBar classe pour éviter d'affecter l'événement au moment de l'exécution:

    type
  TScrollBar = class(StdCtrls.TScrollBar)
  protected
    function DoMouseWheel(Shift: TShiftState; WheelDelta: Integer;
      MousePos: TPoint): Boolean; override;
  end;

function TScrollBar.DoMouseWheel(Shift: TShiftState; WheelDelta: Integer;
  MousePos: TPoint): Boolean;
var
  NewScrollPos: Integer;
begin
  NewScrollPos := Position - WheelDelta;
  Scroll(scPosition, NewScrollPos);
  Position := NewScrollPos;
  Result := True;
end;

    OriginalL'auteur NGLN

  3. 2

    c'est trop facile de simplement augmenter la Valeur de position .

    procedure TForm1.FormMouseWheel(Sender: TObject; Shift: TShiftState;
WheelDelta: Integer; MousePos: TPoint; var Handled: Boolean);
begin
self.VertScrollBar.Position :=  self.VertScrollBar.Position + WheelDelta;
end;
    Cela a fonctionné pour moi juste eu à modifier le + à un autre, il va vers l'arrière "inversé de défilement" LOL

    OriginalL'auteur Safwat Safwat

  4. 1
    procedure TForm1.FormMouseWheelDown(Sender: TObject; Shift: TShiftState;
  MousePos: TPoint; var Handled: Boolean);
begin
  ScrollBox1.VertScrollBar.Position := ScrollBox1.VertScrollBar.Position + 20;
end;

procedure TForm1.FormMouseWheelUp(Sender: TObject; Shift: TShiftState;
  MousePos: TPoint; var Handled: Boolean);
begin
  ScrollBox1.VertScrollBar.Position := ScrollBox1.VertScrollBar.Position - 20;
end;
    Vous devriez lire à propos de code de mise en forme et correction de Votre réponse. Il serait beaucoup plus facile à lire. stackoverflow.com/help/formatting
    La question est à propos d'une barre de Défilement, pas un ScrollBox.

    OriginalL'auteur Testman

  5. 0

    Je ne sais pas si cela va aider beaucoup, mais voici comment le faire avec un TMemo. La barre de défilement devrait être un processus similaire, à moins qu'il y est quelques autres de mieux que Delphi versions plus tard que le mien utilisation.

    procedure TForm1.Memo1WindowProc(var msg: TMessage);
  var
    ticks: ShortInt;
    ScrollMsg: TWMVScroll;
  begin
    if msg.Msg = WM_MOUSEWHEEL then
      begin
        ScrollMsg.Msg := WM_VSCROLL;
        ticks := HiWord(msg.wparam);
        if ticks > 0 then
          ScrollMsg.ScrollCode := sb_LineUp
        else
          ScrollMsg.ScrollCode := sb_LineDown;
        ScrollMsg.Pos:=0;
        Memo1.Dispatch(ScrollMsg) ;
      end
    else
      OldMemo1(msg);
    end;

procedure TForm1.FormCreate(Sender: TObject);
 // save old window proc, assign mine.
  begin
    OldMemo1 := Memo1.WindowProc;
    Memo1.WindowProc := Memo1WindowProc;
  end;

    HTH certains.

    OriginalL'auteur Glenn1234

  6. 0

    Vieux post, mais j'ai trouvé la solution. Tout simplement

    procedure TForm1.FormMouseWheel(Sender: TObject; Shift: TShiftState;
  WheelDelta: Integer; MousePos: TPoint; var Handled: Boolean);
begin
  inherited;

  ScrollBox1.ScrollBy(WheelDelta, 0);
end;

    Fonctionne pour moi.

    La question est à propos d'une barre de Défilement, pas un ScrollBox.
    Outre le fait que c'est à propos de la barre de Défilement, à l'aide de ScrollBy défile le contrôle complet y compris la barre de défilement lui-même et de faire défiler horizontalement. De bien meilleurs résultats sont obtenus en utilisant "ScrollBox1.VertScrollBar.Position := ScrollBox1.VertScrollBar.Position - WheelDelta;". Aussi traité doit être défini à true.

    OriginalL'auteur Lucas Magalhães