Comment faire pour attribuer de la valeur à l'aide de la chaîne VB.NET?

Vous pouvez utiliser la réflexion pour définir S1 valeur:

Imports System.Reflection

Public Class Form1
    Public S1 As String = "a"

    Private Sub Button1_Click(sender As System.Object, e As System.EventArgs) Handles Button1.Click
        Dim StringFromFile As String = "S1=hello"

        Dim temp() As String = Split(StringFromFile, "=", -1, CompareMethod.Binary)
        'temp(0) = variable name
        'temp(1) = variable value

        SetS1(Me, "S1", temp(1))
        MessageBox.Show(S1)
    End Sub

    ''' <summary>
    ''' 
    ''' </summary>
    ''' <param name="obj">the class that stores your S1 public field</param>
    ''' <param name="fieldName">that is your S1 field</param>
    ''' <param name="Value">S1 new value, that is hello</param>
    ''' <remarks></remarks>
    Public Sub SetS1(ByVal obj As Object, ByVal fieldName As String, ByVal Value As Object)
        Try
            Dim fi As FieldInfo = obj.GetType().GetField(fieldName, BindingFlags.Instance Or BindingFlags.Public Or BindingFlags.NonPublic)
            If Not fi Is Nothing Then
                fi.SetValue(obj, Value)
            End If

        Catch ex As Exception

        End Try
    End Sub
End Class

Ressources supplémentaires

Il y a un livre sur la réflexion qui est très bon, prenons un coup d'oeil:

Visual Basic .NET Réflexion Manuel

Réflexion est un mécanisme prévu par .NET qui permet aux développeurs de
rendre leurs programmes plus souples et plus dynamiques. La réflexion fait
possible pour les applications à être plus modulaire, extensible, et
configurable. La construction sur les bases de l'orientation de l'objet et de la
.NET type de système, la réflexion fournit des mécanismes pour dynamiquement
examiner, modifier, et même la création d'objets au moment de l'exécution. .NET aussi
ajoute la possibilité pour les développeurs d'ajouter des attributs à leurs types,
qui fournissent des métadonnées sur le type qui peuvent être examinées et utilisées
grâce à la réflexion, au moment de l'exécution.

Ce livre examine toutes les façons, la réflexion peut être utilisé, et identifie
applications pratiques et important de la programmation des techniques qui comptent
à la réflexion pour leur fonctionnalité. Il couvre l'API reflection,
l'utilisation d'attributs .NET, et se penche également sur les mécanismes .NET
fournit pour la génération dynamique de code - toutes les techniques qui permettent de
aux développeurs de créer plus flexibles, plus dynamique des applications.

OriginalL'auteur Teen

J'espère que je suis arriver le droit de la question. Il me semble que si vous voulez affecter la valeur de temp(1) à la variable S1 qui vous avez déclaré plus tôt.

Cela se fait à l'aide d'une simple opération:

S1 = temp(1)

Ou, si cela n'est pas clair pour vous, Set peut être utilisé ainsi:

Set S1 = temp(1)

Plus d'informations sur ce ici et ici.

Edit 1

Réfléchir sur ce que vous venez d'écrire un commentaire à votre question, la chaîne que vous fractionnez vient à partir d'un fichier qui peut changer à tout moment donné dans le temps.

Pour cela, je voudrais envisager à l'aide d'une base de données (avec des déclencheurs), ou un FileSystemWatcher (documentation ici) objet à surveiller un répertoire spécifique pour les modifications de fichiers.

Un exemple de solution à l'aide de ce qui est indiqué ci-dessous.

Dim watcher As New System.IO.FileSystemWatcher()
watcher.Path = "C:\MyPathToMonitor"
watcher.Filter = "*MyFileNameToLookFor" 'could be *MyFile.txt

'assign the event. could be done by declaring the watcher `WithEvents` in the class scope too.
AddHandler watcher.Changed, AddressOf OnChanged

Et puis, dans votre gestionnaire d'événement:

Private Shared Sub OnChanged(source As Object, e As FileSystemEventArgs)

    'here we just say that StringFromFile has been assigned to the file contents now.

    Dim temp() As String = Split(StringFromFile, "=", -1, CompareMethod.Binary)

    'remember to have the S1 variable in your class scope.
    S1 = temp(1)

End Sub 

Edit 2

Si vous voulez être en mesure de modifier la valeur d'une variable donnée, le nom de cette variable comme un string, alors vous devriez regarder dans la Réflexion, ce qui permet d'évaluer de code lors de l'exécution, par opposition à la compilation.

Je vous ai donné un exemple de code ci-dessous qui résume assez bien l'utilisation de la Réflexion.

'get the reflection type of the current class.
Dim TypeOfMe As Type = Me.GetType()

'did this for readability.
Dim VariableName = temp(0)
Dim VariableValue = temp(1)

'get the field in the class which is private, given the specific name (VariableName).
Dim Field As FieldInfo = TypeOfMe.GetField(VariableName, BindingFlags.NonPublic Or BindingFlags.Instance)

'set the value of that field, on the object "Me".
Field.SetValue(Me, VariableValue)

OriginalL'auteur Mathias Lykkegaard Lorenzen

Vous ne pouvez pas réfléchir une variable locale, car après la compilation, le compilateur perd les noms des habitants, mais conserve les noms de ceux au niveau de la classe.

Afin de rendre votre exemple, le travail, vous devez faire en S1, une classe de niveau variable, pas comme une variable interne à la méthode.

Public Class Class1
    Dim S1 As String = "a"

    Public Sub Ask()
        Try
            Dim StringFromFile As String = "S1=hello"

            Dim temp() As String = Split(StringFromFile, "=", - 1, CompareMethod.Binary)
            'temp(0) = variable name
            'temp(1) = variable value

            'my question is: how to assign value to S1?
            Dim TypeOfMe As Type = Me.GetType()

            'did this for readability.
            Dim VariableName As String = temp(0)
            Dim VariableValue As String = temp(1)

            'get the field in the class which is private, given the specific name (VariableName).
            Dim Field As FieldInfo = TypeOfMe.GetField(VariableName, BindingFlags.NonPublic Or BindingFlags.Instance)

            'set the value of that field, on the object "Me".
            Field.SetValue(Me, VariableValue)            '<-- this line caused NullReferenceException (no more.)
            Console.WriteLine("S1 using reflection")
            Console.WriteLine(S1)

        Catch ex As Exception
            Console.WriteLine(ex.ToString)
        End Try
    End Sub
End Class

Toutefois, comme cela a déjà été dit ici, à avoir une approche plus pragmatique consiste à utiliser un dictionnaire.

Public Class Class2

    Public Sub Ask()
        Try
            Dim StringFromFile As String = "S1=hello"

            Dim temp() As String = Split(StringFromFile, "=", - 1, CompareMethod.Binary)

            ' the way you probably should do it.
            Dim test As Dictionary(Of string, string) = New Dictionary(Of String,String)()
            test.Add(temp(0), temp(1))
            Console.WriteLine("S1 using dictionary")
            Console.WriteLine(test("S1"))

        Catch ex As Exception
            Console.WriteLine(ex.ToString)
        End Try
    End Sub
End Class

si vous aviez un dictionnaire qui avait déjà les valeurs qui vous ont été après cela, tu ne ferais pas un complément de cours, vous serait tout simplement mettre la clé de la nouvelle valeur comme test(temp(0)) = temp(1)

---

Ce que vous avez à retenir est que la Réflexion est cher. Ne pas le faire sauf si vous devez absolument. Dans ce cas, je ne vois pas le besoin réel pour elle, et j'ai rien vu à me convaincre que vous n'avez pas d'autre choix. Essayez de garder votre solution aussi simple que possible.

OriginalL'auteur pms1969

Si vous ne souhaitez affecter la valeur de temp(1) à S1, vous pouvez le faire:

S1 = temp(1)

Si vous avez un petit ensemble fixe de valeurs possibles, vous pouvez essayer d'utiliser Select Case:

Select Case temp(0)
    Case "S1"
        S1 = temp(1)
    Case "S2"
        S2 = temp(1)
End Select

Mais en général, la meilleure façon de le faire est d'utiliser un dictionnaire pour stocker les valeurs, pas de variables:

Dim dict = New Dictionary(Of String, String)

dict(temp(0)) = temp(1)

Ensuite, vous pouvez obtenir la valeur de S1 par quelque chose comme:

dict("S1")

OriginalL'auteur svick