Comment faire pour copier Qt Dll runtime à la sortie du projet

J'ai un simple projet créé dans Qt Creator (installé à l'aide de Qt SDK 1.1.4). Il fonctionne très bien à partir de l'intérieur de l'intervalle Qt Creator, mais si je puis naviguez vers le répertoire de sortie de Windows et double-cliquez sur le fichier EXE, je vais vous obtenez une erreur du genre:

The program can't start because QtCored4.dll is missing from your computer.
Try reinstalling the program to fix this problem.

C'est évidemment parce que ce n'est pas dans mon CHEMIN (et je ne veux pas qu'il le soit, dans les cas, j'ai plusieurs versions de Qt sur mon ordinateur), et Qt Creator /qmake n'ai pas de copie de l'intervalle Qt Dll à la sortie du projet.

Ce que je voudrais faire est d'utiliser qmake pour copier le nécessaire Qt fichiers vers le répertoire de sortie de projet - où que ce soit. Comment puis-je faire cela?

(J'ai essayé de créer une cible personnalisée dans qmake, mais je ne suis pas trop loin...)

Mise à JOUR le 19 juillet 2016: Juste pour préciser, le post ci-dessus en ce qui concerne Qt4. Sur Qt5, vous devriez plutôt regarder appelant windeployqt. Cette Qt5 outil permettra de lire vos binaire, de déterminer qui Qt5 runtime fichiers dont vous avez besoin, et de les copier dans votre répertoire binaire. Notez également qu'il va réparer les chemins absolus dans les Qt5::bibliothèque de Base qui sont spécifiques à votre PC, afin que l'utilisation de cet outil est fondamentalement obligatoire, sauf si vous voulez fournir un qt.conf fichier vous-même.

oh mon dieu,exactement, je suis en train de travailler dessus en ce moment et à la recherche d'une solution
Ali Foroughi question similaire: stackoverflow.com/questions/8391924/...
ce que nous voulons, c'est d'avoir qmake automatiquement copier les Dll à la sortie de la construction, de sorte que nous n'avons pas à faire à la main.
que ma question mec 😀
Je n'ai jamais été aussi paresseux que cela! - Je l'utiliser pour copier manuellement les bibliothèques nécessaires. +1 pour la paresse 🙂
Pour l'enregistrement, vous tentez de déployer une version de débogage au lieu d'une version release.
noté, la solution de copier Dll de débogage pour le debug et release Dll pour la libération. 🙂
Il n'y a pas beaucoup d'utilisation pour copier la dll de débogage bien 🙂
Il y a un grand usage pour les copier quand le fichier EXE est liée à leur encontre. 🙂 (Ma principale préoccupation, bien sûr, est pour la libération des Dll).
Pourquoi voudriez-vous d'exécuter les versions de débogage à l'extérieur de l'IDE?

InformationsquelleAutor James Johnston | 2011-12-05

c++qmake qt qt-creator qt4

8

OK, voici un vilain hack:
```
# Copy required DLLs to output directory
CONFIG(debug, debug|release) {
    QtCored4.commands = copy /Y %QTDIR%\\bin\\QtCored4.dll debug
    QtCored4.target = debug/QtCored4.dll
    QtGuid4.commands = copy /Y %QTDIR%\\bin\\QtGuid4.dll debug
    QtGuid4.target = debug/QtGuid4.dll

    QMAKE_EXTRA_TARGETS += QtCored4 QtGuid4
    PRE_TARGETDEPS += debug/QtCored4.dll debug/QtGuid4.dll
} else:CONFIG(release, debug|release) {
    QtCore4.commands = copy /Y %QTDIR%\\bin\\QtCore4.dll release
    QtCore4.target = release/QtCore4.dll
    QtGui4.commands = copy /Y %QTDIR%\\bin\\QtGui4.dll release
    QtGui4.target = release/QtGui4.dll

    QMAKE_EXTRA_TARGETS += QtCore4 QtGui4
    PRE_TARGETDEPS += release/QtCore4.dll release/QtGui4.dll
} else {
    error(Unknown set of dependencies.)
}
```
Voici une partie de ce que je n'aime pas:
- Utilise %QTDIR% variable d'environnement; cette variable n'est pas évaluée jusqu'à ce que la commande de copie est effectivement exécuté. Semble comme si quelque chose le long des lignes de QMAKE_LIBS_QT_DLL serait plus approprié, mais je ne pouvais pas obtenir que le travail pour une raison quelconque.
- Codée en dur "debug" et "release" noms; semble qu'il devrait y avoir une sorte de variable à utiliser.
- Appelant à l'environnement à l'aide de la commande de "copie".
Je vais accepter une autre réponse si quelqu'un peut nettoyer cette un bon morceau, par exemple en réduisant la durée et/ou pour répondre à certaines de mes préoccupations, ou tout simplement trouver une meilleure façon en général.
- $$QMAKE_LIBDIR_QT semble être le bon remplacement pour %QTDIR%\\bin.
- Mise à jour: $$QMAKE_LIBDIR_QT n'a pas fonctionné pour l'un de nos développeurs. Nous sommes passés de $$[QT_INSTALL_BINS], souligné par "qmake -requête".
- Aussi, à l'aide de $$QMAKE_COPY, $$QMAKE_DIR_SEP et $$QMAKE_EXTENSION_SHLIB pourrait faire de ce cross-plateforme.
- J'ai trouvé que, parfois, j'ai besoin de redémarrer pour résoudre certains des plus étranges de qmake bugs qui se produisent occasionnellement. Bug passe de 100% du temps? Le laisser seul, de revenir, et maintenant ça marche -_- ...
- Vous pouvez toujours référence les fichiers de configuration dans votre mkespec répertoires. Il suffit de ne pas oublier de vérifier le common/ dossier 🙂
InformationsquelleAutor James Johnston
7

Un peu plus propre méthode, mais il faudra faire un make install après un make. Il fonctionne sur Windows, mais aurait besoin de peaufinage pour d'autres plates-formes.
```
debug { DESTDIR = debug }
release { DESTDIR = release }
debug_and_release { DESTDIR = bin }

myqtlibs.path = $$DESTDIR
myqtlibs.files = $$QMAKE_LIBDIR_QT/*.dll junk.txt fred.out
myqtlibs.CONFIG = no_check_exist

INSTALLS += myqtlibs
```
Si qmake est exécuté juste pour le debug, toutes les sorties vont dans ./debug . Si c'est juste pour la presse, la sortie va dans ./la libération . Si les deux, puis ./bin .

J'ai remarqué que l'activation de l'ombre du bâtiment dans QtCreator causé l'exécutable ne pas finir dans le DESTDIR. Je ne suis pas tout à fait sûr pourquoi.

InformationsquelleAutor jwernerny

Copie Dépendances avec windeployqt

# Deployment - Automatically Detect and Copy Dependencies to Build Folder

TARGET_CUSTOM_EXT = .exe
DEPLOY_COMMAND = windeployqt

DEPLOY_OPTIONS = "--no-svg --no-system-d3d-compiler --no-opengl --no-angle --no-opengl-sw"

CONFIG( debug, debug|release ) {
    # debug
    DEPLOY_TARGET = $$shell_quote($$shell_path($${OUT_PWD}/debug/$${TARGET}$${TARGET_CUSTOM_EXT}))
    DEPLOY_OPTIONS += "--debug"
} else {
    # release
    DEPLOY_TARGET = $$shell_quote($$shell_path($${OUT_PWD}/release/$${TARGET}$${TARGET_CUSTOM_EXT}))
    DEPLOY_OPTIONS += "--release"
}

# Uncomment the following line to help debug the deploy command when running qmake
#message($${DEPLOY_COMMAND} $${DEPLOY_OPTIONS} $${DEPLOY_TARGET})

QMAKE_POST_LINK = $${DEPLOY_COMMAND} $${DEPLOY_OPTIONS} $${DEPLOY_TARGET}

ou Copier les dépendances à la main

# Deployment - Copy Dependencies to Build Folder

dlls.path  =  $${DESTDIR}
dlls.files += $$[QT_INSTALL_BINS]/icudt51.dll
dlls.files += $$[QT_INSTALL_BINS]/icuin51.dll
dlls.files += $$[QT_INSTALL_BINS]/icuuc51.dll
dlls.files += $$[QT_INSTALL_BINS]/libgcc_s_dw2-1.dll
dlls.files += $$[QT_INSTALL_BINS]/libstdc++-6.dll
dlls.files += $$[QT_INSTALL_BINS]/libwinpthread-1.dll
dlls.files += $$[QT_INSTALL_BINS]/Qt5Core.dll
dlls.files += $$[QT_INSTALL_BINS]/Qt5Network.dll
dlls.files += $$[QT_INSTALL_BINS]/Qt5Gui.dll
dlls.files += $$[QT_INSTALL_BINS]/Qt5Widgets.dll
dllA.path   += $${DESTDIR}/platforms
dllA.files  += $$[QT_INSTALL_PLUGINS]/platforms/qwindows.dll
dllB.path   += $${DESTDIR}/plugins/imageformats/
dllB.files  += $$[QT_INSTALL_PLUGINS]/imageformats/qico.dll
dllB.files  += $$[QT_INSTALL_PLUGINS]/imageformats/qwbmp.dll
INSTALLS   += dlls dllA dllB

Référencement: http://doc.qt.io/qt-5/qmake-variable-reference.html#deployment

Dans le cas où vous avez besoin d'identifier les conditions préalables /dépendances de la croix-plate-forme, veuillez jeter un oeil à CMake est getPrerequisites(). Il utilise dumpbin, objbin, ldd, otool pour l'identification des dépendances.

Référencement: https://cmake.org/cmake/help/v3.0/module/GetPrerequisites.html

Est-il un générique / espace réservé j'ai pu le faire lors de la prise de plusieurs plates-formes? comme, DEPLOY_COMMAND = *deploy, ou ces tous besoin d'être individuellement et explicitement spécifié?
Pas avec Qt outillage de bord. Mais par exemple avec CMake vous pouvez utiliser getPrerequisites(). Il utilise dumpbin, objbin, ldd, otool (cross-platform) pour l'identification des dépendances. Voir cmake.org/cmake/help/v3.0/module/GetPrerequisites.html
Nice! Merci à vous, @Jens A. Koch!

InformationsquelleAutor Jens A. Koch

4

J'ai rencontré le même problème et jwernerny de la solution m'a beaucoup aidé. Cependant, j'ai été en utilisant l'Ombre de Build sur windows 7 et il avait besoin d'un peu plus tweeking.

J'ai également nécessaire de définir la DESTDIR selon la configuration actuelle.

Dans mon cas, j'ai voulu copier *.qml fichiers, c'est comment je l'ai réalisé:
```
CONFIG(release, debug|release): DESTDIR = $$OUT_PWD/release
CONFIG(debug, debug|release): DESTDIR = $$OUT_PWD/debug

QmlFiles.path = $$DESTDIR/Qml
QmlFiles.files += $$files(Qml/*.qml)

INSTALLS += QmlFiles
```
EDIT :

Depuis que j'ai utiliser Ombre à Construire-je besoin pour utiliser $$OUT_PWD pour obtenir le dossier de sortie.

InformationsquelleAutor ForceMagic

Vous devez vous connecter pour publier un commentaire.