Comment faire pour désactiver l'enregistrer comme invite de commandes?

        If IsWorkbookOpen("CONTRACT\CONTRACTLIST_Cement.xlsx") Then
            x = 0
        Else
            Application.DisplayAlerts = False
            ActiveWorkbook.Close savechanges:=True
            Application.DisplayAlerts = True
        End If

Salut, malgré l'aide du code ci-dessus, l'enregistrer comme invite encore de temps en temps apparaît et sur le programme. Personne ne sait comment l'arrêter complètement? Le problème est que lorsque je clique sur enregistrer sous, il m'avertir qu'elle était encore ouverte.

OriginalL'auteur Ting Ping | 2013-07-16

Essayer de code ci-dessous

Il est toujours bon de explcilty consulter le classeur plutôt que ActiveWorkbook

Sub test()
   If IsWorkbookOpen("CONTRACT\CONTRACTLIST_Cement.xlsx") Then
            x = 0
    Else
        Application.DisplayAlerts = False
        ThisWorkbook.Save
        ThisWorkbook.Close False
        Application.DisplayAlerts = True
    End If

End Sub

OriginalL'auteur Santosh

2

Vous pouvez utiliser Workbook_BeforeSave Événement dans le ThisWorkbook objet de capturer l'utilisateur en sélectionnant enregistrer sous (ou en utilisant le raccourci clavier), ce qui aurait pour résultat de l'Enregistrer Comme l'invite affichée et la SaveAsUI définie sur true. Si SaveAsUI est vrai, cela signifie que l'utilisateur tente d'enregistrer le fichier en tant que quelque chose d'autre, de sorte que vous pouvez annuler l'opération enregistrer sous.

Ouvrir la Fenêtre de Visual Basic (Alt + F11) et placez le code suivant dans ThisWorkbook.

Désactiver Enregistrer Comme
```
Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)

    If (SaveAsUI = True) Then
        MsgBox "Sorry. I can't have you saving this file as something else."
        Cancel = True
    End If
End Sub
```
Vous pouvez supprimer le MsgBox ligne si vous voulez; je l'ai mis là comme un exemple, si vous voulez, pour informer l'utilisateur que la fonction a été désactivée

Pour désactiver les deux les Enregistrer et de les Enregistrer en tant Que fonctionnalités, vous souhaitez supprimer le if déclaration et d'annuler l'opération d'enregistrement, indépendamment de si l'Enregistrer sous s'affiche.

Désactiver Enregistrer et Enregistrer sous
```
Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)

    MsgBox "Sorry. I can't have you saving this file at all."
    Cancel = True
End Sub
```
Si vous voulez juste pour désactiver l'opération de sauvegarde, vous seulement besoin de regarder pour l'événement, où l'utilisateur d'économiser, mais le SaveAsUI est pas affichée (c'est à dire de l'utilisateur est tout simplement d'enregistrer le fichier).

Désactiver Enregistrer
```
Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)

    If (SaveAsUI = False) Then
        MsgBox "Sorry. I can't have you saving any updates to this file."
        Cancel = True
    End If
End Sub
```
Enfin, notez que l'utilisateur aura toujours une invite à enregistrer si l'utilisateur ferme le fichier. L'utilisateur ne sera pas en mesure d'enregistrer, le fichier se ferme, mais si vous voulez faire l'expérience d'être un peu plus propre, vous aurez besoin de faire un changement supplémentaire. Lorsqu'un utilisateur ferme un fichier Excel vérifie la ThisWorkbook.Saved variable pour voir si le fichier a été enregistré. Si elle est fausse, il invite l'utilisateur à Enregistrer le fichier. Pour éviter cela, nous pouvons définir cette valeur à true sans l'enregistrer, donc "tricher" Excel en pensant que le fichier a été enregistré

Désactiver Enregistrer et Enregistrer sous, y compris après que l'Utilisateur tente de fermer le fichier

Ajoutez le code suivant après votre Workbook_BeforeSave code.
```
Private Sub Workbook_BeforeClose(Cancel As Boolean)
    ActiveWorkbook.Saved = True
    MsgBox "Click OK to continue closing this file. Changes will not be saved."
End Sub
```
Ce code fonctionne très bien, juste lui donner un essai.
Jaycal, l'utilisateur encore en mesure de réaliser la sauvegarde en appuyant sur Ctrl+S, peut-être vous pouvez le mettre de cette façon (à l'extérieur de Si SaveAsUI) : Si (Cancel = false) Then Cancel = true
Merci pour l'œil. L'OP a été en réalité que de demander de l'Enregistrer en tant Que fonctionnalité doit être désactivée, ce qui était le code que j'ai fourni. Pour rendre la réponse plus complète, Il montre maintenant comment faire pour désactiver uniquement Enregistrer, Enregistrer sous seulement, ou les deux, enregistrer et Enregistrer sous.

OriginalL'auteur Jaycal

Vous devez vous connecter pour publier un commentaire.