Comment faire pour exécuter sans tête à DISTANCE google chrome à l'aide de robot cadre

Je suis en train de lancer chrome sans tête avec mon robot cadre des tests de suites.
J'ai réussi à le faire independtly avec python en utilisant le sélénium comme suit:

options = webdriver.ChromeOptions()
options.add_argument('--headless')
my_driver = webdriver.Remote(command_executer=my_remote_address, desired_capabilities=options.to_capabilities)

Le code suivant est ce que j'ai fait au robot, mais n'a pas fonctionné:

${options}=  Evaluate  sys.modules['selenium.webdriver'].ChromeOptions()  sys, selenium.webdriver
${options.add_argument}=  Set Variable  add_argument=--headless
Create WebDriver  Chrome  chrome_options=${options}

Open Browser   http://www.google.com   chrome

Passez un peu de réponses, c'est maintenant un oneliner: Open Browser http://www.yoursite.com headlesschrome (Au moins si vous êtes ici pour une solution locale)

OriginalL'auteur Dan W | 2017-10-18

robotframework selenium2library

À exécuter sans tête, vous devez définir les arguments et les convertir en capacités, de sorte qu'ils peuvent être utilisés lors de l'utilisation de la Remote Driver option. Cela fonctionne pour les Open Browser ainsi que la Create Webdriver façon de naviguer vers une URL.

*** Settings ***
Library    Selenium2Library

Suite Teardown    Close All Browsers

*** Test Cases ***
Headless Chrome - Create Webdriver
    ${chrome options} =     Evaluate    sys.modules['selenium.webdriver'].ChromeOptions()    sys, selenium.webdriver
    Call Method    ${chrome options}   add_argument    headless
    Call Method    ${chrome options}   add_argument    disable-gpu
    ${options}=     Call Method     ${chrome_options}    to_capabilities      

    Create Webdriver    Remote   command_executor=http://localhost:4444/wd/hub    desired_capabilities=${options}

    Go to     http://cnn.com

    Maximize Browser Window
    Capture Page Screenshot

Headless Chrome - Open Browser
    ${chrome_options} =     Evaluate    sys.modules['selenium.webdriver'].ChromeOptions()    sys, selenium.webdriver
    Call Method    ${chrome_options}   add_argument    headless
    Call Method    ${chrome_options}   add_argument    disable-gpu
    ${options}=     Call Method     ${chrome_options}    to_capabilities     

    Open Browser    http://cnn.com    browser=chrome    remote_url=http://localhost:4444/wd/hub     desired_capabilities=${options}

    Maximize Browser Window
    Capture Page Screenshot

travaillé! merci beaucoup.
Pour la deuxième solution (Open Browser [...] chrome) l'appel à to_capabilities peut être sauvé, en passant les options comme chrome_options=${chrome_options}.

OriginalL'auteur A. Kootstra

13

Dans les versions plus récentes de SeleniumLibrary (3.1.0) et le Sélénium (3.8.0), vous pouvez tout simplement de paramétrer le navigateur pour headlesschrome au lieu de chrome.

Il y a aussi headlessfirefox disponibles.

Ex.
```
Open Browser      http://www.yoursite.com    headlesschrome
```
http://robotframework.org/SeleniumLibrary/SeleniumLibrary.html#Open%20Browser

Heureux, je défile vers le bas!
L'exemple ouvrir un local sans tête de chrome. La question était à propos de la connexion de Sélénium de la Grille et le démarrage d'une télécommande sans tête de chrome de l'instance.

OriginalL'auteur Joao Coelho

S'il vous plaît essayer la ci-dessous. Exécuter le mot-clé dans la configuration de Test

Running the tests in chrome headless
    ${chrome options} =     Evaluate    sys.modules['selenium.webdriver'].ChromeOptions()    sys, selenium.webdriver
    Call Method    ${chrome options}   add_argument    headless
    Call Method    ${chrome options}   add_argument    disable-gpu
    Create Webdriver    Chrome    chrome_options=${chrome options}

Ce que vous avez écrit est bon d'ouvrir le navigateur en local.

OriginalL'auteur bsd007

Essayer ces deux mots-clés:

Open Chrome
    [Arguments]    ${url}    ${lang}
    ${chrome_options}=    Evaluate    sys.modules['selenium.webdriver'].ChromeOptions()    sys, selenium.webdriver
    Call Method    ${chrome_options}    add_argument    headless
    Call Method    ${chrome_options}    add_argument    disable-gpu
    Create Webdriver    Chrome    chrome_options=${chrome_options}
    Go To    ${url}

Open Remote Chrome
    [Arguments]    ${url}    ${remote_url}    ${lang}
    ${chrome_options}=    Evaluate    sys.modules['selenium.webdriver'].ChromeOptions()    sys, selenium.webdriver
    Call Method    ${chrome_options}    add_argument    headless
    Call Method    ${chrome_options}    add_argument    disable-gpu
    Open Browser    ${url}    Chrome    remote_url=${remote_url}    desired_capabilities=${chrome_options.to_capabilities()}

Première lancera un local de chrome, tandis que la seconde consiste à lancer une distance de chrome. Si vous avez besoin d'être capable de gérer la distance vs. local en un seul mot-clé, vous pouvez créer un wrapper autour de ces deux avec un argument booléen qui permettra de déterminer quels mots clés à l'appel.

OriginalL'auteur Verv

${options}=  Evaluate  sys.modules['selenium.webdriver'].ChromeOptions()  sys, selenium.webdriver
Call Method    ${options}    add_argument    headless
Call Method    ${options}    add_argument    disable-gpu
Create WebDriver  Chrome  chrome_options=${options}
Goto  https://www.cnn.com/
Wait Until Page Contains    Politics today
Close Browser

OriginalL'auteur roshan

J'ai créé dépôt d'exemple et des instructions sur la façon d'exécuter Chrome et Firefox natif, sans tête, ou avec le panneau et également tableau de comparaison pour des temps d'exécution. Vous pouvez trouver des exemples sur mon github page https://github.com/shnigi/Docker-Headless-Testing-Demo

L'Idée principale est toutefois Dans les deux tests pour l'utilisation du Sélénium webdriver API dire chromedriver et geckodriver pour lancer le navigateur avec quelques arguments. SeleniumLibrary du Navigateur Ouvertes mot-clé n'a pas cette fonctionnalité, mais de Créer Webdriver fait le tour.

Open Headless Chrome Browser to Page
  ${chrome_options}=    Evaluate    
  sys.modules['selenium.webdriver'].ChromeOptions()    sys
  Call Method    ${chrome_options}    add_argument    test-type
  Call Method    ${chrome_options}    add_argument    --disable-extensions
  Call Method    ${chrome_options}    add_argument    --headless
  Call Method    ${chrome_options}    add_argument    --disable-gpu
  Call Method    ${chrome_options}    add_argument    --no-sandbox
  Create Webdriver    Chrome    chrome_options=${chrome_options}
  Set Window Size    1920    1080
  Go To    ${PAGE URL}

Firefox true headless
  ${firefox options}=     Evaluate    sys.modules['selenium.webdriver'].firefox.webdriver.Options()    sys, selenium.webdriver
  Call Method    ${firefox options}   add_argument    -headless
  Create Webdriver    Firefox    firefox_options=${firefox options}
  Set Window Size    1920    1080
  Go To    ${PAGE URL}
  Page Should Be Open

Vous aurez besoin navigateurs les plus récents et les pilotes installés.

OriginalL'auteur Shnigi

Vous devez vous connecter pour publier un commentaire.